操作系统真相还原_第4章：进入保护模式

news2025/1/12 4:01:31

文章目录

  • 实模式的缺陷
  • 保护模式的扩展
    • 段寄存器的变化
    • 寄存器扩展
    • 寻址扩展
  • 全局描述符表GDT
    • 描述符格式
    • 字段含义
  • 进入保护模式
    • 步骤
    • 解释
    • 示例
      • 说明
      • 程序编写
        • boot.inc
        • mbr.s
        • loader.s
      • 编译并写入硬盘
      • 启动bochs执行

实模式的缺陷

1、实模式下用户程序所引用的地址都是指向真实的物理地址，用户程序可以自由修改段基址进而轻而易举地访问所有内存，这就意味着用户程序乃至操作系统的数据都可以被随意的修改，没有安全性可言

2、实模式下访问超过64KB的内存区域需要切换段基址，一次只能运行一个程序，无法充分利用计算机的资源，总共20条地址线，最大可用内存为1MB

保护模式的扩展

段寄存器的变化


描述符索引值：GDT/LDT的index
TI：0表示在GDT中索引，1表示在LDT中索引
RPL：表示请求特权级

寄存器扩展

寻址扩展

全局描述符表GDT

描述符格式

字段含义

段基址：32位，表示段的起始地址

段界限：20位，表示段的最大偏移量

G位：
0：粒度为1B
1：粒度为4KB

D/B字段：
对于代码段(D)来说
0：按照16位模式译码(表示指令中的有效地址与操作数是16位)
1：按照32位模式译码(表示指令中的有效地址与操作数是32位)
对于栈段(B)来说
0：表示使用的是sp寄存器
1：表示使用的是esp寄存器

L字段：
0：32位代码段
1：64位代码段

AVL字段：4位，保留，用户可用

P字段：
0：表示此段不在内存中
1：表示此段在内存中

DPL字段：2位，表示段的特权级，等级分别为0、1、2、3级特权，内核处于0特权级

S位：0：表示系统段
1：表示非系统段

type字段：4位，表示段的类型，分为系统段或非系统段，由S位决定
系统段：

非系统段：

进入保护模式

步骤

1、构造段描述符
2、打开A20地址线
3、加载gdt寄存器
4、将CR0的pe位置1
5、刷新流水线

解释

构造段描述符：
保护模式的运行依赖于GDT，所以进入保护模式之前需要构造GDT

打开A20地址线：
实模式下仅有0~19号地址线可用，保护模式下地址线扩展到了32位，所以需要打开高位的地址线

加载gdt寄存器：
在CPU中有一个寄存器专用于记录GDT的地址，所以使用GDT时需要将其地址加载到gdt寄存器

将CR0的pe位置1：
CR0控制寄存器中有许多控制信息，其中pe位用于开启保护模式

刷新流水线：
由于CPU存在指令预取的操作，使得在开启保护模式之前CPU已经取得了保护模式下的指令，此时段寄存器cs中的信息仍为16实模式下的信息，所以在指令译码阶段是按照16位译码，保护模式下的指令按照实模式运行方式移码在执行阶段可能就会出错，所以需要一个远跳转来刷新cs寄存器中的信息以及清空流水线，使得32位代码以32位方式译码

示例

说明

boot.inc包含一些loader加载和gdt设置的宏定义
mbr.s用于加载loader.s，同时会在屏幕上输出"enter mbr"
loader.s用于开启保护模式，开启保护模式之前会在屏幕上输出“enter loader”，开启保护模式之后会在屏幕上输出"enter protect mode"

程序编写

boot.inc

