第2章-编写MBR主引导记录，让我们开始掌权
这是一个网站有所有小节的代码实现，同时也包含了Bochs等文件
在开机的一瞬间，也就是接电的一瞬间， CPU 的 CS: ip 寄存器被强制初始化为 0XF000: 0XFFF0。由于开机的时候处于实模式，再重复一遍加深印象，在实模式下的段基址要乘以 16，也就是左移位，于是0XF000: 0XFFF0的等效地址将是 0XFFFF0。
BIOS 最后一项工作校验启动盘中位于 0 盘。道 1 扇区的内容。 如果此扇区末尾的两个字节分别是魔数 0x55 和 0xaa， BIOS 便认为此扇区中确实存在可执行的程序（在此先剧透一下，此程序便是久闻大名的主引导记录 MBR），便加载到物理地址 0x7c00，随后跳转到此地址，继续执行 。
0xfe05b 处，这是 BIOS 代码真正开始的地方 ，BIOS 跳转到 0x7c00 是用 jmp 0: 0x7c00 实现的，这是 jmp 指令的直接绝对远转移用法，段寄存器 cs 会被替换，这里的段基址是 0，即 cs 由之前的 0xf000 变成了0 。
$和$$是编译器 NASM 预留的关键字，用来表示当前行和本 section 的地址，起到了标号的作用，它是 NASM 提供的，并不是 CPU 原生支持的 。
用8086汇编语言编写显示字符的程序。该程序共512字节（不足部分补0），且最后两个字节是0x55与0xaa。该程序用NASM编译后，用dd命令写入bochs启动硬盘的0盘0道1扇区，BIOS会自动加载程序到内存中，然后自动跳转执行该程序。
;主引导程序
;------------------------------------------------------------
SECTION MBR vstart=0x7c00
mov ax,cs ;此时cs寄存器为0，自然可以用来将ax寄存器置0
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov sp,0x7c00
; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10 功能号:0x06 功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
mov ax, 0x600 ;ah中输入功能号
mov bx, 0x700 ;设置上卷行属性，0x70表示用黑底白字的属性填充空白行
mov cx, 0 ;左上角: (0, 0)
mov dx, 0x184f ;右下角: (80,25),
;VGA文本模式中,一行只能容纳80个字符,共25行。
;下标从0开始,所以0x18=24,0x4f=79
int 0x10 ;int 0x10
;;;;;;;;; 下面这三行代码是获取光标位置 ;;;;;;;;;
mov ah, 3 ;输入: 3号子功能是获取光标位置,需要存入ah寄存器
mov bh, 0 ;bh寄存器存储的是待获取光标的页号
int 0x10 ;输出: ch=光标开始行,cl=光标结束行
;dh=光标所在行号,dl=光标所在列号
;;;;;;;;; 获取光标位置结束 ;;;;;;;;;;;;;;;;
;;;;;;;;; 打印字符串 ;;;;;;;;;;;
;还是用10h中断,不过这次是调用13号子功能打印字符串
mov ax, message
mov bp, ax ; es:bp 为串首地址, es此时同cs一致，
; 开头时已经为sreg初始化
; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
mov cx, 5 ; cx 为串长度,不包括结束符0的字符个数
mov ax, 0x1301 ; 子功能号13是显示字符及属性,要存入ah寄存器,
; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
mov bx, 0x2 ; bh存储要显示的页号,此处是第0页,
; bl中是字符属性, 属性黑底绿字(bl = 02h,07是黑底白字)
int 0x10 ; 执行BIOS 0x10 号中断
;;;;;;;;; 打字字符串结束 ;;;;;;;;;;;;;;;
jmp $ ; 使程序悬停在此
message db "1 MBR"
times 510-($-$$) db 0
db 0x55,0xaa
vstart:主要是把地址编译为0x7c00
vstart和 org ，它们的功能是告诉编译器：“嘿，老兄，你帮我把后面所有数据〈指令和变量 ）的地址以 xxxx 为起始开始编吧”
mbr 用 vstart=0x7c00 来修饰的原因，是因为开发人员知道 mbr 要被加载器（ BIOS ）加载到物理地址0x7c00, mbr 中后续的物理地址都是 0x7c00+。另外，因为 BIOS 进入 mbr 是通过 jmp 0: 7c00 来实现的，故此时 cs 己经变成 0，相当于“平坦模型”了，只不过此“平坦模型”大小只是 65536 字节，而不是 4GB 。
所以 mbr 中各数据编译出来的地址（大于等于 0x7c00 ）实际上都成了偏移地址，这样“俨 16：偏移地址。0x7c00＋”来访问被加载到 0x7c00 的 mbr 是正确无误的。所以说，用 vstart 的时机是：我预先知道我的程序将来被加载到某地址处。程序只有加载到非 0 地址时 vstart 才是有用的，程序默认起始地址是 0 。
此时的一个内存结构图为：
