Day5-Hive的结构和优化、数据文件存储格式

news2024/11/18 18:42:59

Hive

窗口函数

案例

  1. 需求：连续三天登陆的用户数据

  2. 步骤：

    -- 建表
create table logins (
    username string,
    log_date string
) row format delimited fields terminated by ' ';
-- 加载数据
load data local inpath '/opt/hive_data/login' into table logins;
-- 查询数据
select *
from logins tablesample (5 rows);
-- 按用户分组，将登陆日期进行排序
-- over(partition by xxx order by xxx)
-- 获取每一条数据两行之前的数据
select *, 
       lag(log_date, 2) over (partition by username order by log_date) as 2d_log_date
from logins;
-- 获取连续三天登录的数据
select distinct username
from (
    select *, 
           lag(log_date, 2) over (partition by username order by log_date) as 2d_log_date
    from logins
) t where datediff(log_date, 2d_log_date) = 2;

其他操作

join

  1. 同MySQL类似，在Hive中也提供了表之间的join，包含：内连接inner join，左连接left join，右连接right join和全外连接full outer join以及极少使用的笛卡尔积

  2. 除此之外，Hive还提供了特殊的连接：left semi join。当a left semi join b，表示获取a表哪些数据在b表中出现过

  3. 案例

    -- 建表
drop table if exists orders;
create table orders (
    order_id   int,
    order_date string,
    product_id int,
    number     int
) row format delimited fields terminated by ' ';
drop table if exists products;
create table products (
    product_id   int,
    product_name string,
    price        double
) row format delimited fields terminated by ' ';
-- 加载数据
load data local inpath '/opt/hive_data/orders' into table orders;
load data local inpath '/opt/hive_data/products' into table products;
select *
from orders;
select *
from products;
-- 需求一：获取每天卖了多少钱
select o.order_date,
       sum(o.number * p.price)
from orders o left join products p 
    on o.product_id = p.product_id
group by o.order_date;
-- 需求二：获取哪些商品被卖出去过
-- 获取商品表中的哪些数据在订单表中出现过
-- 方式一：left semi join
select *
from products p left semi join orders o
              on p.product_id = o.product_id;
-- 方式二：
select * from products
where product_id in (select product_id from orders);

排序

  1. 不同于MySQL的地方在于，在Hive中，提供了两种排序方式

    1. order by：全局排序。在排序的时候，会忽略掉ReduceTask的数量，对所有的数据进行整体的排序
    2. sort by：局部排序。这种方式，在每一个ReduceTask内部排序。如果没有指定，那么会根据排序字段，计算字段的哈希码，然后将字段分发到对应到ReduceTask上来进行排序

  2. 案例

    1. 原始数据

      2 henry 84
3 jack 76
1 david 92
1 bruce 78
1 balley 77
2 hack 85
1 tom 79
3 peter 96
2 eden 92
1 mary 85
3 pard 61
3 charles 60
2 danny 94
3 cindy 75

    2. 案例

      -- 建表
drop table if exists scores;
create table scores (
    class int,
    name  string,
    score int
) row format delimited fields terminated by ' ';
-- 加载数据
load data local inpath '/opt/hive_data/scores' into table scores;
-- 查询数据
select *
from scores tablesample (5 rows);
-- order by
insert overwrite local directory '/opt/hive_demo/order_by1'
    row format delimited fields terminated by '\t'
select * from scores order by score;
-- sort by
insert overwrite local directory '/opt/hive_demo/sort_by1'
    row format delimited fields terminated by '\t'
select * from scores sort by score;
-- Hive中的SQL默认会转化为MapReduce任务来执行
-- 在MapReduce中，如果不指定，默认只有1个ReduceTask
-- 因此也只产生1个结果文件
-- 指定ReduceTask的个数
set mapreduce.job.reduces = 3;
insert overwrite local directory '/opt/hive_demo/order_by2'
    row format delimited fields terminated by '\t'