;--------- mbr & loader ---------
LBA_START_SECTOR equ 0x1
SECTOR_COUNT equ 0x4
LOADER_BASE_ADDR equ 0x100
LOADER_OFF_ADDR equ 0x0
LOADER_ADDR equ 0x1000
;--------- gdt ---------
DESC_G_4K   equ	  1_00000000000000000000000b   
DESC_D_32   equ	   1_0000000000000000000000b
DESC_L	    equ	    0_000000000000000000000b
DESC_AVL    equ	     0_00000000000000000000b
DESC_LIMIT_CODE2  equ 1111_0000000000000000b
DESC_LIMIT_DATA2  equ DESC_LIMIT_CODE2
DESC_LIMIT_VIDEO2  equ 0000_000000000000000b
DESC_P	    equ		  1_000000000000000b
DESC_DPL_0  equ		   00_0000000000000b
DESC_DPL_1  equ		   01_0000000000000b
DESC_DPL_2  equ		   10_0000000000000b
DESC_DPL_3  equ		   11_0000000000000b
DESC_S_CODE equ		     1_000000000000b
DESC_S_DATA equ	  DESC_S_CODE
DESC_S_sys  equ		     0_000000000000b
DESC_TYPE_CODE  equ	      1000_00000000b	;x=1,c=0,r=0,a=0 代码段是可执行的,非依从的,不可读的,已访问位a清0.  
DESC_TYPE_DATA  equ	      0010_00000000b	;x=0,e=0,w=1,a=0 数据段是不可执行的,向上扩展的,可写的,已访问位a清0.

;code section
DESC_CODE_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_CODE2 + DESC_P + DESC_DPL_0 + DESC_S_CODE + DESC_TYPE_CODE + 0x00

;data section
DESC_DATA_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_DATA2 + DESC_P + DESC_DPL_0 + DESC_S_DATA + DESC_TYPE_DATA + 0x00

;video section
DESC_VIDEO_HIGH4 equ (0x00 << 24) + DESC_G_4K + DESC_D_32 + DESC_L + DESC_AVL + DESC_LIMIT_VIDEO2 + DESC_P + DESC_DPL_0 + DESC_S_DATA + DESC_TYPE_DATA + 0x0b

;--------------   选择子属性  ---------------
RPL0  equ   00b
RPL1  equ   01b
RPL2  equ   10b
RPL3  equ   11b
TI_GDT	 equ   000b
TI_LDT	 equ   100b

mbr.s

;主引导程序
;------------------------------------------------------------
%include "boot.inc"
SECTION MBR vstart=0x7c00         
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov ax, 0xB800
   mov gs, ax
   mov sp,0x7c00

; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06	   功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0x600
   mov     bx, 0x700
   mov     cx, 0           ; 左上角: (0, 0)
   mov     dx, 0x184f	   ; 右下角: (80,25),
			   ; VGA文本模式中,一行只能容纳80个字符,共25行。
			   ; 下标从0开始,所以0x18=24,0x4f=79
   int     0x10            ; int 0x10


;;;;;;;;;     打印字符串    ;;;;;;;;;;;

   mov cx, sx - msg
   mov si, msg
   mov di, 0
show_str:
   mov byte al, [si]
   mov byte ah, [sx]
   mov word [gs:di], ax
   inc si
   add di, 2
   loop show_str
   jmp L0

   msg db "enter mbr"
   sx db 0x24

;;;;;;;;;      打字字符串结束	 ;;;;;;;;;;;;;;;
L0:
   push ds
   push di
   mov eax, LBA_START_SECTOR
   push eax
   mov ax, SECTOR_COUNT
   push ax
   mov ax, LOADER_BASE_ADDR
   push ax
   mov ax, LOADER_OFF_ADDR
   push ax
   call read_disk
   add sp, 10
   pop di
   pop ds

   jmp LOADER_ADDR

;;;;;;;;;      read disk      ;;;;;;;;;

; LBA: [bp+10]
; sector count: [bp+8]
; destination: sec=[bp+6], off=[bp+4]
read_disk:
   push bp
   mov bp, sp

;sector_count
   mov dx,0x1f2
   mov ax, [bp+8]
   out dx, al

;sector_addr
   mov dx, 0x1f3
   mov ax, [bp+10]
   out dx, al

   mov dx, 0x1f4
   mov al, ah
   out dx, al

   mov dx, 0x1f5
   mov ax, [bp+12]
   out dx, al

   mov dx, 0x1f6
   mov al, ah
   and al, 0x0f
   or al, 0xe0
   out dx, al

;command_write
   mov dx, 0x1f7
   mov al, 0x20
   out dx, al

disk_test:
   nop          ;give disk a moment
   in al, dx
   and al, 0x88 ;7: BUSY, 3: READY
   cmp al, 0x08 ; (BUSY=0 & READY=1) or not?
   jnz disk_test

;data_read:   
   mov ax, [bp+8]
   mov dx, 256
   mul dx
   mov cx, ax

   mov bx, [bp+4]
   mov ax, [bp+6]
   mov ds, ax

   mov dx, 0x1f0
