[290页]

8-2 asm.s程序

8-2-1 功能描述

1、 我们先考虑c)、 d)

2、无出错码
2.1、 将要执行的处理函数压栈；
2.2、 eax被交换入栈。现在eax=护理函数
2.3、 其他寄存压栈
2.4、 立即数0压栈
2.5、 取edx=EIP后，将edx压栈
2.6、 段寄存器都设置0x10段选择符
2.7、 调用处理函数(eax)
2.8、 去掉（2.4和2.5）数据
2.9、 弹出所有寄存
2.10、 返回到应用程序

3、 有出错码
3.1、 将要执行的处理函数压栈；
3.2、 出错码与eax交换；
3.3、 处理函数与ebx交换；
3.4、 其他寄存器压栈；
3.5、 将eax（错误码）压栈；
3.6、 取eax=EIP后，将eax压栈
3.7、 段寄存器都设置0x10段选择符
3.8、 调用处理函数(ebx)
3.9、 去掉（2.4和2.5）数据
3.10、 弹出所有寄存
3.11、 返回到应用程序

8-2-2 代码注释

/*
 *  linux/kernel/asm.s
 *
 *  (C) 1991  Linus Torvalds
 */

/*
asm.s程序中包括大部分的硬件故障（或出错）处理的低层次代码。
页异常由内存管理程序mm处理，所以不在这里。此程序还处理（希望是这样）由于TS-位而
造成的fpu异常，因为fpu必须正确地进行保存/恢复处理，这些还没有测试过。
*/

#本代码文件主要涉及对Intel保留中断int0--int16的处理(int17-int31留作今后使用)。
#以下是一些全局函数名的声明，其原形在traps.c中说明。
.globl _divide_error,_debug,_nmi,_int3,_overflow,_bounds,_invalid_op
.globl _double_fault,_coprocessor_segment_overrun
.globl _invalid_TSS,_segment_not_present,_stack_segment
.globl _general_protection,_coprocessor_error,_irq13,_reserved
.globl _alignment_check

#下面这段程序处理无出错号的情况。
#int0 -- 处理被零除出错的情况。 类型：错误； 无错误码。
#在执行DIV或IDIV指令时，若除数是0，CPU就会产生这个异常。当EAX（或AX、AL）容纳
#不了一个合法除操作的结果时，也会产生这个异常。21行标号'_do_divide_error'实际上是
#C语言函数do_divide_error()编译后所生产模块中对应的名称。函数'do_divide_error'在
#traps.c中实现。
_divide_error:
	pushl $_do_divide_error		#首先把将要调用的函数地址入栈。
no_error_code:					#这里是无出错号处理的入口处，见下面第56行等。
	xchgl %eax,(%esp)			#_do_divide_error的地址->eax,eax被交换入栈。
	pushl %ebx
	pushl %ecx
	pushl %edx
	pushl %edi
	pushl %esi
	pushl %ebp
	push %ds					#！！16位的段寄存器入栈后也要占用4个字节。
	push %es
	push %fs
33	pushl $0					# "error code" #将数值0作为出错码入栈。
34	lea 44(%esp),%edx			#取有效地址，即栈中原调用返回地址处的栈指针位置。
35	pushl %edx					#并压入堆栈。
	movl $0x10,%edx				#初始化段寄存器ds、es和fs，加载内存数据段选择符。
	mov %dx,%ds
	mov %dx,%es
	mov %dx,%fs
#下面上的'*'号表示调用操作数指定地址处的函数，称为间接调用。这句的含义是调用引起本次异常
#的C处理函数，例如do_divide_error()等。第41行是将堆栈指针加8相当于执行2次pop操作，
#弹出（丢弃）最后入堆栈的两个C函数（33行和35行入栈的值），让堆栈指针重新指向寄存器
#fs入栈处。
	call *%eax
41	addl $8,%esp
	pop %fs
	pop %es
	pop %ds
	popl %ebp
	popl %esi
	popl %edi
	popl %edx
	popl %ecx
	popl %ebx
	popl %eax			#弹出原来eax中的内容。
	iret

#int1 -- debug调试中断入口点。处理过程通上。类型：错误/陷阱（Fault/Trap）;无错误码。
#当eflags中TF标志置位时而引发的中断。当发现硬件断电（数据：陷阱，代码：错误），或者
#开启了指令跟踪陷阱或任务交换陷阱，或者调用寄存器访问无效（错误），CPU就会产生该异常。
_debug:
	pushl $_do_int3		# _do_debug #C函数指针入栈。以下同。
	jmp no_error_code

#int2 -- 非屏蔽中断调用入口点。 类型：陷阱； 无错误码。
#这是仅有的被赋予固定中断向量的硬件中断。每当接收到一个NMI信号，CPU内部就会产生中断
#向量2，并执行标志中断应答周期，因此很节省时间。NMI通常保留为极为重要的硬件时间使用。
#当CPU收到一个NMI信号并且开始执行其中断处理过程时，随后所有的硬件中断都将被忽略。
_nmi:
	pushl $_do_nmi
	jmp no_error_code
#int3 -- 断点指令引起中断的入口点。 类型：陷阱； 无错误码。
#由int 3指令引发的中断，与硬件中断无关。该指令通常由调试器插入被调试程序的代码中。
#处理过程通_debug。
_int3:
	pushl $_do_int3
	jmp no_error_code