select * from scores order by score;
insert overwrite local directory '/opt/hive_demo/sort_by2'
    row format delimited fields terminated by '\t'
select * from scores sort by score;
-- 在实际过程中，其实极少单独使用sort by
-- sort by一般是结合distribute by来使用
-- 案例：将每一个班的学生按照成绩降序排序
insert overwrite local directory '/opt/hive_demo/distribute_by'
    row format delimited fields terminated by '\t'
select * from scores distribute by class sort by score desc;

  3. 如果distribute by和sort by的字段一致，那么可以省略为cluster by。注意，cluster by默认只能升序不能降序排序

beeline和JDBC

  1. JDBC(Java Database Connection)：类似于MySQL，Hive也提供了JDBC操作，代码和MySQL的JDBC操作一模一样

    package com.fesco.jdbc;

import java.sql.*;

public class HiveJDBCDemo {

    public static void main(String[] args) throws ClassNotFoundException, SQLException {

        // 注册驱动
        Class.forName("org.apache.hive.jdbc.HiveDriver");
        // 获取连接
        // Hive对外提供的连接端口是10000
        Connection connection = DriverManager.getConnection("jdbc:hive2://101.36.69.196:31177/demo", "root", "root");
        // 获取表述
        Statement statement = connection.createStatement();
        // 执行SQL
        ResultSet resultSet = statement.executeQuery("select * from products");
        // 遍历结果集
        while(resultSet.next()){
            System.out.println(resultSet.getString("product_name"));
        }
        // 关闭
        resultSet.close();
        statement.close();
        connection.close();

    }

}

  2. 利用Datagrip连接Hive，实际上就是用JDBC的方式连接的Hive

  3. Hive提供了原生的远程连接方式：beeline

    beeline -u jdbc:hive2://hadoop01:10000/demo -n root

    -u表示url，连接地址；-n表示name，用户名

  4. 注意：如果想要使用JDBC的方式连接Hive，那么必须开启hiveserver2服务！！！

SerDe

  1. SerDe(Serializar-Deserializar)：是Hive中提供的一套用于进行序列化和反序列化操作的机制

  2. 可以利用SerDe来解决数据的格式问题

  3. 案例

    -- 不使用SerDe
-- 1. 建表管理原始数据
create table logs_tmp (
    log string
);
load data local inpath '/opt/hive_data/logs' into table logs_tmp;
select * from logs_tmp tablesample (5 rows);
-- 2. 建表
create table logs (
    user_ip     string, -- 用户ip
    log_date    string, -- 访问日期和时间
    timezone    string, -- 时区
    request_way string, -- 请求方式
    resources   string, -- 请求资源
    protocol    string, -- 请求协议
    state_id    int     -- 状态码
) row format delimited fields terminated by '\t';
-- 3. 先将数据替换为规则形式，然后利用split拆分
insert into table logs
select arr[0], arr[1], arr[2], arr[3], arr[4], arr[5], cast(arr[6] as int)
from (
   select split(regexp_replace(log, '(.*) \-\- \\[(.*) (.*)\\] \"(.*) (.*) (.*)\" (.*) \-', '$1 $2 $3 $4 $5 $6 $7'), ' ') arr from logs_tmp
) t;
-- 查询数据
select * from logs;
-- 使用SerDe
-- 建表
drop table if exists logs;
create table logs (
    user_ip     string, -- 用户ip
    log_date    string, -- 访问日期和时间
    timezone    string, -- 时区
    request_way string, -- 请求方式
    resources   string, -- 请求资源
    protocol    string, -- 请求协议
    state_id    int     -- 状态码
) row format serde 'org.apache.hadoop.hive.serde2.RegexSerDe'
  with serdeproperties (
      'input.regex'='(.*) \-\- \\[(.*) (.*)\\] \"(.*) (.*) (.*)\" (.*) \-'
  ) stored as textfile ;
load data local inpath '/opt/hive_data/logs' into table logs;
select * from logs;