go_on_read:
   in ax, dx
   mov [bx], ax
   add bx,2
   loop go_on_read

   mov sp, bp
   pop bp
   ret
;;;;;;;;;      read disk      ;;;;;;;;;

   times 510-($-$$) db 0
   db 0x55,0xaa

loader.s

%include "boot.inc"
section loader vstart=LOADER_ADDR
;;;;;;;;;     打印字符串    ;;;;;;;;;;;

   mov cx, sx-msg1
   mov si, msg1
   mov di, 160
show_str:
   mov byte al, [si]
   mov byte ah, [sx]
   mov word [gs:di], ax
   inc si
   add di, 2
   loop show_str

   jmp Jmp_there

   msg1 db "enter loader"
   sx db 0x24

;;;;;;;;;      打字字符串结束    ;;;;;;;;;;;;;;;
Jmp_there:
;----- open A20 -----
   in al, 0x92
   or al, 00000010b
   out 0x92, al

;----- load gdtr-----
   lgdt [gdt_ptr]

;----- cr0 set -----
   mov eax, cr0
   or eax, 0x00000001
   mov cr0, eax

;----- clear instruction pipeline -----
   jmp dword SELECTOR_CODE:p_m_start

[bits 32]
p_m_start:
   mov ax, SELECTOR_DATA
   mov ds, ax
   mov es, ax
   mov ss, ax
   mov esp, LOADER_ADDR

   mov ax, SELECTOR_VIDEO
   mov gs, ax
   mov ecx, GDT_BASE-msg2
   mov si, msg2
   mov di, 320
show_str2:
   mov byte al, [si]
   mov byte [gs:di], al
   inc si
   add di, 2
   loop show_str2

   jmp $

;string
msg2 db "enter protect mode"

;GDT_CREATE
GDT_BASE:
   dd 0x00000000, 0x00000000

CODE_DESC:
   dd 0x0000FFFF, DESC_CODE_HIGH4

DATA_DESC:
   dd 0x0000FFFF, DESC_DATA_HIGH4

VIDEO_DESC:
   dd 0x80000007, DESC_VIDEO_HIGH4

GDT_SIZE equ $ - GDT_BASE
GDT_LIMIT equ GDT_SIZE - 1
times 30 dq 0

;SELECTOR_SET
SELECTOR_CODE equ 0000000000001_000b + TI_GDT + RPL0
SELECTOR_DATA equ 0000000000010_000b + TI_GDT + RPL0
SELECTOR_VIDEO equ 0000000000011_000b + TI_GDT + RPL0

;GDT_pointer
gdt_ptr dw GDT_LIMIT
        dd GDT_BASE

编译并写入硬盘

nasm -I 配置文件所在目录 -o mbr.bin mbr.s所在目录/mbr.s
nasm -I 配置文件所在目录 -o loader.s.bin loader.s所在目录/loader.s
dd if=mbr.s所在目录/mbr.bin of=硬盘所在目录/hd60M.img bs=512 count=1 seek=0 conv=notrunc
dd if=loader.s所在目录/loader.bin of=硬盘所在目录/hd60M.img bs=512 count=4 seek=1 conv=notrunc

由于loader程序大小可能超过1个扇区的大小，所以此处一次性读取4个扇区

启动bochs执行

./bochs安装目录/bochs/bin/bochs -f bochs配置文件所在目录/boot.disk

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：http://www.coloradmin.cn/o/295.html

如若内容造成侵权/违法违规/事实不符，请联系多彩编程网进行投诉反馈，一经查实，立即删除！

相关文章

计算机等级考试Python二级

计算机等级考试Python二级

补记录一下之前考Python二级的一些相关理论记录 数据结构与算法 算法杂度 算法复杂度用来衡量算法的优劣&#xff0c;它包括算法的时间复杂度和算法的空间复杂度 时间复杂度&#xff1a;执行算法所需要的计算量【所需要的计算工作量是用算法所执行的基本运算次数来度量的】 …
阅读更多...
子串和子序列问题-动态规划向

子串和子序列问题-动态规划向

1. 子串子序列问题概述 有关于子序列和子串的问题是字符串或者数组经常会遇到的问题&#xff0c;一般我们经常使用多指针&#xff0c;滑动窗口&#xff0c;回溯&#xff0c;动态规划的方式去解决&#xff0c;而本篇重点关注能用动态规划解决或者说明显使用动态规划解决的子串问…
阅读更多...
Java开发手册解析_编程规约-集合处理

