0、结果

说明：先来看看串口调试助手显示的结果，第一个值是原始的模拟电压值，第二个值是含水量，如果是你想要的，可以接着往下看。

1、外观

说明：虽然土壤湿度传感器形态各异，但是原理和代码都是适用的。

2、连线

说明：只需要连接三根线。
uno————土壤湿度传感器

5V--------------VCC
GND--------------GND

A0--------------A0

3、源程序

说明：采用非阻塞方式编写，一定时间检测一次土壤湿度，并将对应功能进行函数化，方便移植。

/****************************************soil part****************************************/
/*
  Note:
  It is necessary to test the simulated value of completely dry soil first,
  and then measure the simulated value of soaked water.
  These two values are the values of 0~100 water content,
  and the other water content is within this range.
  Because the simulated value is inversely proportional to the water content,
  it needs to be looked at backwards.
*/
#define maxSoil 1024                                                    //The maximum value of the soil read
#define minSoil 400                                                     //Minimum value read from the soil
#define soilTimeInterval 1000                                           //Soil moisture was measured once every 1000 milliseconds
#define soilHumPin A0                                                   //A0 Indicates the original read data

unsigned long soilTimes = 0;                                            //Record the device running time
int soilHumidityData = 0;                                               //Current measured air humidity
int soilWaterContent = 0;                                               //Water content in soil
/***********************************set up and loop part*********************************/
void setup() {
  Serial.begin(9600);                                                   // open serial port, set the baud rate to 9600 bps

  Serial.println("Go online！");
}
void loop() {
  getSoilHumData();                                                     //Soil moisture acquisition
}
/****************************************soil part****************************************/
/*Soil moisture acquisition*/
void getSoilHumData() {
  if (millis() - soilTimes >= soilTimeInterval) {
    soilTimes = millis();
    
    soilHumidityData = analogRead(soilHumPin);                          //Obtain the soil moisture value
    soilHumidityData = constrain(soilHumidityData, minSoil, maxSoil);   //Limit the fetched values to a range
    soilWaterContent = map(soilHumidityData, minSoil, maxSoil, 100, 0); //Map the restricted value to the water content

    Serial.print("Original value: ");
    Serial.print(soilHumidityData);                                     // The serial port displays the corresponding value
    Serial.print(" , ");
    Serial.print(" Water content: ");
    Serial.print(soilWaterContent);                                     // The serial port displays the corresponding value
    Serial.println(" %");
  }
}