0、结果
说明：先来看看串口调试助手显示的结果，当按下按键的时候，按一次会打印一次按键被按下，并且打印是哪个按键被按下。如果是你想要的，可以接着往下看。
1、外观
说明：虽然每个型号的按键形态各异，但是原理和代码都是适用的，只要能保证按下导通，不按下不导通就行。
2、连线
说明：只需要连接两根线，一端和另一端需要保证按下导通，不按下不导通。
uno————按键
GND--------------按键一端
D2--------------按键另一端
3、源程序
说明：对按键进行了消抖，基本上不会存在误触发的可能，按键多了或者少了也可以自行更改，很方便。并将对应功能进行函数化，方便移植。
/****************************************按键 part****************************************/
/*
用到几个按键的话就定义几个引脚，不然引脚悬空的话会误触发!!!
接线：
按键一端接GND，一端接D2~D8，能保证按下导通，不按下不导通就行。
*/
#define startButton 2 //0号按钮
#define buttonPin1 3 //1号按钮
#define buttonPin2 4 //2号按钮
#define buttonPin3 5 //3号按钮
#define buttonPin4 6 //4号按钮
#define buttonPin5 7 //5号按钮
#define buttonPin6 8 //6号按钮
#define buttonON LOW //按钮按下时为低电平
struct Button {
int buttonState = !buttonON; //按钮状态变量，与按钮按下时的状态取反
int lastButtonState = !buttonON; //按钮状态初始化，与按钮按下时的状态取反
long lastDebounceTime = 0; //记录抖动变量
long debounceDelay = 30; //抖动时间变量
bool flag = false; //按钮flag
};
const int buttonPins[7] = {startButton, buttonPin1, buttonPin2, buttonPin3, buttonPin4, buttonPin5, buttonPin6};
Button button, buttons[7]; //新建1个按钮，和按钮数组，数组含有七个按钮
int runCount = 0; //定义一个变量
int buttonCount = 9; //按键号
/****************************************set up and loop part*********************************/
void setup() {
Serial.begin(9600); //初始化串口，波特率为9600
initButtons(); //初始化所有按键串口
}
void loop() {
buttonMonitor(); //按键检测函数
}
/****************************************按键 part****************************************/
/*按钮初始化函数，设置为上拉输入,更加稳定*/
void initButtons() {
for (int i = 0; i < sizeof(buttonPins) / sizeof(buttonPins[0]); i++) {
pinMode(buttonPins[i], INPUT_PULLUP); //适用于多个按钮
}
}
/*按钮输入读取，采用非阻塞式按键消抖，适用于多个按钮*/
void getButton(int _buttonPin, int _buttonIndex) {
int reading = digitalRead(_buttonPin); //读取状态
if (reading != buttons[_buttonIndex].lastButtonState) { //如果状态改变
buttons[_buttonIndex].lastDebounceTime = millis(); //更新时间
} //如果等待大于debounceDelay
if ((millis() - buttons[_buttonIndex].lastDebounceTime) > buttons[_buttonIndex].debounceDelay) {
if (reading != buttons[_buttonIndex].buttonState) { //读取状态不等于按钮状态
buttons[_buttonIndex].buttonState = reading; //更新状态
if (buttons[_buttonIndex].buttonState == buttonON) { //判断按钮是否真的按下
buttonCount = _buttonIndex;
Serial.print(buttonCount); //打印按钮编号
Serial.println(" is pressed"); //输出按钮按下的文字
buttons[_buttonIndex].flag = true; //按钮flag为真
}
else {
buttons[_buttonIndex].flag = false; //按钮flag为假
}
}
}
buttons[_buttonIndex].lastButtonState = reading; //更新last状态
}
/*设备上电之后会误触发按键检测，写这个函数是为了稳定后，再来检测按键的状态*/
void runCountToStable() {
if (runCount < 10) { //防止误触发
runCount++;
}
}
/*按键检测函数*/
void buttonMonitor() {
runCountToStable(); //记录运行次数为了按键检测运行精确
for (int i = 0; i < sizeof(buttonPins) / sizeof(buttonPins[0]); i++) {
getButton(buttonPins[i], i); //适用于多个按钮
}
}4、注意事项
说明：按键有四个引脚或者三个引脚，四个引脚的按键，两个引脚挨得近的是不按下不导通，按下导通；如果是三个引脚的，随便接两个引脚就行。
5、基本原理
在按键被按下时使得电路闭合，从而触发相应的程序操作。按键通常由两个部分组成：一个是用于连接电路的接点（也称为触点或固定触点），另一个是用于控制接点状态的弹簧式机构（也称为活动触点）。
当按键未被按下时，接点处于断开状态，此时电路不通，无法传递电信号。当按键被按下时，机械结构将弹簧压缩，使活动触点与固定触点接触，从而形成闭合电路。在这个过程中，电流可以沿着闭合的电路流通，达到控制相应程序操作的目的。
在Arduino中，按键的工作流程主要包括两个阶段：输入和处理。在输入阶段，当按键被按下时，Arduino会读取对应的数字或模拟输入引脚的电压状态，并将其转换为高或低电平信号。在处理阶段，Arduino根据输入信号的状态进行相应的判断和操作，如执行特定函数、调用模块等操作。
6、消抖的方法
采用软件消抖的原理是通过编程实现，在按键被按下后，通过程序进行一定的处理和判断，使得系统仅响应有效的按键操作，避免因按键抖动等原因产生误触发现象。
具体来说，软件消抖的原理主要包括以下几个步骤：
-
读取按键状态：首先需要读取按键状态，即检测输入引脚的电平是否发生变化（从高电平到低电平）。可以使用Arduino中的digitalRead函数实现该功能。
-
延时消抖：当检测到按键状态发生变化时，需要延时一段时间，以等待按键抖动消除。可以使用Arduino中的delay函数或借助定时器实现延时功能。
-
再次读取按键状态：在延时结束后，需要再次读取按键状态，并与之前的状态比较，以确定是否发生有效的按键操作。只有当两次读取的状态相同，且状态为低电平时，才表示发生了有效的按键操作。