Java开发手册解析_编程规约-集合处理

前言 《Java开发手册&#xff08;黄山版&#xff09;》编程规约-集合处理 该章节的知识点基本都来源于jdk源码&#xff0c;将结合源码及例子进行理解 备注&#xff1a;文章中的详细及说明为手册本身内容 博客地址&#xff1a;芒果橙的个人博客 【http://mangocheng.com】 1.【强…
阅读更多...
服务与发现

服务与发现

文章目录服务与发现什么是服务发现应用层服务发现模式平台层服务发现模式服务与发现 假设你正在编写一些调用具有 REST API 的服务的代码&#xff0c;为了发出请求&#xff0c;你的代码需要知道服务实例的网络位置&#xff08;IP 地址和端口&#xff09;&#xff0c;在物理硬件…
阅读更多...
整型数据是如何在内存中存储的

整型数据是如何在内存中存储的

&#x1f3d6;️作者&#xff1a;malloc不出对象 ⛺专栏&#xff1a;《初识C语言》 &#x1f466;个人简介&#xff1a;一名双非本科院校大二在读的科班编程菜鸟&#xff0c;努力编程只为赶上各位大佬的步伐&#x1f648;&#x1f648; 目录前言一. 整型在内存中的存储1.1 整型…
阅读更多...
Vue2生命周期详细图解和代码

Vue2生命周期详细图解和代码

加油&#xff0c;新时代打工人&#xff01;&#xff01;&#xff01; 话不多说&#xff0c;看图。 <!DOCTYPE html> <html lang"en"> <head><meta charset"UTF-8"><meta http-equiv"X-UA-Compatible" content"…
阅读更多...
C语言数据结构——链表

C语言数据结构——链表

C语言数据结构——链表 链表包括单链表&#xff0c;双链表&#xff0c;循环链表等。 而今天要说的是单链表&#xff0c;它是一个线性表&#xff0c;它在内存中是无序的&#xff0c;由一个个指针来连接。 图示&#xff1a; 小方块代表的就是存储的数据&#xff0c;箭头就是指…
阅读更多...
（46）STM32——FATFS文件系统实验

（46）STM32——FATFS文件系统实验

目录 学习目标 运行结果 文件系统 常用系统 FATFS 特点 结构图 移植步骤 disk_initialize disk_status disk_read disk_write disk_ioctl get_fattime 代码 总结 学习目标 我们要来介绍的是FATFS文件系统&#xff0c;这是一个为嵌入式设计的文件系统&#xff0c…
阅读更多...
大学科目网课搜题接口

大学科目网课搜题接口

大学科目网课搜题接口 本平台优点&#xff1a; 多题库查题、独立后台、响应速度快、全网平台可查、功能最全&#xff01; 1.想要给自己的公众号获得查题接口&#xff0c;只需要两步&#xff01; 2.题库&#xff1a; 查题校园题库&#xff1a;查题校园题库后台&#xff08;点…
阅读更多...
【1024社区大奖】让你一小时内狂揽大奖[保姆级教程①]

【1024社区大奖】让你一小时内狂揽大奖[保姆级教程①]

四层挑战&#xff0c;一小时内拿捏&#xff01;&#xff08;上&#xff09;一、龙蜥社区大奖二、战前准备1.注册码云Gitee2.注册龙蜥社区三、开始挑战&#xff0c;包揽大奖&#xff01;①第一层&#xff1a;小龙推荐 [15分钟]②第二层随机试炼 [15分钟]一、龙蜥社区大奖 活动分…
阅读更多...
【论文笔记】Transformer-based deep imitation learning for dual-arm robot manipulation

【论文笔记】Transformer-based deep imitation learning for dual-arm robot manipulation

【论文笔记】Transformer-based deep imitation learning for dual-arm robot manipulation Abstract 问题&#xff1a;In a dual-arm manipulation setup, the increased number of state dimensions caused by the additional robot manipulators causes distractions and …
阅读更多...
微信小程序入门与实战之更多电影列表与电影搜索

微信小程序入门与实战之更多电影列表与电影搜索