视图(view)

  1. 视图是对原表中部分字段进行抽取，可以看作是原表的子表，但是本质上是一个虚拟表

  2. 当不需要表中所有的字段，而只需要这个表中的部分字段的时候，那么此时就可以使用视图来对数据进行封装

  3. 视图只能看不能修改！

  4. 视图的优点

    1. 简单。使用视图的时候，完全不需要关心视图背后依赖的表结构是否发生变化，是否产生关联。对于用户而言，视图就是已经符合过滤条件的结果集
    2. 安全。用户只被允许访问视图中已经过滤好的数据，并且视图中的数据只能查不能改，此时不会影响基表的数据
    3. 数据独立。一旦视图创建，那么此时基表发生结构变化，不会影响视图的操作

  5. Hive中，在定义视图的时候，需要封装一个select语句。此时，被封装的这个select在创建视图的时候并不会执行；而是会在第一次查询视图的时候才会触发封装的select执行

  6. 视图分为虚拟视图(只存储在内存中，可以认为是一个虚拟表)和物化视图(会落地到磁盘上，此时就是一个真正的子表)。需要注意的是，Hive只支持虚拟视图不支持物化视图

  7. 案例

    -- 创建视图
create view logs_view as select user_ip, log_date, resources from logs order by log_date;
-- 查询视图
select * from logs_view;
-- 删除视图
drop view logs_view;

Hive存储

概述

  1. Hive中的数据最终是以文件形式落地到HDFS上，目前Hive官方原生的文件格式有6种：textfile，RCFile，orc，parquet，avro和sequencefile
    1. avro和sequencefile将文件以序列形式来存储(序列化文件)
    2. 如果不指定，那么HDFS默认将文件以textfile格式存储
    3. textfile，avro和sequencefile是行存储格式，RCFile，orc和parquet是列存储格式
    4. textfile不支持修改(delete和update)，但是列存储格式都支持delete和update操作，效率非常低

textfile

  1. Hive中的文件格式默认就是textfile
  2. 默认情况下，textfile不对数据进行压缩，因此占用磁盘空间相对较大；在进行数据分析的时候，开销相对也较大
  3. textfile支持Gzip和Bzip2的压缩格式

orc

  1. orc(Optimized Row Columnar，优化的行列格式)，是Hive0.11版本引入的一种文件格式，是基于RCFile格式机型优化，本身是以列存储形式来存放数据
  2. 每一个ORC文件，由1个File Footer、1个Postscript以及1到多个Stripe来组成
  3. Stripe：用于存储数据的。默认情况下，每一个Stripe的大小是250M。Stripe由三部分组成
    1. Index Data：索引数据。默认每隔10000行数据形成一次索引，会记录每一列的最小值、最大值、以及每一列中的行索引
    2. Row Data：行数据。在存储数据的时候，不是将整个表的列来进行拆分，而是先截取部分行，然后将每一行数据的字段来进行拆分。因为同一列中的字段类型是一致的，所以可以给不同的列来指定的压缩机制进行更好的压缩
    3. Stripe Footer：记录每一列的数据类型、每一列的字节长度
  4. File Footer：记录每一个Stripe中包含的行数以及每一列的数据类型。初次之外，File Footer还可以记录每一列的聚合信息，例如sum、max等
  5. Postscript：记录了整个文件的信息，例如文件是否压缩，压缩编码是什么，以及File Footer在orc文件中的从存储位置
  6. 如果需要在ORC文件中查询某一条数据：
    1. 首先从文件末尾读取Postscript，从Postscript中获取到File Footer在文件中的存储位置
    2. 然后读取File Footer，从File Footer中获取这条数据所在的Stripe的位置
    3. 读取Stripe中的Index Data，锁定这条数据对应的索引位置，最后再通过Row Data获取到这条数据