#int4 -- 溢出出错处理中断入口点。 类型：陷阱； 无错误码。
#EFLAGS中OF标志置位时CPU执行INTO指令就会引发该中断。通常用于编译器跟踪算术计算溢出。
_overflow:
	pushl $_do_overflow
	jmp no_error_code

#int5 -- 边界检查出错中断入口点。 类型：错误；无错误码。
#当操作数在有效范围以外时引发的中断。当BOUND指令测试失败就会产生该中断。
#BOUND指令有3个操作数，如果第1个不在另外2个之间，就产生异常5
_bounds:
	pushl $_do_bounds
	jmp no_error_code

#int6 -- 无效操作指令出错中断入口点。 类型：错误；无错误码。
#CPU执行机构检测到一个无效的操作码而引起的中断。
_invalid_op:
	pushl $_do_invalid_op
	jmp no_error_code

#int9 -- 协处理器段超出出错中断入口点。 类型：放弃；无错误码。
#该异常基本上等同于协处理器出错保护。因为在浮点指令操作数太大时，我们就有这个机会来加载或
#保存超出数据段的浮点值。
_coprocessor_segment_overrun:
	pushl $_do_coprocessor_segment_overrun
	jmp no_error_code

#int15 -- 其他Intel保留中断的入口点。
_reserved:
	pushl $_do_reserved
	jmp no_error_code

#int45 -- (0x20+13)Linux设置的数学协处理器硬件中断。
#当协处理器执行完一个操作是就会发出IRQ13中断信号，以通知CPU操作完成。80387在执行计算
#时，CPU会等待其操作完成。下面89行上0xF0是协处理器端口，用于清忙锁存器。通过写该端口，
#本中断将消除CPU的BUSY延续信号，并重新激活80387的处理扩展请求引脚PEREQ。
#该操作主要是为了确保在继续执行8038的任何指令之前，CPU响应本中断。
_irq13:
	pushl %eax
	xorb %al,%al
89	outb %al,$0xF0
	movb $0x20,%al
	outb %al,$0x20
	jmp 1f
1:	jmp 1f
1:	outb %al,$0xA0
	popl %eax
	jmp _coprocessor_error

#以下中断在调用时CPU会在中断返回地址之后将出差号压入堆栈，
#因此返回时也需要将出错号弹出。

#int8 -- 双出错故障。 类型：放弃；有错误码。
#通常当CPU在调用前一个异常的处理程序而又监测到偶一个新的异常时，这两个异常会被串行地进行
#处理，但也会碰到很少的情况，CPU不能进行这样的串行处理操作，此时就引发该中断。
_double_fault:
	pushl $_do_double_fault		
error_code:
	xchgl %eax,4(%esp)		# error code <-> %eax
	xchgl %ebx,(%esp)		# &function <-> %ebx
	pushl %ecx
	pushl %edx
	pushl %edi
	pushl %esi
	pushl %ebp
	push %ds
	push %es
	push %fs
	pushl %eax			# error code
	lea 44(%esp),%eax		# offset
	pushl %eax
	movl $0x10,%eax
	mov %ax,%ds
	mov %ax,%es
	mov %ax,%fs
	call *%ebx
	addl $8,%esp
	pop %fs
	pop %es
	pop %ds
	popl %ebp
	popl %esi
	popl %edi
	popl %edx
	popl %ecx
	popl %ebx
	popl %eax
	iret

#int10 -- 无效的任务状态段(TSS)。 类型：错误；有错误码。
#CPU企图切换到一个进程，而该进程的TSS无效。根据TSS中那一部分引起异常，当由于TSS
#长度超过104字节时，这个异常在当前任务产生，因而切换被终止。其他问题则会导致在切换
#后的新任务中产生异常。
_invalid_TSS:
	pushl $_do_invalid_TSS
	jmp error_code

#int11 -- 段不存在。 类型：错误；有错误码。
#被引用的段不在内存中。段描述符中标志着段不在内存中。
_segment_not_present:
	pushl $_do_segment_not_present
	jmp error_code

#int12 -- 堆栈段错误。 类型：错误；有错误码。
#指令操作试图超出堆栈段范围，或者堆栈段不在内存中。这是异常11和13的特例。
#有些 操作系统可以利用这个异常来确定什么时候应该为程序分配更多的栈空间。
_stack_segment:
	pushl $_do_stack_segment
	jmp error_code

#int13 -- 一般保护性出差。 类型：错误；有错误码。
#表面是不属于任何其他类的错误。若一个异常产生时没有对应的处理向量（0--16），
#通常就会归到此类。
_general_protection:
	pushl $_do_general_protection
	jmp error_code
#int17 -- 边界对齐检查出错。
#在启用了内存边界检查时，若特权级3（用户级）数据非边界对齐时会产生该异常。

_alignment_check:
	pushl $_do_alignment_check
	jmp error_code

剩下中断

#int7 -- 设备不存在(_device_not_available)在kernel/sys_call.s,158行。
#int14 -- 也错误(_page_fault)在mm/page.s,14行。
#int16 -- 协处理器错误(_coprocessor_error)在kernel/sys_call.s,140行
#时钟中断int 0x20(_timer_interrupt)在kernel/sys_call.s,189行。
#系统调用int 0x80(_systme_call)在kernel/sys_call.s,84行。

8-2-3 Intel保留中断向量的定义。

看赵老师表。
表8-2 给出了Intel保留中断向量具体含义的说明。