目录
- 一、类文件结构
- 1、魔术
- 2、版本
- 3、常量池
- 二、字节码指令
- 1、javap工具
- 2、图解方法执行流程
- 3、通过字节码指令来分析问题
- 4、构造方法
- 5、方法调用
- 6、多态原理——HSDB
- 7、异常处理
- 四、类加载阶段
- 五、类加载器
- 六、运行期优化
一、类文件结构
以一个简单的HelloWord.java程序为例
// HelloWord示例
public class HelloWord {
public static void main(String[] args) {
System.out.println("HelloWord");
}
}
首先获得.class字节码文件
方法：
● 在文本文档里写入java代码（文件名与类名一致），将文件类型改为.java
● java终端中，执行javac X:…\XXX.java
-parameters参数：保留方法中参数的名称信息
编译后的字节码文件
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07
0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29
0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e
0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 12 4c 6f 63
0000120 61 6c 56 61 72 69 61 62 6c 65 54 61 62 6c 65 01
0000140 00 04 74 68 69 73 01 00 1d 4c 63 6e 2f 69 74 63
0000160 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c 6f
0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16
0000220 28 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72
0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13
0000260 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69
0000300 6e 67 3b 01 00 10 4d 65 74 68 6f 64 50 61 72 61
0000320 6d 65 74 65 72 73 01 00 0a 53 6f 75 72 63 65 46
0000340 69 6c 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64
0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e
0000400 00 1f 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64
0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74
0000440 63 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c
0000460 6f 57 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61
0000500 6e 67 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61
0000520 2f 6c 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f
0000540 75 74 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72
0000560 69 6e 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76
0000600 61 2f 69 6f 2f 50 72 69 6e 74 53 74 72 65 61 6d
0000620 01 00 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a
0000640 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69 6e 67 3b
0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01
0000700 00 07 00 08 00 01 00 09 00 00 00 2f 00 01 00 01
0000720 00 00 00 05 2a b7 00 01 b1 00 00 00 02 00 0a 00
0000740 00 00 06 00 01 00 00 00 04 00 0b 00 00 00 0c 00
0000760 01 00 00 00 05 00 0c 00 0d 00 00 00 09 00 0e 00
0001000 0f 00 02 00 09 00 00 00 37 00 02 00 01 00 00 00
0001020 09 b2 00 02 12 03 b6 00 04 b1 00 00 00 02 00 0a
0001040 00 00 00 0a 00 02 00 00 00 06 00 08 00 07 00 0b
0001060 00 00 00 0c 00 01 00 00 00 09 00 10 00 11 00 00
0001100 00 12 00 00 00 05 01 00 10 00 00 00 01 00 13 00
0001120 00 00 02 00 14
根据 JVM 规范，类文件结构如下
ClassFile {
u4 magic // 魔术 (u4——>前四个字节)
u2 minor_version; // 小版本号
u2 major_version; // 主版本号
u2 constant_pool_count; // 常量池信息
cp_info constant_pool[constant_pool_count-1]; // 常量池信息
u2 access_flags; // 访问修饰
u2 this_class; // 类名、包名信息
u2 super_class; // 父类信息
u2 interfaces_count; // 接口信息
u2 interfaces[interfaces_count]; // 接口信息
u2 fields_count; // 类中的变量信息（成员变量、静态变量......）
field_info fields[fields_count]; // 类中的变量信息（成员变量、静态变量......）
u2 methods_count; // 类中的方法信息（成员方法、静态方法......）
method_info methods[methods_count]; // 类中的方法信息（成员方法、静态方法......）
u2 attributes_count; // 类的附加属性信息
attribute_info attributes[attributes_count]; // 类的附加属性信息
}
1、魔术
0~3字节，表示它是否是【class】类型的文件 ===>ca fe ba be标识一个java类型的文件
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
2、版本
u2 major_version
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
4~7字节，表示类的版本34H = 52，代表JDK8
3、常量池
8~9字节，便是常量池长度，00 23 (35) 表示常量池有 #1~#34项不计入，也没有值
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
第 #1项0a表示一个Method信息，00 06 和00 15 （21） 表示它引用了常量池中的 #6和 #21 项来获得这个方法的【所属类】和【方法名】
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
第 #2项09表示一个Filed信息，00 06（22） 和00 17 （23） 表示它引用了常量池中的 #22和 #23 项来获得这个成员变量的【所属类】和【成员变量名】
0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
…
二、字节码指令
可参考
https://docs.oracle.com/javase/specs/jvms/se8/html/jvms-6.html#jvms-6.5
1、javap工具
自己分析类文件结构较麻烦，因此Oracle 提供了 javap 工具来反编译 class 文件
javap -v F:\Thread_study\src\com\nyima\JVM\day01\Main.class （-v：输出类文件的详细信息）
2、图解方法执行流程
① 原始代码
/**
* 演示 字节码指令 和 操作数栈、常量池的关系
* /
public class Demo3_1 {
public static void main(String[] args) {
int a = 10;
int b = Short.MAX_VALUE + 1;
int c = a + b;
System.out.println(c);
}
}
② 编译后字节码文件…
③ 常量池载入运行时常量池
常量池也属于方法区，只不过这里单独提出来了
④ 方法字节码载入方法区
（stack=2，locals=4） 对应操作数栈有2个空间（每个空间4个字节），局部变量表中有4个槽位
⑤ main线程开始执行，分配栈帧内存执行
（stack=2，locals=4）
⑥ 执行引擎开始执行字节码
bipush 10
● 将一个 byte 压入操作数栈（其长度会补齐 4 个字节），类似的指令还有
sipush 将一个 short 压入操作数栈（其长度会补齐 4 个字节）
ldc 将一个 int 压入操作数栈
ldc2_w 将一个 long 压入操作数栈（分两次压入，因为 long 是 8 个字节）
这里小的数字都是和字节码指令存在一起，超过 short 范围的数字存入了常量池
istore 1
将操作数栈栈顶元素弹出，放入局部变量表的slot 1中
对应代码中的
a = 10
ldc #3
读取运行时常量池中#3，即32768(超过short最大值范围的数会被放到运行时常量池中)，将其加载到操作数栈中
注意 Short.MAX_VALUE 是 32767，所以 32768 = Short.MAX_VALUE + 1 实际是在编译期间计算好的
istore 2
将操作数栈中的元素弹出，放到局部变量表的2号位置
iload1 iload2
将局部变量表中1号位置和2号位置的元素放入操作数栈中
● 因为只能在操作数栈中执行运算操作
iadd
将操作数栈中的两个元素弹出栈并相加，结果在压入操作数栈中
istore 3
将操作数栈中的元素弹出，放入局部变量表的3号位置
getstatic #4
在运行时常量池中找到#4，发现是一个对象
在堆内存中找到该对象，并将其引用放入操作数栈中
iload 3
将局部变量表中3号位置的元素压入操作数栈中
invokevirtual 5
找到常量池 #5 项，定位到方法区 java/io/PrintStream.println:(I)V 方法
生成新的栈帧（分配 locals、stack等）
传递参数，执行新栈帧中的字节码
执行完毕，弹出栈帧
清除 main 操作数栈内容
return
完成 main 方法调用，弹出 main 栈帧，程序结束
3、通过字节码指令来分析问题
目的：从字节码角度分析 a++ 相关题目
源码：
字节码：
public static void main(java.lang.String[]);
descriptor: ([Ljava/lang/String;)V
flags: ACC_PUBLIC, ACC_STATIC
Code:
stack=2, locals=3, args_size=1
0: bipush 10
2: istore_1
3: iload_1
4: iinc 1, 1
7: iinc 1, 1
10: iload_1
11: iadd
12: iload_1
13: iinc 1, -1
16: iadd
17: istore_2
18: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
21: iload_1
22: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
25: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
28: iload_2
29: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
32: return
LineNumberTable:
line 6: 0
line 7: 3
line 8: 18
line 9: 25
line 10: 32
LocalVariableTable:
Start Length Slot Name Signature
0 33 0 args [Ljava/lang/String;
3 30 1 a I
18 15 2 b I
}
分析：
● iinc指令是直接在局部变量slot上进行计算
● a++（先iload再自增）和++a（先iinc再iload）的区别是先执行iload还是先执行iinc
练习——分析X=0
请从字节码角度分析，下列代码运行的结果：
通过分析字节码指令即可知晓
Code:
stack=2, locals=3, args_size=1 //操作数栈分配2个空间，局部变量表分配3个空间
0: iconst_0 //准备一个常数0
1: istore_1 //将常数0放入局部变量表的1号槽位 i=0
2: iconst_0 //准备一个常数0
3: istore_2 //将常数0放入局部变量的2号槽位 x=0
4: iload_1 //将局部变量表1号槽位的数放入操作数栈中
5: bipush 10 //将数字10放入操作数栈中，此时操作数栈中有2个数
7: if_icmpge 21 //比较操作数栈中的两个数，如果下面的数大于上面的数，就跳转到21。这里的比较是将两个数做减法。因为涉及运算操作，所以会将两个数弹出操作数栈来进行运算。运算结束后操作数栈为空
10: iload_2 //将局部变量2号槽位的数放入操作数栈中，放入的值是0
11: iinc 2, 1 //将局部变量2号槽位的数加1，自增后，槽位中的值为1
14: istore_2 //将操作数栈中的数放入到局部变量表的2号槽位，2号槽位的值又变为了0
15: iinc 1, 1 //1号槽位的值自增1
18: goto 4 //跳转到第4条指令
21: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
24: iload_2
25: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
28: return
将x=0放入局部变量表中，x++首先执行iload_x（将局部变量表中的0读进操作数栈中）再执行iinc x1（局部变量表中自增1），然后再执行赋值操作（将操作数栈中的0覆盖本地变量x）
4、构造方法
① cinit()V （整个类的构造方法）
public class Demo3 {
static int i = 10;
static {
i = 20;
}
static {
i = 30;
}
public static void main(String[] args) {
System.out.println(i); //结果为30
}
}
编译器会按从上至下的顺序，收集所有 static 静态代码块和静态成员赋值的代码，合并为一个特殊的方法 cinit()V ：
stack=1, locals=0, args_size=0
0: bipush 10
2: putstatic #3 // Field i:I
5: bipush 20
7: putstatic #3 // Field i:I
10: bipush 30
12: putstatic #3 // Field i:I
15: return
② init()V（每个实例对象的构造方法）
public class Demo4 {
private String a = "s1";
{
b = 20;
}
private int b = 10;
{
a = "s2";
}
public Demo4(String a, int b) {
this.a = a;
this.b = b;
}
public static void main(String[] args) {
Demo4 d = new Demo4("s3", 30);
System.out.println(d.a);
System.out.println(d.b);
}
}
编译器会按从上至下的顺序，收集所有 {} 代码块和成员变量赋值的代码，形成新的构造方法，但原始构造方法内的代码总是在后
Code:
stack=2, locals=3, args_size=3
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: aload_0
5: ldc #2 // String s1
7: putfield #3 // Field a:Ljava/lang/String;
10: aload_0
11: bipush 20
13: putfield #4 // Field b:I
16: aload_0
17: bipush 10
19: putfield #4 // Field b:I
22: aload_0
23: ldc #5 // String s2
25: putfield #3 // Field a:Ljava/lang/String;
//原始构造方法在最后执行
28: aload_0
29: aload_1
30: putfield #3 // Field a:Ljava/lang/String;
33: aload_0
34: iload_2
35: putfield #4 // Field b:I
38: return
5、方法调用
public class Demo5 {
public Demo5() {
}
private void test1() {
}
private final void test2() {
}
public void test3() {
}
public static void test4() {
}
public static void main(String[] args) {
Demo5 demo5 = new Demo5();
demo5.test1();
demo5.test2();
demo5.test3();
Demo5.test4();
}
}
不同方法在调用时，对应的虚拟机指令有所区别
● 私有、构造、被final修饰的方法，在调用时都使用invokespecial指令
● 普通成员方法在调用时，使用invokevirtual指令。因为编译期间无法确定该方法的内容（普通的Public方法有可能出现方法重写的情况，因此再编译期间不能确定调用哪个对象的方法，可能是子类的、可能是父类的），只有在 运行期间才能确定
● 静态方法在调用时使用invokestatic指令
Code:
stack=2, locals=2, args_size=1
0: new #2 // class com/nyima/JVM/day5/Demo5
3: dup
4: invokespecial #3 // Method "<init>":()V
7: astore_1
8: aload_1
9: invokespecial #4 // Method test1:()V
12: aload_1
13: invokespecial #5 // Method test2:()V
16: aload_1
17: invokevirtual #6 // Method test3:()V
20: invokestatic #7 // Method test4:()V
23: return
● new 是创建【对象】，给对象分配堆内存，执行成功会将【对象引用】压入操作数栈
● dup 是赋值操作数栈栈顶的内容，本例即为【对象引用】，为什么需要两份引用呢，一个是要配合 invokespecial 调用该对象的构造方法 “init”: ()V（会消耗掉栈顶一个引用），另一个要 配合 astore_1 赋值给局部变量
● 终方法（final），私有方法（private），构造方法都是由 invokespecial 指令来调用，属于静态绑定
● 普通成员方法是由 invokevirtual 调用，属于动态绑定，即支持多态 成员方法与静态方法调用的另一个区别是，执行方法前是否需要【对象引用】
多态原理
6、多态原理——HSDB
因为普通成员方法需要在运行时才能确定具体的内容，所以虚拟机需要调用invokevirtual指令
在执行invokevirtual指令时，经历了以下几个步骤（可运行HSDB工具查看）
● 先通过栈帧中的对象引用找到对象
● 分析对象头（对象头中有八个字节是其对象Class类型的实际地址），找到对象实际的Class
● Class结构中有vtable
● 查询vtable找到方法的具体地址
● 执行方法的字节码
7、异常处理
① 异常——catch
try-catch
public class Demo1 {
public static void main(String[] args) {
int i = 0;
try {
i = 10;
}catch (Exception e) {
i = 20;
}
}
}
对应字节码指令
Code:
stack=1, locals=3, args_size=1
0: iconst_0
1: istore_1
2: bipush 10
4: istore_1
5: goto 12
8: astore_2
9: bipush 20
11: istore_1
12: return
//多出来一个异常表
Exception table:
from to target type
2 5 8 Class java/lang/Exception
● 可以看到多出来一个 Exception table 的结构，[from, to) 是前闭后开（也就是检测2~4行）的检测范围，一旦这个范围内的字节码执行出现异常，则通过 type 匹配异常类型，如果一致，进入 target 所指示行号
● 8行的字节码指令 astore_2 是将异常对象引用存入局部变量表的2号位置（为e）
② 异常——多个catch
多个single-catch
public class Demo1 {
public static void main(String[] args) {
int i = 0;
try {
i = 10;
}catch (ArithmeticException e) {
i = 20;
}catch (Exception e) {
i = 30;
}
}
}
对应的字节码
Code:
stack=1, locals=3, args_size=1
0: iconst_0
1: istore_1
2: bipush 10
4: istore_1
5: goto 19
8: astore_2
9: bipush 20
11: istore_1
12: goto 19
15: astore_2
16: bipush 30
18: istore_1
19: return
Exception table:
from to target type
2 5 8 Class java/lang/ArithmeticException
2 5 15 Class java/lang/Exception
● 因为异常出现时，只能进入 Exception table 中一个分支，所以局部变量表 slot 2 位置被共用
③ 异常——finally
finally
public class Demo2 {
public static void main(String[] args) {
int i = 0;
try {
i = 10;
} catch (Exception e) {
i = 20;
} finally {
i = 30;
}
}
}
对应字节码
Code:
stack=1, locals=4, args_size=1
0: iconst_0
1: istore_1
//try块
2: bipush 10
4: istore_1
//try块执行完后，会执行finally
5: bipush 30
7: istore_1
8: goto 27
//catch块
11: astore_2 //异常信息放入局部变量表的2号槽位
12: bipush 20
14: istore_1
//catch块执行完后，会执行finally
15: bipush 30
17: istore_1
18: goto 27
//出现异常，但未被Exception捕获，会抛出其他异常，这时也需要执行finally块中的代码
21: astore_3
22: bipush 30
24: istore_1
25: aload_3
26: athrow //抛出异常
27: return
Exception table:
from to target type
2 5 11 Class java/lang/Exception
2 5 21 any
11 15 21 any
可以看到 finally 中的代码被复制了 3 份，分别放入 try 流程，catch 流程以及 catch剩余的异常类型流程
注意：虽然从字节码指令看来，每个块中都有finally块，但是finally块中的代码只会被执行一次
④ finally——面试题1
finally中出现return（下面结果输出什么？）
对应字节码
● 由于 finally 中的 ireturn 被插入了所有可能的流程，因此返回结果肯定以finally的为准
● 如果在 finally 中出现了 return，会吞掉异常
● 所以不要在finally中进行返回操作
会发现打印结果为20，并未抛出异常
⑤ finally——面试题2
对应字节码
Code:
stack=1, locals=3, args_size=0
0: bipush 10
2: istore_0 //赋值给i 10
3: iload_0 //加载到操作数栈顶
4: istore_1 //加载到局部变量表的1号位置 （目的是为了固定返回值）
5: bipush 20
7: istore_0 //赋值给i 20
8: iload_1 //加载局部变量表1号位置的数10到操作数栈
9: ireturn //返回操作数栈顶元素 10
10: astore_2
11: bipush 20
13: istore_0
14: aload_2 //加载异常
15: athrow //抛出异常
Exception table:
from to target type
3 5 10 any
⑥ Synchronized
public class Demo5 {
public static void main(String[] args) {
int i = 10;
Lock lock = new Lock();
synchronized (lock) {
System.out.println(i);
}
}
}
class Lock{}
对应字节码
Code:
stack=2, locals=5, args_size=1
0: bipush 10
2: istore_1
3: new #2 // class com/nyima/JVM/day06/Lock
6: dup //复制一份，放到操作数栈顶，用于构造函数消耗
7: invokespecial #3 // Method com/nyima/JVM/day06/Lock."<init>":()V
10: astore_2 //剩下的一份放到局部变量表的2号位置
11: aload_2 //加载到操作数栈
12: dup //复制一份，放到操作数栈，用于加锁时消耗
13: astore_3 //将操作数栈顶元素弹出，暂存到局部变量表的三号槽位。这时操作数栈中有一份对象的引用
14: monitorenter //加锁
//锁住后代码块中的操作
15: getstatic #4 // Field java/lang/System.out:Ljava/io/PrintStream;
18: iload_1
19: invokevirtual #5 // Method java/io/PrintStream.println:(I)V
//加载局部变量表中三号槽位对象的引用，用于解锁
22: aload_3
23: monitorexit //解锁
24: goto 34
//异常操作
27: astore 4
29: aload_3
30: monitorexit //解锁
31: aload 4
33: athrow
34: return
//可以看出，无论何时出现异常，都会跳转到27行，将异常放入局部变量中，并进行解锁操作，然后加载异常并抛出异常。
Exception table:
from to target type
15 24 27 any
27 31 27 any