parquet格式

  1. parquet格式是从Hive0.10版本开始提供的一种二进制的文件格式，所以不能直接读取
  2. 每一个parquet文件中，包含了四部分
    1. Magic Code：魔数，用于确保当前的文件是一个parquet文件
    2. Footer Length：记录元数据的大小。通过这个值以及parquet文件的大小，可以计算出元数据在parquet文件中的偏移量
    3. Metastore：元数据存储，记录了当前parquet文件的文件信息，以及文件大小、Row Group的数量
    4. Row Group：行组
      1. 将文件从行方向上进行切分，每一部分就是一个Row Group。默认情况下，Row Group和Block是等大的
      2. 每一个行组中，又包含了1个到多个Column Chunk(列块)。每一列对应了一个列块。因为同一个列块中的数据类型相同，所以可以给不同的列块指定不同的压缩编码
      3. 每一个列块中包含了一个到多个Page(页)。Page是parquet文件中数据存储的最小单位
      4. Page分为三种
        1. 数据页：存储数据
        2. 字典页：存储编码信息
        3. 索引页：记录存储的数据在文件中的偏移量
      5. 需要注意的是，Hive提供的原生的parquet文件不支持索引页
  3. parquet格式支持LZO和snappy压缩

Hive压缩

  1. Hive支持对结果文件进行压缩。其中，经常对orc和parquet文件进行压缩

  2. orc文件压缩可以通过属性orc.compress来配置压缩，可以使用的值：NONE，ZLIB和SNAPPY。NONE表示不压缩

    create table orc_test (
    id   int,
    name string,
    age  int
) row format delimited fields terminated by ' '
    stored as orc; -- 以orc格式来存储
insert into table orc_test values (1, 'Amy', 15);

create table orc_zlib (
    id   int,
    name string,
    age  int
) row format delimited fields terminated by ' '
    stored as orc
    tblproperties ('orc.compress' = 'ZLIB');
insert into table orc_zlib values (1, 'Amy', 15);

create table orc_snappy (
    id   int,
    name string,
    age  int
) row format delimited fields terminated by ' '
    stored as orc
    tblproperties ("orc.compress" = "SNAPPY");
insert into table orc_snappy values (1, 'Amy', 15);

  3. parquet文件压缩可以通过属性parquet.compression进行配置。可以使用的值：NONE和SNAPPY

    create table parquet_test (
    id   int,
    name string,
    age  int
) row format delimited fields terminated by ' '
    stored as parquet; -- 以parquet形式来存储数据
insert into table parquet_test values (1, 'May', 15);

create table parquet_snappy (
    id   int,
    name string,
    age  int
) row format delimited fields terminated by ' '
    stored as parquet
    tblproperties ("parquet.compression" = "SNAPPY");
insert into table parquet_snappy values (1, 'May', 15);

Hive结构和优化

结构

Hive结构
  1. Client Interface：客户端端口，包含CLI(Command-line，命令行)和JDBC两种方式
  2. 客户端连接Client Interface，提交要执行的SQL。这个SQL会被提交给Driver(驱动器)
  3. Driver包含了4部分
    1. SQL Parser：SQL解析器，SQL提交给Driver之后，会先有SQL Parser进行解析，在解析的时候，先去检查SQL的语法是否正确，会连接元数据库查询/修改元数据，然后将SQL转化为抽象语法树(AST)
    2. Physical Plan：物理计划。SQL Parser将SQL解析成AST之后，将AST交给Physical PLAN，将AST编译成具体的执行逻辑
    3. Query Optimizer：查询优化器。Physical PLAN将执行逻辑交给Query Optimizer进行优化
    4. Execution：执行器。负责将优化之后的执行逻辑转化成具体的执行任务，例如将执行逻辑转化为MapReduce程序