wx.request的更多参数详解 在网络请求中我们可以采用下面这种形式&#xff1a; 如果我们可以不采用直接写在url的方式我们可以采用data的方式&#xff1a; 默认请求方式是GET我们可以通过设置method修改请求方式&#xff1a; 更多电影页面 我们要实现的效果&#xff1a;…
阅读更多...
应用层——HTTP协议

应用层——HTTP协议

文章目录一、应用层1.1 应用层概念1.2 再谈协议二、网络版本的计算器网络计算器编码部分版本1&#xff1a;原生版本版本2&#xff1a;引入序列化和反序列化三、HTTP协议3.1 URL3.2 urlencode和urldecode3.3 HTTP协议格式3.3.1 请求报文3.3.2 响应报文3.4 HTTPDemo3.4.1改进3.4.…
阅读更多...
这里不适合做技术

这里不适合做技术

6点&#xff0c;の&#xff0c;下班了又是一个差不多一样的星期过去了&#xff0c;又是一个差不多的周末要到来了。我也差不多要离开这家公司了&#xff0c;入职4年多&#xff0c;那时候雄心壮志&#xff0c;决定干一番大事业&#xff0c;那个时候的自己&#xff0c;技术的炉火…
阅读更多...
【图像融合】基于 DCT结合拉普拉斯金字塔的图像融合附matlab代码

【图像融合】基于 DCT结合拉普拉斯金字塔的图像融合附matlab代码

✅作者简介&#xff1a;热爱科研的Matlab仿真开发者&#xff0c;修心和技术同步精进&#xff0c;matlab项目合作可私信。 &#x1f34e;个人主页&#xff1a;Matlab科研工作室 &#x1f34a;个人信条&#xff1a;格物致知。 更多Matlab仿真内容点击&#x1f447; 智能优化算法 …
阅读更多...
论文理解与笔记【CVPR_2022.6】Region-Aware Face Swapping

论文理解与笔记【CVPR_2022.6】Region-Aware Face Swapping

论文理解与笔记【CVPR_2022】Region-Aware Face Swapping论文的缩写全拼&#xff1a;一、贡献二、介绍三、提出问题&#xff0c;也是论文解决的问题四、具体实现方案五、实验六、最终感想和总结论文地址&#xff1a;传送门或者传送门2 先看看效果&#xff1a; 论文的缩写全拼…
阅读更多...
【单片机毕业设计】【mcuclub-jj-003】基于单片机的八层电梯的设计

【单片机毕业设计】【mcuclub-jj-003】基于单片机的八层电梯的设计

最近设计了一个项目基于单片机的八层电梯系统&#xff0c;与大家分享一下&#xff1a; 一、基本介绍 项目名&#xff1a;八层电梯 项目编号&#xff1a;mcuclub-jj-003 单片机类型&#xff1a;STC89C52、STM32F103C8T6 功能简介&#xff1a; 1、通过3*4矩阵键盘实现电梯内部…
阅读更多...
【Linux修炼】5.vim详解

【Linux修炼】5.vim详解

每一个不曾起舞的日子&#xff0c;都是对生命的辜负。 Linux-yum&vim工具的使用本节目标1. Linux 软件包管理器 yum1.1 什么是软件包1.2 关于rzsz1.3 查看软件包1.4 如何安装软件1.5 如何卸载软件2. Linux编辑器-vim的使用&#xff08;重点&#xff09;2.1 什么是vim&#…
阅读更多...
C++内存管理

C++内存管理

1.C内存分布 学习C内存分布之前&#xff0c;先小试牛刀一下。 int globalVar 1; static int staticGlobalVar 1; void Test() {static int staticVar 1;int localVar 1;int num1[10] { 1, 2, 3, 4 };char char2[] "abcd";const char* pChar3 "abcd&quo…
阅读更多...
webpack--》webpack底层深入讲解，从初识到精通，真正实现从0到1的过程

webpack--》webpack底层深入讲解，从初识到精通，真正实现从0到1的过程

目录 webpack webpack的基本使用 安装 配置 修改自定义打包的入口与出口 优化js或图片的存放路径 配置webpack中符号的使用 webpack中相关插件安装 webpack-dev-server html-webpack-plugin clean-webpack-plugin webpack中的loader 打包处理css文件 打包处理les…
阅读更多...
推荐文章
最新文章

Copyright @ 2022~2023