excel图表设计：如何让数据变化更加可视化

挖掘数据背后的意义，不能只是单纯的将原始数据，从数字变成图表；而是要让数据变化具现出来，能直观看到其变化形态。

在我们的实际工作中，通常会看到很多类似下面这种架构的数据。

【正文】

因为这样的数据是非常常见的，那么领导就会经常找我们要这些数据，切记一点“报表的呈阅要尽力和清晰明了的图表放在一起”，这样才能有一个比较的直观效果，那么同学你的图表是什么样子的呢？是不是也像下面这些，应付差事就完了！（我们以上面展示的“示例2”的数据为例）

一定会有很多的同学把图表做成这个样子就OK了，上面4个图的样式就不在这里给大家介绍了，无外乎就是选定数据区域，在工具栏中点击“插入”，再选择合适的图表就可以了。但是不得不说，这样一份没有重点的图表，就连“中规中矩”都谈不上吧，那么领导自然也就不会记住你做的什么工作，归根结底就是将本身的数据，从数字变成图形而已，而这但凡是个会操作EXCEL图表的人都可以完成的东西，实在没有什么可以被别人记住的地方！

▲好图表往往都不是源数据做出来的，重要的话说一遍▲

图表说明：由系列积木堆积出一条隐形的等高线，代表12个月的平均数值，超出的部分用橙色标记，不够平均数的用灰色补足。

制作过程：

步骤1：首先处理源数据，如下图所示：

在C2单元格输入函数：

=IF(B2<AVERAGE($B$2:$B$13),B2,AVERAGE($B$2:$B$13))

利用AVERAGE函数计算出12个月数据的平均值，再判断B2单元格的值是否小于平均值，如果小于则返回B2的值，否则返回平均值。下拉填充柄填充函数到C2:C13区域。

在D2单元格输入函数：

=IF(B2<AVERAGE($B$2:$B$13),AVERAGE($B$2:$B$13)-B2,NA())

判断B2单元格的值是否小于平均值，如果小于则返回平均值减去B2数值后的值，否则用NA函数返回#N/A值。这部分就是我们图表中的灰色柱条，使其形成一种视觉上的占位效果。

在E2单元格输入函数：

=IF(B2>=AVERAGE($B$2:$B$13),B2-AVERAGE($B$2:$B$13),NA())

判断B2单元格的值是否大于等于平均值，如果大于等于则返回B2数值减去平均值的值，否则用NA返回#N/A值。这部分表示如果数值大于平均值，就只显示大于部分的柱形条，也就是我们的橙色部分。

步骤2：选中C2:E13单元格区域，点击工具栏“插入”——“图表”——“堆积柱形图”。

这样我们的图表就创建好了，然后就是排版的工作，这里就仁者见仁、智者见智，看同学们自己的偏好和排版功底了。

▲好图表往往都不是源数据做出来的，重要的话说两遍▲

图表说明：这个就是“旋风图”了，也被叫做“漏斗图”，这样的图表最大的意义就是可以把无序的数据按升序或者降序目视化，让观阅者可以很清晰地看出最大值或者最小值。

制作过程：

步骤1：首先处理源数据，如下图所示：

在C2单元格输入函数：

=INDEX($A$2:$A$13,MATCH(LARGE($B$2:$B$13,ROW(C1)),$B$2:$B$13,0))

函数首先使用了LARGE函数结合ROW函数，确定了数据中第N个最大值的数值，再使用MATCH函数确定这个第N大的值在区域中的排列序号，接着使用INDEX函数引用相对序号所对应的A2:A13区域的月份，下拉填充柄填充函数到C2:C13单元格区域，这样就将月份关键字按降序排列出来了。

在E2单元格输入函数：

=VLOOKUP(C2,$A$1:$B$13,2,0)

很常规的VLOOKUP函数的用法，将对应月份的数值引用到E2:E13单元格区域。

在D2单元格输入函数：

{=MAX($E$2:$E$13/2)-E2/2}

这里用了一个数组函数，表示E2:E13单元格区域的值都除以2之后的最大值，再减去E列中对应行的单元格除以2的值，最后下拉填充柄填充函数，就得到了这样一组数据。它的作用是在条形图中形成图形占位，再把此部分的图形“填充、边框”都设置无颜色即可。

步骤2：选中C2:E13单元格区域，在工具栏中点击“插入”——“图表”——“堆积条形图”：

藉此完成，记得把占位的辅助图形的填充和边框，都设置为无颜色，你的旋风图就做好了。

▲好图表往往都不是源数据做出来的，重要的话说三遍▲

图表说明：“半圆饼图”可以让观者在从左到右的浏览，如果是一个圆环的话，势必会让观者上下左右地看，这样容易产生视觉疲劳。我们同样以上例排序的效果来做出饼图，更有层次感，让数据也更加的有重点。

制作过程：

步骤1：首先处理源数据，如下图所示：

在C2单元格输入函数，下拉填充到C2:C13单元格区域

=INDEX($A$2:$A$13,MATCH(LARGE($B$2:$B$13,ROW(C1)),$B$2:$B$13,0))

和上例“旋风图”是一样的，在这里就不做说明了。

在D2单元格输入函数，下拉填充到D2:D13单元格区域

=VLOOKUP(C2,$A$2:$B$13,2,0)

在D14单元格输入函数（或者直接使用“ALT =”组合键做汇总）

=SUM(D2:D13)

做到这里基本上就已经完成饼图源数据的处理了，选中C2:D14单元格区域，在工具栏中点选“插入”——“图表”——“饼图”。

这里注意一下，有可能在你选择插入图表后，只得到了一个“空白的图表”，莫慌，此时我们选中图表，单击鼠标右键，在弹出的菜单中选择“更改图表类型”，如下：

再按下图选择出图表即可。

此时再选中图表的绘图区，在设置数据系列格式中将“第一扇区起始角度”设置为270°，如下图所示。

再按下图所示给图表添加“系列标签”。

再选中数据标注，在标签设置中按下图勾选“类别名称”、“百分比”。当然同学们也可以自由选择想要显示的内容。

但是，对于作者E图表述来说，一般作为饼图系列中的标签内容，很少选择默认的数据，就比如上图的样式，标签是不是显得有些凌乱。所以我们在工作表区域中的E2单元格输入函数，并下拉填充到E2:E13单元格区域。

=C2&" "&TEXT(D2/SUM($D$2:$D$13),"0.0%")

计算出每一行的数值占总体合计的百分比，再用TEXT函数保留一位小数，接着用&连接符连接月份、空格、百分比值，此时再选择标签，在标签设置中，选择“单元格中的值”，就会出现如下窗口，我们把引用区域设置为E2:E13区域，并取消勾选“类别名称”、“百分比”，那么标签就能显示我们需要的内容了，你也可以DIY自己的内容。