优化

  1. 列裁剪或者分区裁剪。在实际生产环境中，经常需要处理大量的数据，那么此时使用select * from x的形式，会对整个表进行扫描，从而导致查询效率变低。因此在实际过程中，最好执行列或者指定分区进行查询；如果需要进行按行的查询，那么最好限制查询的行数，例如使用limit n或者tablesample(n rows)

  2. group by的优化。在进行group by的时候，那么此时相同的键对应的值会被分到一组，会被分发到某一个ReduceTask来处理这一组数据。如果某一个键对应的值比较多，那么此时处理这个键的ReduceTask的任务量就相对较大，此时就产生了数据倾斜。针对这个问题，提供了两种优化方案

    1. map combine：map端的聚合，就是将数据在MapTask处先进行一次聚合，然后再将聚合后的结果发送给ReduceTask处理

      -- 开启聚合机制
set hive.map.aggr = true;
-- 指定聚合的值
set hive.groupby.mapaggr.checkinterval = 10000;

    2. 二阶段聚合(负载均衡方式)：将Hive的执行过程拆分成2个MapReduce任务执行。第一个MapReduce中，先将数据打散之后进行聚合，第二个MapReduce中，再根据实际的要求进行聚合

      -- 开启二阶段聚合
set hive.groupby.skewindata = true;

  3. CBO(Cost based Optimizer，基于花费的优化器)

    1. CBO是从Hive0.10开始添加的一种优化机制，从Hive1.1.0开始，CBO优化默认是开启的，可以通过属性hive.cbo.enable来调节
    2. CBO遵循的原则：谁的执行代价最小就是最好的执行计划

  4. 谓词下推。在保证结果不发生改变的前提下，尽量将where条件(谓词)提前执行，来减少下游处理的数据量，这个过程就称之为谓词下推

    -- 开启谓词下推
-- ppd是PredicatePushDown，预测/谓词下推
set hive.optimize.ppd = true;

  5. map join。当小表和大表进行join的时候， 将小表放入内存中分发给每一个MapTask，MapTask在处理数据时候就直接从内存中获取数据，此时join过程在Map端完成，从而减少了最终交给ReduceTask的数据量

    -- 默认是25M
set hive.mapjoin.smalltable.filesize = 25000000;

  6. SMB join

    1. SMB join(sort merge bucket join)：基于分桶机制和map join的前提下实现的一种join方式，用于解决大表和大表之间的join问题
    2. 当大表和大表进行join的时候，可以考虑先将大表的数据进行分桶，每一个桶中都只包含部分数据，此时每一个桶就相当于是一个小表，在此时join的时候，就是小表和大表join，那么可以进行map join。本质上就是"分而治之"的思想
    3. SMB join的条件：A join B
      1. A表和B表都必须分桶，并且B表的桶数必须是A表桶数的整数倍。例如A分了4个桶，那么B表的桶数必须是4n
      2. 分桶字段和join字段必须一致。A join B on a.id = b.id，那么此时A表和B表必须以id字段来进行分桶

  7. 启用严格模式

    1. hive.strict.checks.no.partition.filter：默认为false，如果设置为true，那么在查询分区表的时候，必须以分区作为查询条件

    2. hive.strict.checks.orderby.no.limit：默认为false，如果设置为true，那么进行order by的时候，必须添加limit语句

    3. hive.strict.checks.cartesian.product：默认为false，如果设置为true，那么严禁进行笛卡尔积

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：http://www.coloradmin.cn/o/1570909.html

如若内容造成侵权/违法违规/事实不符，请联系多彩编程网进行投诉反馈，一经查实，立即删除！

相关文章

armlinux-外部中断

armlinux-外部中断

s3c2440的中断框图 如果我们单纯配置一个按键的外部中断，就不存在子中断与优先级的问题。 由于是按键的外部中断，通过引脚的高低电平来触发。所以我们要先配置引脚的功能。 我们使用按键1，终端源为EINT8，对应引脚GPG0 通过用户手…
阅读更多...
Stable diffusion 加载扩展列表报错解决方法

Stable diffusion 加载扩展列表报错解决方法

