由于Android以及Jetson TK的编译工具链中的汇编器仍然不支持大部分的32位Thumb-2指令，比如 add.w，因此我们只能通过手工写机器指令码来实现想要的指令。下面我将简单地介绍如何在ARM GCC汇编器中手工去写机器指令码。

对于GCC或Clang的汇编器，我们使用 .long 或 .short 来写机器指令码。.long 直接插入在指令汇编中，表示一个 四字节 的整型数据；.short 直接插入在汇编中，表示一个 双字节 的整型数据。

然后，我们举一个add.w指令的例子，由于Android NDK r9d以及当前的Jetson TK1都不支持该指令的汇编。我们先看一下ARM官方对此指令编码的描述：

上图中我们可以看到 add.w 指令有两个双字节构成。而左边的16位放在低地址；而右边的16位放在高地址。这么做的好处是，处理器的译码器（decoder）在Thumb模式下总是从低双字节到高双字节进行解析，而左边的16位编码包含了Thumb指令类别，从而使得译码器可以知道是否当前指令是一条完整的指令，因为Thumb-2有32位宽和16位宽两种形式的指令类别。因此，如果我们要写：

add.w     r0, r0, r1, LSL #1

那么我们就要这么写机器指令码：

.long 0x0041eb00

或者是：

.short 0xeb00
.short 0x0041

这里，imm3 与 imm2 合并成一个5位的移位立即数；两个比特位的type形式如下：

• 00: LSL（逻辑左移）
• 01: LSR（逻辑右移）
• 10: ASR（算术左移）
• 11: 若5位立即数为00000，那么为 RRX（带进位标志的循环右移一位）；否则为 ROR（循环右移）

下面举一个稍微完整的例子：

.text
.align 4

.globl MyASMTest

.thumb

.thumb_func
MyASMTest:

    // add.w        r0, r0, r1, LSL #1
    .long 0x0041eb00

    // equivalent
    .short 0xeb00
    .short 0x0041

    add.w   r1, r0, r12
    adr     r1, MyARMTest
    bx      r1

.arm

MyARMTest:

    movw    r12, #0
    add     r0, r0, r12
    bx      lr

然后，我们可以在C语言中做如下调用：

#include <stdio.h>

extern int MyASMTest(int, int);

int main(void)
{
    int result = MyASMTest(10, 20);
    printf("The result is: %d\n", result);
}

// 最终输出90

经过Google工程师的提醒，对于ARM GCC的汇编器，在汇编文件最上面加入 .syntax unified 之后，Thumb-2 T3 encoding汇编也能正常使用了，比如：

.syntax unified
.text
.align 4
.globl helloThumb

.thumb
.thumb_func
helloThumb:

    add.w    r0, r0, r1, lsl #2
    bx       lr

以上汇编能顺利通过，并与上面那段直接用指令码实现的等价。