使用arduino编写mqtt客户端连接emqx服务器

news2024/11/16 7:47:29

摘要：mqtt客户端可以有很多种，本文介绍一种使用arduino d1（esp8266）制作的客户端，连接emqx服务器的方法。

首先需要配置开发环境，配置方法可以参考文章

(1条消息) 使用arduino开发esp8266和esp32时首选项设置方法（附国内开发板管理网址）_TMS320VC5257H的博客-CSDN博客_esp32开发板管理器网址https://blog.csdn.net/youngwah292/article/details/125820767?ops_request_misc=%257B%2522request%255Fid%2522%253A%2522166926413816782425673674%2522%252C%2522scm%2522%253A%252220140713.130102334.pc%255Fblog.%2522%257D&request_id=166926413816782425673674&biz_id=0&utm_medium=distribute.pc_search_result.none-task-blog-2~blog~first_rank_ecpm_v1~rank_v31_ecpm-3-125820767-null-null.nonecase&utm_term=arduino&spm=1018.2226.3001.4450本文介绍的是使用d1模块连接本地的MQTT服务器，假如需要了解如何连接阿里云物联网平台，可以参考文章

(1条消息) 从arduino板开始做到阿里云app控制--WeMos D1或ESP8266连接阿里云文章合集及源代码_TMS320VC5257H的博客-CSDN博客https://blog.csdn.net/youngwah292/article/details/105855714?ops_request_misc=%257B%2522request%255Fid%2522%253A%2522166926413816782425673674%2522%252C%2522scm%2522%253A%252220140713.130102334.pc%255Fblog.%2522%257D&request_id=166926413816782425673674&biz_id=0&utm_medium=distribute.pc_search_result.none-task-blog-2~blog~first_rank_ecpm_v1~rank_v31_ecpm-15-105855714-null-null.nonecase&utm_term=arduino&spm=1018.2226.3001.4450

源代码如下：编译之前请确定板级支持包和mqtt库是否正确加载。下面这个源代码经过测试是没问题的，如果遇到编译不通过的问题，请仔细查找环境配置方面的问题。

#include <ESP8266WiFi.h>
#include <PubSubClient.h>



const char* ssid = "TP-LINK_XXXX";//在此输入WIFI的名称
const char* password = "XXXXXXXXX";//在此输入WIFI的密码
const char* mqtt_server = "192.168.1.3";//这个是MQTT服务器的IP地址，以实际为准

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE	(50)
char msg[MSG_BUFFER_SIZE];
int value = 0;

void setup_wifi() {

  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  // 如果订阅的主题，第一个字符是1，那么就拉低LED引脚，此时LED就点亮了，具体以实际电路为准，也可能拉高才是点亮
  if ((char)payload[0] == '1') {
    digitalWrite(BUILTIN_LED, LOW);   
  } else {
    digitalWrite(BUILTIN_LED, HIGH);  
  }

}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // 创建一个随机数后缀的客户端名字
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // 
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // 一旦连接上了，就发布一个主题，这个主题是自定义的，您可以在自己的MQTT服务器进行查看
      client.publish("testtopic/2", "hello world");
      // subscribe是订阅的意思，MQTT通信的核心就是“订阅+发布”
      client.subscribe("testtopic/#");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(BUILTIN_LED, OUTPUT);   
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);//端口号是1883，这个不用动，一般都是它
  client.setCallback(callback);
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;
    value = random(1,50);//生成一个随机数
    snprintf (msg, MSG_BUFFER_SIZE, "%ld", value);//将随机数转变成为字符串
    Serial.print("Publish message: ");
    Serial.println(msg);
    client.publish("testtopic/2", msg);//发布这个随机数
  }
}

烧录成功后，使用arduino自带的串口终端观察数据可以看到数据。