项目场景： 在使用Stable diffusion webui时，使用扩展列表出现错误 问题描述 点击loadfrom后，出现加载扩展列表报错 原因分析： 下载的扩展的时候，都是github 的url，需要科学上网，如果不能科学…
阅读更多...
深澜计费管理系统 任意文件读取漏洞复现

深澜计费管理系统 任意文件读取漏洞复现

0x01 产品简介 深澜计费管理系统是是一套完善的领先的具有复杂生物型特征的弹性认证计费系统。系统主要由 AAA 认证计费平台、系统运营维护管理平台、用户及策略管理平台、用户自助服务平台、智能客户端模块、消息推送模块、数据统计模块组成。目前在全球为超过 2500 家客户提…
阅读更多...
MicroPython 树莓派 RP2 入门教程

MicroPython 树莓派 RP2 入门教程

系列文章目录 前言 Raspberry Pi Pico 开发板（图片来源：Raspberry Pi 基金会）。 以下是 Raspberry Pi RP2xxx 板的快速参考资料。如果您是第一次使用该开发板，了解微控制器的概况可能会对您有所帮助： 一、关于 RP2xxx…
阅读更多...
【项目实战】——商品管理的制作完整代码

【项目实战】——商品管理的制作完整代码

👨‍💻个人主页：开发者-曼亿点 👨‍💻 hallo 欢迎 点赞👍 收藏⭐ 留言📝 加关注✅! 👨‍💻 本文由 曼亿点 原创 👨‍💻 收录于专栏&#xff1a…
阅读更多...
数据结构：详解【树和二叉树】

数据结构：详解【树和二叉树】

1. 树的概念及结构（了解） 1.1 树的概念 树是一种非线性的数据结构，它是由n（n>0）个有限结点组成一个具有层次关系的集合。把它叫做树是因为它看起来像一棵倒挂的树，也就是说它是根朝上，而叶朝…
阅读更多...
Vue项目登录页实现获取短信验证码的功能

Vue项目登录页实现获取短信验证码的功能

之前我们写过不需要调后端接口就获取验证码的方法，具体看《无需后端接口，用原生js轻松实现验证码》这个文章。现在我们管理后台有个需求，就是登录页面需要获取验证码，用户可以输入验证码后进行登录。效果如下，当我点击获取验证码后能获取短信验证码： 这里在用户点击获取…
阅读更多...
Cortex-M7 异常处理与返回

Cortex-M7 异常处理与返回

1 前言 当CM3开始响应一个中断时，会在它小小的体内奔涌起三股暗流：  入栈： 把8个寄存器的值压入栈;  取向量：从向量表中找出对应的服务程序入口地址;  选择堆栈指针MSP/PSP，更新堆栈指针…
阅读更多...
LeetCode 19.删除链表的倒数第N个结点

LeetCode 19.删除链表的倒数第N个结点

给你一个链表，删除链表的倒数第 n 个结点，并且返回链表的头结点。 示例 1： 输入：head [1,2,3,4,5], n 2 输出：[1,2,3,5] 示例 2： 输入：head [1], n 1 输出：[] 示例 3&#x…
阅读更多...
Leetcode 39.组合总和

Leetcode 39.组合总和

题目 思路 1.确定递归函数的返回值及参数： 返回值是void,参数这里还是先设定两个全局变量。一个是path存放符合条件单一结果。如：（1，2）。一个是result，是所有path的集合[(1,2),(1,3)…]。 此外再设定一个…
阅读更多...
前端学习之DOM编程-docmument对象、操作DOM对像内容、操作DOM对象属性方式、操作DOM对象的样式

前端学习之DOM编程-docmument对象、操作DOM对像内容、操作DOM对象属性方式、操作DOM对象的样式

docmument对象 <!DOCTYPE html> <html lang"en"> <head><meta charset"UTF-8"><title>document对象</title> </head> <body><div id"container" nameparent><ul name"parent&qu…
阅读更多...
计算机系统结构速成,期末和自考必备

计算机系统结构速成,期末和自考必备

【拯救者】计算机系统结构速成(期末自考)均可用 1️⃣先讲每章对应的基础 2️⃣接着会讲对应的题目巩固 &#x1f357;提供文档下载 这里讲的是【 &#x1f337;速成&#x1f337; 速成&#x1f337; 速成】版本&#xff0c;按课本章节来&#xff0c; 抽取重点&#xff0c;翻…
阅读更多...
数据分析——数据规范化

数据分析——数据规范化

数据规范化是数据分析中的一个重要步骤&#xff0c;其目的在于确保数据的一致性和可比性&#xff0c;提高数据质量和分析结果的准确性。以下是一些数据规范化的常见方法和技术&#xff1a; 数据清洗&#xff1a;此步骤主要清除数据中的重复项、空格、格式错误等&#xff0c;确…
阅读更多...
Transformer Based Multi-view Network for Mammographic Image Classification

Transformer Based Multi-view Network for Mammographic Image Classification

“C-Tk” means “Classification Token” 辅助信息 作者未提供代码
阅读更多...
【python从入门到精通】-- 第四战：语句汇总

【python从入门到精通】-- 第四战：语句汇总

&#x1f308; 个人主页&#xff1a;白子寰 &#x1f525; 分类专栏&#xff1a;python从入门到精通&#xff0c;魔法指针&#xff0c;进阶C&#xff0c;C语言&#xff0c;C语言题集&#xff0c;C语言实现游戏&#x1f448; 希望得到您的订阅和支持~ &#x1f4a1; 坚持创作博文…
阅读更多...
C++：函数重载和引用

C++：函数重载和引用

hello&#xff0c;各位小伙伴&#xff0c;本篇文章跟大家一起学习C&#xff1a;函数重载和引用&#xff0c;感谢大家对我上一篇的支持&#xff0c;如有什么问题&#xff0c;还请多多指教 &#xff01; 文章目录 函数重载1.函数重载的概念为什么C支持函数重载 引用引用的概念引…
阅读更多...
C++中发送HTTP请求的方式

C++中发送HTTP请求的方式

一&#xff0c;简介 使用C编程发送HTTP请求通常需要使用第三方的HTTP库或框架。在C中&#xff0c;有几个受欢迎的HTTP库可供选择&#xff0c;例如Curl、Boost.Beast和cpp-httplib。另外&#xff0c;也可以自己实现socket来发送http请求 二、使用Curl库发送HTTP请求 1. 确认当…
阅读更多...
day60 动态规划part17

day60 动态规划part17

这两题看了自己写的笔记还不懂的话&#xff0c;看看这个up的思路就行&#xff1a; https://space.bilibili.com/111062940/search/video?keyword%E5%9B%9E%E6%96%87 647. 回文子串 中等 提示 给你一个字符串 s &#xff0c;请你统计并返回这个字符串中 回文子串 的数目。 回…
阅读更多...
微带线特性阻抗快速计算---根据介质板参数和特性阻抗得到线宽（Matlab代码）

微带线特性阻抗快速计算---根据介质板参数和特性阻抗得到线宽（Matlab代码）

微带线特性阻抗快速计算—根据介质板参数和特性阻抗得到线宽&#xff08;Matlab代码&#xff09; 参考&#xff1a;https://blog.csdn.net/weixin_45811090/article/details/130045689 《射频电路理论与设计》第2版 黄玉兰著 《射频电路设计——理论与应用》第二版 Reinhold L…
阅读更多...
STC89C51学习笔记（三）

STC89C51学习笔记（三）

STC89C51学习笔记&#xff08;三&#xff09; 综述&#xff1a;本文讲述了通过51单片机控制LED闪烁、流水灯、按键控制LED亮灭、按键控制LED实现二进制、按键控制LED左右移。 一、LED 1.LED闪烁 1&#xff09;原理 如果要实现LED闪烁&#xff0c;不可以直接先使LED亮&…
阅读更多...
推荐文章
最新文章

Copyright @ 2022~2023