【目录】8051汇编与C语言系列教程

news2024/9/24 0:25:58

8051汇编与C语言系列教程

作者将狼才鲸
创建日期2024-07-23
  • CSDN文章地址：【目录】8051汇编与C语言系列教程
  • 本Gitee仓库原始地址：才鲸嵌入式/8051_c51_单片机从汇编到C_从Boot到应用实践教程

一、本教程目录

序号教程名称简述教程链接
1点亮LCD灯通过IO输出而点亮LCD灯教程链接
2延时与函数用汇编准确延时函数，C语言近似延时函数教程链接
……………………

二、参考网址

  • 51单片机教程(简叙及目录)1~28章 51单片机教程(从原理开始基于汇编)
    • 评分：5分。51单片机汇编，可以下载源码和工程，能直接运行。教程非常入门，有单片机介绍、组成部分、引脚介绍、Keil使用、汇编介绍、IO口介绍、寄存器、汇编指令介绍、数码管等。
  • 单片机c语言教程1~17
    • 评分：5分。51单片机的C语言和32位ARM C语言有点不一样，这个教程描述了8051专有的存储关键字，Keil使用
  • 零基础学习8051单片机（一）~（十六）
    • 评分：5分。和学校里学的类似，讲解了8051单片机的结构、组成、有哪些历史厂商、常用寄存器的介绍。
  • 51单片机入门教程0~6
    • 评分：4分。介绍了Keil和Proteus，模拟器使用Proteus来运行程序，展示了传统的流水灯、数码管、按键。
  • 51单片机从零开始学习
    • 评分：4分。介绍了C语言关键字、Keil使用、流水灯、按键、数码管、模块化编程、定时器、串口、外设控制。
  • 单片机学习教程(目录)1~20章
    • 评分：4分。51单片机C语言。
  • 51单片机轻松入门—基于STC15W4K系列（C语言版）1-22章
    • 评分：4分。
  • 51单片机入门基础教程(共十节)
    • 评分：4分。介绍了原理、引脚、代码。
  • 单片机入门教程1~7
    • 评分：4分。51单片机介绍、键盘、LCD、定时器。
  • 单片机教程
    • 评分：4分。代码不全。51单片机的一些项目设计：万年历、宠物小屋、视频小车等
  • 51 单片机1~18
    • 评分：4分。代码不全。一些单片机自带模块的项目。
  • 51单片机-从零开始入门1~14
  • 51单片机教程1~6
    • 评分：3分。内容少。
  • 单片机应用1~32
  • 屠龙刀STC32保姆级教程[共9篇-13个实验代码]

三、教程介绍

1、点亮一个LED灯

  • 本源码包含C语言和汇编工程，能直接在电脑中通过Keil模拟器运行，并在Keil示波器窗口看到 IO 输出的矩形波。

  • 源码及工程链接

    • 汇编效果：img
    • C语言效果：img

  • 汇编源码：

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; \brief	让LCD灯闪烁（控制IO输出）
; \details	使用Keil Simulator模拟器，和Debug时的Logic Analyzer示波器窗口查看输出
; \remark	File format: UTF-8，源文件使用UTF-8中文编码
; \note		省略了8051的初始化，使用模拟器时会自动准备好运行环境
; \author	将狼才鲸
; \date		2024-07-18
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; 头文件 ;;
;$INCLUDE(at89c51xd2.inc)	; 也可以使用 #include <at89c51xd2.inc>，Keil默认隐藏包含了8051通用寄存器，不用重复包含

MAIN:	; 标号或函数名
	; 请在Debug后通过 View--Analysis Windows--Logic Analyzer--Setup--点击右上角叉叉左边的新建图标--键入P1
	; --点击选中P1--在Max那里将0xFF改成0x01--在And Mask中将0xFFFFFFFF改成0x00000001--Close 来创建模拟器中示波器的采样引脚；
	; 把示波器的小窗口向下拉一点，露出波形的显示区域；
	; 再点击Zoom中的All来显示整个波形（不点击会看不到变化的波形）；
	; 再F10单步运行，一边运行一边看输出的矩形波。
	CLR		P1.0	; P1_0 IO口置低；P1.0里面的.0是汇编的特殊语法，意思是前面P1寄存器的第0 bit，能位寻址的寄存器都能这样调用
	SETB	P1.0	; P1_0 IO口拉高
	LJMP	MAIN	; 跳转到标号

END	; 源文件结束
  • C源码：
/******************************************************************************
 * \brief	让LCD灯闪烁（控制IO输出）
 * \details	使用Keil Simulator模拟器，和Debug时的Logic Analyzer示波器窗口查看输出
 * \remark	File format: UTF-8，源文件使用UTF-8中文编码
 * \note	省略了8051的初始化，使用模拟器时会自动准备好运行环境
 * \author	将狼才鲸
 * \date	2024-07-18
 ******************************************************************************/
 
/** 头文件 **/
#include <Atmel/at89c51RC2.h>	/* 寄存器定义 */

/** 接口函数 **/
int main(void)
{
	while (1)
	{
		/**
		 请在Debug后通过 View--Analysis Windows--Logic Analyzer--Setup--点击右上角叉叉左边的新建图标--键入P1_0--Close 来创建模拟器中示波器的采样引脚；
		 把示波器的小窗口向下拉一点，露出波形的显示区域；
		 再点击Zoom中的All来显示整个波形（不点击会看不到变化的波形）；
		 再F10单步运行，一边运行一边看输出的矩形波。
		 */
		P1_0 = 0;	/* P1_0是头文件中已经定义的寄存器Bit */
		P1_0 = 1;
	}
}
  • 参考网址：
    • 2课:单片机引脚介绍 该文章后半部分有C语言原始工程下载链接
    • 4课:第一个单片机小程序 该文章前半部分有汇编原始工程下载链接

2、延时与函数

  • ms、us级别的延时最好使用定时器，ns级别的延时就可以关闭所有中断后使用汇编，不需要精准的延时则可以使用C语言的for循环；

    • 使用C语言进行延时时，延时的时间不好算，一般通过实际测试得到，并且延时的时间长短容易受到代码优化的影响；
    • 在关闭中断的情况下，汇编函数可以做到精准控制延时，精度和指令周期一致，前提是你要知道当前主频和每条指令的执行时间（指令周期）；

  • 延时可以用在IO输出的时序控制和通信端口模拟，例如用IO口模拟I2C、SPI、SDIO等协议；

  • 源码及工程链接

    • 该汇编工程里演示了汇编函数的编写、参数的调用和精准的延时；
    • 该C语言工程里演示了一般的延时，在C语言中如何调用汇编函数；
    • 汇编效果：img
    • C语言效果：img
    • C语言中调用汇编精准延时效果：img

  • 汇编精准延时函数源码：

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; \brief	演示延时与函数，控制LCD灯闪烁的间隔
; \details	使用Keil Simulator模拟器，和Debug时的Logic Analyzer示波器窗口查看输出
; \remark	File format: UTF-8，源文件使用UTF-8中文编码
; \note		省略了8051的初始化，使用模拟器时会自动准备好运行环境
; \author	将狼才鲸
; \date		2024-07-21
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; 8051汇编指令及每条指令所消耗的时钟数详见：
; https://gitee.com/langcai1943/8051-from-boot-to-application/blob/develop/02_doc/01_8051寄存器、指令集、伪指令和关键字介绍.md

; 当前工程中配置的晶振是Keil默认的24MHz，时钟周期41.67ns，状态周期是2倍时钟周期即83.3333ns，
; 机器周期是6倍状态周期即500ns，一个机器周期记为1T，一条指令周期为1~4T，具体哪条指令占多少T需要查阅上面文档

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 声明 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$NOMOD51	; 不使用Keil默认隐含的8051通用寄存器定义，而是显式的包含寄存器定义头文件

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 头文件 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
$INCLUDE(at89c51xd2.inc)	; 也可以使用 #include <at89c51xd2.inc>，实际文件在C:\Keil_v5\C51\ASM\at89c51xd2.inc

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 宏定义 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
INS_SET_10US_NUM	EQU 20	; 10us占20个机器周期；当前工程中配置的晶振是Keil默认的24MHz，时钟周期41.67ns，机器周期500ns；

;; 宏定义函数
DELAY_1US  MACRO
	NOP	; 1T，500ns
	NOP
ENDM

DELAY_2US  MACRO
	DELAY_1US
	DELAY_1US
ENDM

DELAY_4US  MACRO
	DELAY_2US
	DELAY_2US
ENDM

DELAY_8US  MACRO
	DELAY_4US
	DELAY_4US
ENDM

DELAY_16US  MACRO
	DELAY_8US
	DELAY_8US
ENDM

;;
; \brief	汇编主函数，演示延时与函数，控制LCD灯闪烁的间隔
;			其实不算真正的函数，只是标号 + 死循环
; \param	无
; \return	无
;;
MAIN:	; 标号或函数名
	; 请在Debug后通过 View--Analysis Windows--Logic Analyzer--Setup--点击右上角叉叉左边的新建图标--键入P1
	; --点击选中P1--在Max那里将0xFF改成0x01--在And Mask中将0xFFFFFFFF改成0x00000001--Close 来创建模拟器中示波器的采样引脚；
	; 把示波器的小窗口向下拉一点，露出波形的显示区域；
	; 再点击Zoom中的All来显示整个波形（不点击会看不到变化的波形）；
	; 再F10单步运行，一边运行一边看输出的矩形波。
	CLR		P1.0			; 1T（耗时1个机器周期），P1_0 IO口置低；P1.0里面的.0是汇编的特殊语法，意思是前面P1寄存器的第0 bit，能位寻址的寄存器都能这样调用
	;; 和CLR一起延时10us，再补齐9.5us
	NOP						; 1T，0.5us
	DELAY_8US				; 宏定义函数
	DELAY_1US

	;; 延时990us
	MOV		R7, #99			; 1T；延时99 x 10 = 990us；0xR7 = 十进制99；调用函数时，第一个参数是0xR7
	LCALL	_delay_us_10x	; 2T，传入的参数是R7

	;; 延时4ms
	MOV		R6, #HIGH(4)	; HIGH和LOW是Keil C51的伪指令，用于获取16位立即数中的高字节和低字节
	MOV		R7, #LOW(4)		; 传入的参数0xR6R7 = 4ms
	LCALL	_delay_ms		; 调用函数；和C语言不一样，汇编函数的定义即使在本调用下方的话，不用先声明也能使用

	SETB	P1.0			; 1T，P1_0 IO口拉高
	;; 和SETB、LJMP MAIN一起延时10us，再补齐8.5us
	NOP						; 1T，0.5us
	DELAY_8US				; 宏定义函数

	;; 延时1000us
	MOV		R7, #99			; 0xR7 = 99
	LCALL	_delay_us_10x	; 传入的参数是99，延时990us

	;; 延时9ms
	MOV		R6, #HIGH(9)
	MOV		R7, #LOW(9)		; 传入的参数0xR6R7 = 9ms
	LCALL	_delay_ms

	LJMP	MAIN			; 2T，跳转到标号

;;
; \brief	以10us为单位的延时函数（必须延时20us及以上，否则请直接使用NOP进行延时！）
; \details	1. 使用小写标号（函数名），在C语言中调用该函数时让函数名与C语言标准更统一；
;			2. 传入的参数需要 >= 2，否则会有异常的长时间延时，也就是说至少延时2个10us；
; \note		注意：要使用汇编实现精准延时的话，需要在调用延时前关闭所有中断，调用后再恢复中断！
; \remark	C语言调用此汇编函数时使用 delay_us_10x(100); // 延时1000us
; \param	0xR7	uint8，延时多少个10us，取值为 2 ~ 255
; \return	无
;;
_delay_us_10x:
	; 外部调用此函数时如果有给R7赋值则会额外消耗1T（已优化）
	; 外部调用此函数的LCALL或ACALL会额外占2T（已优化）
	DEC		R7					; 1T，将10us的次数直接减1；用于补齐10us，抵消额外的消耗

	;; 抵消额外消耗的6T，再补14T凑成10us；
	;  \note	如果晶振有变化，则这里的补时也要调整，或者修改得和 INS_SET_10US_NUM 相关
	DELAY_4US					; 这里是宏定义函数
	DELAY_2US
	DELAY_1US

	;; 延时10us
DELAY_US_LOOP2:
	MOV		R6, #((INS_SET_10US_NUM - 4) / 2)	; 1T
	NOP											; 1T，空指令，什么也不做；为了补齐MOV指令的1T时间到2T
DELAY_US_LOOP1:
	DJNZ	R6, DELAY_US_LOOP1	; 2T

	DJNZ	R7, DELAY_US_LOOP2	; 2T，延时多少个10us

	RET	; 从函数中返回；返回额外占2T（已优化）

;;
; \brief	ms延时函数
; \details	1. 传入的参数必须 >= 1，即至少延时1ms，如果为0则会导致超长时间延时
;			2. 当低字节为0x01时，本延时函数少了2T也就是1us；
;			3. 当低字节为0x00时，本延时函数多了4T也就是2us；
; \note		注意：要使用汇编实现精准延时的话，需要在调用延时前关闭所有中断，调用后再恢复中断！
; \remark	C语言调用此汇编函数时使用 delay_ms(1000); // 延时1000ms
; \param	0xR6R7-->0xR4R5	uint16，延时多少ms；取值范围为0x0002~0xFEFF（注意不是0xFFFF!）
; \return	无
;;
_delay_ms:
	; 外部调用此函数时如果有给R6R7赋值则会额外消耗2T（已优化）
	; 外部调用此函数的LCALL或ACALL会额外占2T（已优化）

	; 0xR4R5 = 0xR6R7
	MOV		A, R7	; 1T，因为之后R7还需作为子函数的参数，所以将0xR6R7先移动到0xR4R5
	MOV		R5, A	; 1T，不能直接MOV R5, R7; 没有这种指令，两个内部寄存器之间不能直接赋值
	MOV		A, R6	; 1T，下面调用us延时函数时没有进行压栈弹栈操作，us延时里面用了R6作为临时变量，所以这里也要避开
	MOV		R4, A	; 1T

	INC		R4		; 1T，R4自增1；如果R4本来为0，则本函数最后的R4减1不为0跳转会有bug；因此高位的取值只能是0x00~0xFE，不能取到0xFF

	;; 函数进入和函数返回时的额外消耗是24T（其中有2T是R4自增一导致的），12us，此处将其补齐到1ms，
	;  还需额外补980us + 8us；并后续将0xR4R5减1，也就是减去这补齐的1ms
	DELAY_8US
	MOV		R7, #98			; 1T已抵消，_delay_us_10x函数的参数，980us
	LCALL	_delay_us_10x	; 2T已抵消

	;; 将0xR4R5减1，用于时间凑整补齐
	;  执行所有INC或DEC自增自减、所有ADD加法指令时都不会产生PSW寄存器的CY借位；
	;  只有ADDC和SUBB指令才带进位或借位，进位和借位都是PSW寄存器的CY位；
	;  SUBB不能用R0~R7去减别的数，只能用累加器A去减
	;; 低字节减1
	MOV		A, R5	; 1T
	CLR		C		; 1T，CLR C和CLR CY是一样的效果，C是指令集里面特定的用法，CY是头文件中BIT伪指令定义的位
	SUBB	A, #1	; 1T
	MOV		R5, A	; 1T，减完后放回R5
	JNC		DELAY_MS_HIGH_BYTE_IGNORE_DEC	; 2T，如果CY进位为0则跳转
	;; 类似跳转指令还有：JNZ累加器为1跳转，JZ累加器为0跳转，JNC进位为0跳转，JC进位为1跳转，
	;  JNB比特为0跳转，JB比特为1跳转，JBC比特为1跳转并清零（前面其他指令都不会自动清零）

	;; 如果有借位则高字节减1（因为有减1的步骤，所以传入的参数不能为0x0001）
	;  当低字节为0x00时，此处会执行，则会多了4T也就是2us
	;                               ;=====================;
	CLR		C		; 1T，CLR C和CLR CY是一样的效果，C是指令集里面特定的用法，CY是头文件中BIT伪指令定义的位
	MOV		A, R4	; 1T
	SUBB	A, #1	; 1T，SUBB使用前要清零进位CY，否则借位存在的话会多减去1
	MOV		R4, A	; 1T，减完后放回R4

DELAY_MS_HIGH_BYTE_IGNORE_DEC:

	;; 处理传入的参数低字节为0的情况
	MOV		A, R5					; 1T
	JZ		DELAY_MS_HIGH_BYTE_JMP	; 2T，累加器A为0则跳转
	LJMP	DELAY_MS_BYTE_LOOP_LOW	; 2T，当低字节减完1后为0时，此处会少了2T也就是1us，少的这1us没有进行优化
	;                                                          ;=====================;
DELAY_MS_BYTE_LOOP_HIGH:
	; 每次高字节循环256ms时的额外消耗是4T，2us；此处将其补齐到10us，后面再调用990us
	DELAY_8US

	;; 延时1ms；高字节减1，低字节从256变成255时，将少的那一次补上
	MOV		R7, #99			; 1T已抵消，_delay_us_10x函数的参数
	LCALL	_delay_us_10x	; 2T已抵消

	MOV		R5, #0FFH		; 2T，R5 = 255
	;; 延时1 ~ 255ms
DELAY_MS_BYTE_LOOP_LOW:
	; 每次低字节循环1ms时的额外消耗是2T，1us，此处将其补齐到10us，后面再调用990us
	DELAY_8US
	DELAY_1US

	;; 延时1ms
	MOV		R7, #99			; 1T已抵消，_delay_us_10x函数的参数
	LCALL	_delay_us_10x	; 2T已抵消

	DJNZ	R5, DELAY_MS_BYTE_LOOP_LOW	; 2T，R5寄存器内的数据减1，不为0则跳转；延时多少个ms

DELAY_MS_HIGH_BYTE_JMP:
	DJNZ	R4, DELAY_MS_BYTE_LOOP_HIGH	; 2T，处理高字节，延时多少个256ms；之前有加1，函数调用时这里额外多了2T（已优化）

	RET	; 2T，返回额外占2T（已优化）

END	; 源文件结束
  • C语言不精准的延时函数源码
/******************************************************************************
 * \brief	演示延时与函数，控制LCD灯闪烁的间隔
 * \details	使用Keil Simulator模拟器，和Debug时的Logic Analyzer示波器窗口查看输出
 * \remark	File format: UTF-8，源文件使用UTF-8中文编码
 * \note	省略了8051的初始化，使用模拟器时会自动准备好运行环境
 * \author	将狼才鲸
 * \date	2024-07-23
 ******************************************************************************/

/* 一个文件中将一些全局的东西分门别类，模块性更好，不容易错漏，方便查找bug */

/********************************* 头文件 *************************************/
#include <Atmel/at89c51RC2.h>	/* 寄存器定义 */

/******************************** 类型定义 ************************************/
/** 下面的类型定义让程序的可移植性更好，例如无负担的移植到32位或64位MCU上；
    typedef是C语言进行类型定义的关键字，很常用 */
typedef unsigned char		uint8;		/* 使用uint8代替8051一个字节的unsigned char */
typedef unsigned int		uint16;		/* 使用uint16代替8051两个字节的unsigned int，8051的int是2字节，而32位CPU是4字节 */
typedef unsigned long int	uint32;		/* 8051的long是4字节，而32位CPU是8字节，4字节的float和8字节的double与32位CPU一致 */
typedef char				int8;
typedef int					int16;
typedef long int			int32;

/********************************* 宏定义 *************************************/
/** 定义错误码，正式工程建议所有的返回值都用错误码，不要直接返回 -1，这样模块化更好 */
#define	OK			0
#define ERR			(-1)	/* 宏定义如果是表达式，建议用括号括起来，防止优先级错误导致难定位的bug出现 */
#define ERR_PARAM	(-2)	/* 传入的参数错误 */

/****************************** 结构体定义*************************************/
typedef enum _BOOL {	/* enum是C语言的关键词，联合体，很常用 */
	FALSE = 0,
	TRUE		/* enum的项目如果是缺省值，则值默认是上一个值 + 1 */
} BOOL;	/* C语言标准库没有定义布尔类型，所以自己定义，当然，Linux和Windows的一些库文件中会有 */

/******************************* 函数声明 *************************************/
static int16 sleep_us_10x(int16 cnt);	/* 函数声明，如果有函数在定义前就被调用，则需要在调用前进行声明 */
static int16 sleep_ms(int16 cnt);	/* static是C语言关键字，表示静态变量或静态函数，这里是静态函数 */

/******************************* 接口函数 *************************************/
/**
 * \brief	主函数
 * \details	当整个工程文件中没有汇编文件时，Debug后默认进入到main函数第一行，
 *			但当有汇编文件时，默认会先进入到汇编，此时则需要写好boot
 */
int main(void)
{
	/* 进入函数时先拉低拉高做标记，作为延时的起始零点，因为main执行前会有耗时 */
	P1_0 = 0;	/* IO口输出低；P1_0是头文件中已经定义的寄存器Bit */
	P1_0 = 1;	/* IO口输出高 */
	
	while (1)
	{
		/**
		 请在Debug后通过 View--Analysis Windows--Logic Analyzer--Setup--点击右上角叉叉左边的新建图标--键入P1_0--Close 来创建模拟器中示波器的采样引脚；
		 把示波器的小窗口向下拉一点，露出波形的显示区域；
		 再点击Zoom中的All来显示整个波形（不点击会看不到变化的波形）；
		 再F10单步运行，一边运行一边看输出的矩形波。
		 */
		P1_0 = 0;			/* IO口输出低；P1_0是头文件中已经定义的寄存器Bit */
		sleep_us_10x(500);	/* 延时5ms */
		P1_0 = 1;			/* IO口输出高 */
		sleep_ms(15);		/* 延时15ms */
	}
}

/******************************* 私有函数 *************************************/
/**
 * \brief	us级别延时，延时时间 = cnt x 10 us
 * \details	没使用定时器，只使用了死循环，当前延时只是大体上准，而且会受中断的影响；
 *			只延时10us时，误差+13.5us；
 *			延时20us及以上时，误差 + 0.25% x 想要的延时 + 13.5us，例如想要延时1ms，实际会延时1016us；
 * \param	cnt	延时多少个10us，有效取值范围为 1 ~ 32768
 * \return	返回值无实际含义
 */
static int16 sleep_us_10x(int16 cnt)	/* 不是供其它模块调用的接口函数，都建议定义成静态函数，模块化更好 */
{
	int16 i;	/* 8051的所有局部变量必须在函数的前面定义，不能像32位CPU那样随用随定义 */
	int8 ret = 0;

	/* cnt为0时延时12us，cnt为1时延时19.5us，通过实测得到 */
	/* 循环1001次耗时8021us，每次循环消耗8.0015us，通过实测得到 */

	for (i = 0; i < cnt; i++)	/* 8051不能使用 for (int i = 0; i < cnt; i++); 这种使用时定义的做法 */
	{
		/** 每次空循环耗时8us，此处再补2us，补成10us */
		/* 也可以使用 __asm NOP; 插入汇编，但是这样会导致.c文件打不了断点，所以不用 */
		/* 指令集参见：https://gitee.com/langcai1943/8051-from-boot-to-application/blob/develop/02_doc/01_8051寄存器、指令集、伪指令和关键字介绍.md */
		ret++;	/* 字节自增在汇编中消耗1个机器周期，当前24MHz晶振，一个机器周期0.5us */
		ret++;
		ret++;
		ret++;
	}

	return ret;	/* 使用ret，防止此变量的所有操作被编译器优化掉；该返回值没有含义 */
}

/**
 * \brief	ms级别延时
 * \details	没使用定时器，只使用了死循环，当前延时只是大体上准，而且会受中断的影响；
 *			延时误差约 + 0.1%，例如延时1000ms，实际耗时约1001ms；
 * \param	cnt	延时多少个ms，有效取值范围为 1 ~ 32768
 * \return	返回值无实际含义
 */
static int16 sleep_ms(int16 cnt)
{
	int16 i, j;
#	define MS_SLEEP_CNT	356	/* 延时1ms所需要的循环次数，实测所得 */

	for (i = 0; i < cnt; i++)
	{
		for (j = 0; j < MS_SLEEP_CNT; j++)
		{
		}
	}

	return 0;	/* 返回0代表一切执行正常，处理错误则返回负数的错误码；建议所有函数都弄成有返回值的结构，中断处理除外 */
}

/********************************* 文件尾 *************************************/
  • C语言中调用精准汇编延时函数的源码
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; \brief	汇编延时函数，供C语言调用
; \remark	File format: UTF-8，源文件使用UTF-8中文编码
; \author	将狼才鲸
; \date		2024-07-22
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$NOMOD51	; 不使用Keil默认隐含的8051通用寄存器定义，而是显式的包含寄存器定义头文件

;; 定义本汇编文件的代码段，不定义的话放到位置不固定，有可能上电RESET后直接就跑到这里来了 ;
;  如果该汇编文件会被别的汇编文件直接包含，则不用定义，同时文件尾也不用加END
NAME	DELAY_ASM
DELAY_ASM  SEGMENT  CODE	; SEGMENT CODE是定义代码段
RSEG  DELAY_ASM

; 8051汇编指令及每条指令所消耗的时钟数详见：
; https://gitee.com/langcai1943/8051-from-boot-to-application/blob/develop/02_doc/01_8051寄存器、指令集、伪指令和关键字介绍.md

; 当前工程中配置的晶振是Keil默认的24MHz，时钟周期41.67ns，状态周期是2倍时钟周期即83.3333ns，
; 机器周期是6倍状态周期即500ns，一个机器周期记为1T，一条指令周期为1~4T，具体哪条指令占多少T需要查阅上面文档

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 函数声明 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
PUBLIC _delay_us_10x	; 类似于C语言头文件中的 extern void delay_us_10x(uint8 cnt); 让别的文件中能调用此函数
PUBLIC _delay_ms

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 宏定义 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
INS_SET_10US_NUM	EQU 20	; 10us占20个机器周期；当前工程中配置的晶振是Keil默认的24MHz，时钟周期41.67ns，机器周期500ns；

;; 宏定义函数
DELAY_1US  MACRO
	NOP	; 1T，500ns
	NOP
ENDM

DELAY_2US  MACRO
	DELAY_1US
	DELAY_1US
ENDM

DELAY_4US  MACRO
	DELAY_2US
	DELAY_2US
ENDM

DELAY_8US  MACRO
	DELAY_4US
	DELAY_4US
ENDM

DELAY_16US  MACRO
	DELAY_8US
	DELAY_8US
ENDM

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 接口函数 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
; \brief	以10us为单位的延时函数（必须延时20us及以上，否则请直接使用NOP进行延时！）
; \details	1. 使用小写标号（函数名），在C语言中调用该函数时让函数名与C语言标准更统一；
;			2. 传入的参数需要 >= 2，否则会有异常的长时间延时，也就是说至少延时2个10us；
; \note		注意：要使用汇编实现精准延时的话，需要在调用延时前关闭所有中断，调用后再恢复中断！
; \remark	C语言调用此汇编函数时使用 delay_us_10x(100); // 延时1000us
; \param	0xR7	uint8，延时多少个10us，取值为 2 ~ 255
; \return	无
;;
_delay_us_10x:
	; 外部调用此函数时如果有给R7赋值则会额外消耗1T（已优化）
	; 外部调用此函数的LCALL或ACALL会额外占2T（已优化）
	DEC		R7					; 1T，将10us的次数直接减1；用于补齐10us，抵消额外的消耗

	;; 抵消额外消耗的6T，再补14T凑成10us；
	;  \note	如果晶振有变化，则这里的补时也要调整，或者修改得和 INS_SET_10US_NUM 相关
	DELAY_4US					; 这里是宏定义函数
	DELAY_2US
	DELAY_1US

	;; 延时10us
DELAY_US_LOOP2:
	MOV		R6, #((INS_SET_10US_NUM - 4) / 2)	; 1T
	NOP											; 1T，空指令，什么也不做；为了补齐MOV指令的1T时间到2T
DELAY_US_LOOP1:
	DJNZ	R6, DELAY_US_LOOP1	; 2T

	DJNZ	R7, DELAY_US_LOOP2	; 2T，延时多少个10us

	RET	; 从函数中返回；返回额外占2T（已优化）

;;
; \brief	ms延时函数
; \details	1. 传入的参数必须 >= 1，即至少延时1ms，如果为0则会导致超长时间延时
;			2. 当低字节为0x01时，本延时函数少了2T也就是1us；
;			3. 当低字节为0x00时，本延时函数多了4T也就是2us；
; \note		注意：要使用汇编实现精准延时的话，需要在调用延时前关闭所有中断，调用后再恢复中断！
; \remark	C语言调用此汇编函数时使用 delay_ms(1000); // 延时1000ms
; \param	0xR6R7-->0xR4R5	uint16，延时多少ms；取值范围为0x0002~0xFEFF（注意不是0xFFFF!）
; \return	无
;;
_delay_ms:
	; 外部调用此函数时如果有给R6R7赋值则会额外消耗2T（已优化）
	; 外部调用此函数的LCALL或ACALL会额外占2T（已优化）

	; 0xR4R5 = 0xR6R7
	MOV		A, R7	; 1T，因为之后R7还需作为子函数的参数，所以将0xR6R7先移动到0xR4R5
	MOV		R5, A	; 1T，不能直接MOV R5, R7; 没有这种指令，两个内部寄存器之间不能直接赋值
	MOV		A, R6	; 1T，下面调用us延时函数时没有进行压栈弹栈操作，us延时里面用了R6作为临时变量，所以这里也要避开
	MOV		R4, A	; 1T

	INC		R4		; 1T，R4自增1；如果R4本来为0，则本函数最后的R4减1不为0跳转会有bug；因此高位的取值只能是0x00~0xFE，不能取到0xFF

	;; 函数进入和函数返回时的额外消耗是24T（其中有2T是R4自增一导致的），12us，此处将其补齐到1ms，
	;  还需额外补980us + 8us；并后续将0xR4R5减1，也就是减去这补齐的1ms
	DELAY_8US
	MOV		R7, #98			; 1T已抵消，_delay_us_10x函数的参数，980us
	LCALL	_delay_us_10x	; 2T已抵消

	;; 将0xR4R5减1，用于时间凑整补齐
	;  执行所有INC或DEC自增自减、所有ADD加法指令时都不会产生PSW寄存器的CY借位；
	;  只有ADDC和SUBB指令才带进位或借位，进位和借位都是PSW寄存器的CY位；
	;  SUBB不能用R0~R7去减别的数，只能用累加器A去减
	;; 低字节减1
	MOV		A, R5	; 1T
	CLR		C		; 1T，CLR C和CLR CY是一样的效果，C是指令集里面特定的用法，CY是头文件中BIT伪指令定义的位
	SUBB	A, #1	; 1T
	MOV		R5, A	; 1T，减完后放回R5
	JNC		DELAY_MS_HIGH_BYTE_IGNORE_DEC	; 2T，如果CY进位为0则跳转
	;; 类似跳转指令还有：JNZ累加器为1跳转，JZ累加器为0跳转，JNC进位为0跳转，JC进位为1跳转，
	;  JNB比特为0跳转，JB比特为1跳转，JBC比特为1跳转并清零（前面其他指令都不会自动清零）

	;; 如果有借位则高字节减1（因为有减1的步骤，所以传入的参数不能为0x0001）
	;  当低字节为0x00时，此处会执行，则会多了4T也就是2us
	;                               ;=====================;
	CLR		C		; 1T，CLR C和CLR CY是一样的效果，C是指令集里面特定的用法，CY是头文件中BIT伪指令定义的位
	MOV		A, R4	; 1T
	SUBB	A, #1	; 1T，SUBB使用前要清零进位CY，否则借位存在的话会多减去1
	MOV		R4, A	; 1T，减完后放回R4

DELAY_MS_HIGH_BYTE_IGNORE_DEC:

	;; 处理传入的参数低字节为0的情况
	MOV		A, R5					; 1T
	JZ		DELAY_MS_HIGH_BYTE_JMP	; 2T，累加器A为0则跳转
	LJMP	DELAY_MS_BYTE_LOOP_LOW	; 2T，当低字节减完1后为0时，此处会少了2T也就是1us，少的这1us没有进行优化
	;                                                          ;=====================;
DELAY_MS_BYTE_LOOP_HIGH:
	; 每次高字节循环256ms时的额外消耗是4T，2us；此处将其补齐到10us，后面再调用990us
	DELAY_8US

	;; 延时1ms；高字节减1，低字节从256变成255时，将少的那一次补上
	MOV		R7, #99			; 1T已抵消，_delay_us_10x函数的参数
	LCALL	_delay_us_10x	; 2T已抵消

	MOV		R5, #0FFH		; 2T，R5 = 255
	;; 延时1 ~ 255ms
DELAY_MS_BYTE_LOOP_LOW:
	; 每次低字节循环1ms时的额外消耗是2T，1us，此处将其补齐到10us，后面再调用990us
	DELAY_8US
	DELAY_1US

	;; 延时1ms
	MOV		R7, #99			; 1T已抵消，_delay_us_10x函数的参数
	LCALL	_delay_us_10x	; 2T已抵消

	DJNZ	R5, DELAY_MS_BYTE_LOOP_LOW	; 2T，R5寄存器内的数据减1，不为0则跳转；延时多少个ms

DELAY_MS_HIGH_BYTE_JMP:
	DJNZ	R4, DELAY_MS_BYTE_LOOP_HIGH	; 2T，处理高字节，延时多少个256ms；之前有加1，函数调用时这里额外多了2T（已优化）

	RET	; 2T，返回额外占2T（已优化）

END	; 源文件结束；如果该汇编文件会被别的汇编文件直接包含，则不用加END


/******************************************************************************
 * \brief	演示在C语言中调用汇编函数和汇编宏定义函数
 * \details	使用Keil Simulator模拟器，和Debug时的Logic Analyzer示波器窗口查看输出
 * \remark	File format: UTF-8，源文件使用UTF-8中文编码
 * \note	工程里包含了汇编文件的话，还需要自己手写Boot代码，或者创建工程时添加Keil默认的Boot代码
 * \author	将狼才鲸
 * \date	2024-07-23
 ******************************************************************************/

/********************************* 头文件 *************************************/
#include <Atmel/at89c51RC2.h>

/******************************** 类型定义 ************************************/
typedef unsigned char		uint8;
typedef unsigned int		uint16;
typedef unsigned long int	uint32;
typedef char				int8;
typedef int					int16;
typedef long int			int32;

/********************************* 宏定义 *************************************/
/** 错误码 */
#define	OK			0
#define ERR			(-1)	/* 通用的错误码 */
#define ERR_PARAM	(-2)	/* 传入的参数错误 */

/****************************** 结构体定义*************************************/
typedef enum _BOOL {
	FALSE = 0,
	TRUE		/* TRUE = 1 */
} BOOL;

/******************************* 函数声明 *************************************/
extern void delay_us_10x(uint8 cnt);
extern void delay_ms(uint16 cnt);

/* 如果是在一个汇编文件中调用另一个汇编文件里的函数，采用 EXTRN CODE (YOUR_FUNCTION_NAME) 的方式进行声明 */

/******************************* 接口函数 *************************************/
/**
 * \brief	主函数
 * \details	当整个工程文件中没有汇编文件时，Debug后默认进入到main函数第一行，
 *			但当有汇编文件时，默认会先进入到汇编，此时则需要写好boot
 */
int main(void)
{
	P1_0 = 0;
	P1_0 = 1;

	while (1)
	{
		/**
		 请在Debug后通过 View--Analysis Windows--Logic Analyzer--Setup--点击右上角叉叉左边的新建图标--键入P1_0--Close 来创建模拟器中示波器的采样引脚；
		 把示波器的小窗口向下拉一点，露出波形的显示区域；
		 再点击Zoom中的All来显示整个波形（不点击会看不到变化的波形）；
		 再F10单步运行，一边运行一边看输出的矩形波。
		 */
		P1_0 = 0;			/* IO口输出低；P1_0是头文件中已经定义的寄存器Bit */
		delay_us_10x(200);	/* 调用汇编函数延时2000us */
		P1_0 = 1;			/* IO口输出高 */
		delay_ms(8);		/* 调用汇编函数延时8ms */
	}
}

/********************************* 文件尾 *************************************/

  • 参考网址：

    • 4课:第一个单片机小程序 该文章前半部分有汇编原始工程下载链接
    • C51中汇编的使用及参数传递与数据返回
    • 试把如下c函数改写成汇编语言函数,用51汇编完整写一个函数
    • 当AT89C51单片机外接晶振为6MHz时，其震荡周期、状态时钟周期、机器周期、指令周期的值各是多少？
    • Keil官方8051 Instruction Set Manual指令集在线查看
    • MicroChip Atmel官方指令集文档8051 Microcontroller Instruction Set下载
    • MicroChip Atmel官方芯片手册Atmell 8051 Microcontrollers Hardware Manual下载
    • [Keil官方MCS-51 INSTRUCTION SET指令集文档下载]((https://www.keil.com/dd/docs/datashts/intel/ism51.pdf)

  • Keil C51 C语言中调用汇编函数时，最多使用三个参数，默认第一个参数从R7开始放，第二个参数从R5开始放，第三个参数从R3开始放，如果是2字节的int，那么遵循8051的大端模式，高字节放在R2、R4、R6，低字节放在R3、R5、R7；如果是指针参数，无论是第一第二第三个参数，都放在R1~R3，存储类型是R3，指针值是0xR2R1（注意此时是小端模式存储）；超过三个的参数请用外部RAM来实现；

  • 汇编函数将返回值返回给C语言时，返回值需要放在R7开始的位置，char就放在R7，int是0xR6R7，long和float是0xR4R5R6R7，指针是类型在R3，指针值0xR2R1；

  • 汇编里的函数如果要给C语言用，那么函数名（标号）前要叫下划线，例如 _LOOP: NOP; RET;，C语言调用时去掉下划线，如：LOOP();

    • 其实加下划线是代表有参数调用，但是无参数的汇编函数你也这么加并没有问题；

  • 想找原文的，在Keil安装目录的C:\Keil_v5\C51\Hlp\c51.chm，在里面搜索Parameter Passing或者Passing in Registers，原文摘抄如下：

Passing in Registers

C functions may pass parameters in registers and fixed memory locations. A maximum of 3 parameters may be passed in registers. All other parameters are passed using fixed memory locations. The following tables define which registers are used for passing parameters.

Arg Numberchar, 1-byte ptrint, 2-byte ptrlong, floatgeneric ptr
1R7R6 & R7 (MSB in R6,LSB in R7)R4—R7R1—R3 (Mem type in R3, MSB in R2, LSB in R1)
2R5R4 & R5 (MSB in R4,LSB in R5)R4—R7R1—R3 (Mem type in R3, MSB in R2, LSB in R1)
3R3R2 & R3 (MSB in R2,LSB in R3)R1—R3 (Mem type in R3, MSB in R2, LSB in R1)

The following examples clarify how registers are selected for parameter passing.

DeclarationDescription
func1 ( int a)The first and only argument, a, is passed in registers R6 and R7.
func2 ( int b, int c, int *d)The first argument, b, is passed in registers R6 and R7. The second argument, c, is passed in registers R4 and R5. The third argument, d, is passed in registers R1, R2, and R3.
func3 ( long e, long f)The first argument, e, is passed in registers R4, R5, R6, and R7. The second argument, f, cannot be located in registers since those available for a second parameter with a type of long are already used by the first argument. This parameter is passed using fixed memory locations.
func4 ( float g, char h)The first argument, g, passed in registers R4, R5, R6, and R7. The second parameter, h, cannot be passed in registers and is passed in fixed memory locations.

Copyright © Keil, An ARM Company. All rights reserved.

*　４、中断
*　参考网址：
　　* 19课:单片机定时器、中断试验

  • 5、定时器计数器
  • 参考网址：
    • 20课:单片机定时/计数器实验
  • 串口收发 22课:单片机串行口通信程序设计
  • IO波形模拟数码管 3课:LED数码管静态显示接口与编程
  • 按钮，IO输入

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：http://www.coloradmin.cn/o/1944271.html

如若内容造成侵权/违法违规/事实不符，请联系多彩编程网进行投诉反馈，一经查实，立即删除！

相关文章

【技术支持案例】使用S32K144+NSD8381驱动电子膨胀阀

【技术支持案例】使用S32K144+NSD8381驱动电子膨胀阀

文章目录 1. 前言2. 问题描述3. 理论分析3.1 NSD8381如何连接电机3.2 S32K144和NSD8381的软件配置 4.测试验证4.1 测试环境4.2 测试效果4.3 测试记录 1. 前言 最近有客户在使用S32K144NSD8381驱动电子膨胀阀时&#xff0c;遇到无法正常驱动电子膨胀阀的情况。因为笔者也是刚开…
阅读更多...
分享一个Springer模板关于论文作者和单位信息的修改范例，以及Applied Intelligence期刊latex模板的下载链接

分享一个Springer模板关于论文作者和单位信息的修改范例，以及Applied Intelligence期刊latex模板的下载链接

在这篇文章中&#xff0c;我写一些关于解决springer期刊提供的LaTex模板参考文献格式为作者年份时的顺序问题以及如何在正文中将参考文献格式引用成[1]这种数字格式类似的经验&#xff0c;该篇帖子里还分享了一个大佬关于springer模板完整的修改流程&#xff0c;有需要的伙伴可…
阅读更多...
如何实现可视化、智能化、自动化的文件采集？一文了解

如何实现可视化、智能化、自动化的文件采集？一文了解

内部数据文件采集需求在多个行业中都非常重要&#xff0c;以下是一些涉及此场景需求的行业&#xff1a; 1.大数据行业&#xff1a;随着大数据的行业应用不断深入&#xff0c;物联网、智能家居、数字政务等领域的大数据技术应用逐渐成熟&#xff0c;数据采集的需求也将被逐步激…
阅读更多...
0723，UDP通信（聪明小辉聪明小辉），HTTP协议

0723，UDP通信（聪明小辉聪明小辉），HTTP协议

我就是一个爱屋及乌的人&#xff01;&#xff01;&#xff01;&#xff01; #include "network_disk_kai.h" 昨天的epoll&#xff1a; 可恶抄错代码了 epoll_s.csockect return listenfdsetsockoptsockaddr_in bind listenfd & serveraddr…
阅读更多...
Zilliz 推出 Spark Connector：简化非结构化数据处理流程

Zilliz 推出 Spark Connector：简化非结构化数据处理流程

随着人工智能&#xff08;AI&#xff09;和深度学习&#xff08;Deep Learning&#xff09;技术的高速发展&#xff0c;使用神经网络模型将数据转化为 Embedding 向量 已成为处理非结构化数据并实现语义检索的首选方法&#xff0c;广泛应用于搜索、推荐系统等 AI 业务中。 以生…
阅读更多...
Windows 11+Visual Studio 2022 环境OpenCV+CUDA 12.5安装及踩坑笔记

Windows 11+Visual Studio 2022 环境OpenCV+CUDA 12.5安装及踩坑笔记

周六日在家捣腾了一下&#xff0c;把过程记录下来。 前置条件 Visual Studio C 生成工具和本机显卡适配的CUDA与CUDA匹配的cuDNNPython 3NumPyOpenCV源代码以及对应版本的OpenCV-contrib模块源码CMake Visual Studio 下载Visual Studio&#xff08;我本机的是VS2022&#xf…
阅读更多...
虚拟局域网配置与分析-VLAN

虚拟局域网配置与分析-VLAN

前言&#xff1a;本博客仅作记录学习使用&#xff0c;部分图片出自网络&#xff0c;如有侵犯您的权益&#xff0c;请联系删除 一、相关知识 虚拟局域网&#xff08;Virtual Local Area Network&#xff0c;VLAN&#xff09;是一组逻辑上的设备和用户&#xff1b;不受物理位置的…
阅读更多...
二、【Python】入门 - 【PyCharm】安装教程

二、【Python】入门 - 【PyCharm】安装教程

往期博主文章分享文章&#xff1a; 【机器学习】专栏http://t.csdnimg.cn/sQBvw 目录 第一步&#xff1a;PyCharm下载 第二步&#xff1a;安装&#xff08;点击安装包打开下图页面&#xff09; 第三步&#xff1a;科学使用&#xff0c;请前往下载最新工具及教程&#xff1a…
阅读更多...
前端：Vue学习-3

前端：Vue学习-3

前端&#xff1a;Vue学习-3 1. 自定义指令2. 插槽2.1 插槽 - 后备内容&#xff08;默认值&#xff09;2.2 插槽 - 具名插槽2.3 插槽 - 作用域插槽 3. Vue - 路由3.1 路由模块封装3.2 声明式导航 router-link 高亮3.3 自定义匹配的类名3.4 声明式导肮 - 跳转传参3.5 Vue路由 - 重…
阅读更多...
C#初级——条件判断语句和循环语句

C#初级——条件判断语句和循环语句

条件判断语句 简单的条件判断语句&#xff0c;if()里面进行条件判断&#xff0c;如果条件判断正确就执行语句块1&#xff0c;如果不符合就执行语句块2。 if (条件判断) { 语句块1 } else { 语句块2 } int age 18;if (age < 18){Console.WriteLine("未…
阅读更多...
Python面试宝典第18题：单词搜索

Python面试宝典第18题：单词搜索

题目 给定一个m x n的二维字符网格board和一个字符串单词word。如果word存在于网格中&#xff0c;返回true。否则&#xff0c;返回false。单词必须按照字母顺序&#xff0c;通过相邻的单元格内的字母构成。所谓相邻单元格&#xff0c;是那些水平相邻或垂直相邻的单元格。 备注&…
阅读更多...
Blender材质-PBR与纹理材质

Blender材质-PBR与纹理材质

1.PBR PBR:Physically Based Rendering 基于物理的渲染 BRDF:Bidirection Reflectance Distribution Function 双向散射分散函数 材质着色操作如下图&#xff1a; 2.纹理材质 左上角&#xff1a;编辑器类型中选择&#xff0c;着色器编辑器 新建着色器 -> 新建纹理 -> 新…
阅读更多...
爬虫学习3：爬虫的深度爬取

爬虫学习3：爬虫的深度爬取

爬虫的深度爬取和爬取视频的方式 深度爬取豆瓣读书 import time import fake_useragent import requests from lxml import etree head {"User-Agent":"Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/126.0.0.0 …
阅读更多...
[AWS]MSK调用，报错Access denied

[AWS]MSK调用，报错Access denied

背景&#xff1a;首先MSK就是配置一个AWS的托管 kafka&#xff0c;创建完成之后就交给开发进行使用&#xff0c;开发通常是从代码中&#xff0c;编写AWS的access_key 和secret_key进行调用。 但是开发在进行调用的时候&#xff0c;一直报错连接失败&#xff0c;其实问题很简单&…
阅读更多...
AI学习记录 - 本地知识库实现的相关知识

AI学习记录 - 本地知识库实现的相关知识

在公司内部实现了个知识库&#xff0c;由于保密吗&#xff0c;只介绍在实现知识库的过程中用到的知识&#xff08;虽然知识库也是个烂大街的东西了hehehehe&#xff09; 1、分词器 先分词&#xff0c;中文可以使用jieba分词 2、构造数据集 将词汇向量化是自然语言处理中的…
阅读更多...
OpenHarmony 开发

OpenHarmony 开发

本心、输入输出、结果 文章目录 OpenHarmony 开发前言JonathanOpenHarmony 并不是 AndroidOpenHarmony 应用迁移OpenHarmony 的开发流程OpenHarmony 开发 编辑 | 简简单单 Online zuozuo 地址 | https://blog.csdn.net/qq_15071263 如果觉得本文对你有帮助，欢迎点赞、收藏、评…
阅读更多...
【北京迅为】《i.MX8MM嵌入式Linux开发指南》-第三篇 嵌入式Linux驱动开发篇-第四十七章 字符设备和杂项设备总结回顾

【北京迅为】《i.MX8MM嵌入式Linux开发指南》-第三篇 嵌入式Linux驱动开发篇-第四十七章 字符设备和杂项设备总结回顾

i.MX8MM处理器采用了先进的14LPCFinFET工艺&#xff0c;提供更快的速度和更高的电源效率;四核Cortex-A53&#xff0c;单核Cortex-M4&#xff0c;多达五个内核 &#xff0c;主频高达1.8GHz&#xff0c;2G DDR4内存、8G EMMC存储。千兆工业级以太网、MIPI-DSI、USB HOST、WIFI/BT…
阅读更多...
vim gcc

vim gcc

vim 使用 vs filename 分屏 ctrl ww 切窗口 shift zz 快速提出vim vim配置 vim启动时自动读取当前用户的家目录的.vimrc文件 vim配置只影响本用户 其他用户观看同一文件不受影响 gcc指令 & c文件编译过程 动态库 静态库 & 链接方式 有相应库才能进行…
阅读更多...
数据传输安全--IPSEC

数据传输安全--IPSEC

目录 IPSEC IPSEC可以提供的安全服务 IPSEC 协议簇 两种工作模式 传输模式 隧道模式 两个通信保护协议&#xff08;两个安全协议&#xff09; AH&#xff08;鉴别头协议&#xff09; 可以提供的安全服务 报头 安全索引参数SPI 序列号 认证数据 AH保护范围 传输模…
阅读更多...
深入浅出WebRTC—LossBasedBweV2

深入浅出WebRTC—LossBasedBweV2

WebRTC 同时使用基于丢包的带宽估计算法和基于延迟的带宽估计算法那&#xff0c;能够实现更加全面和准确的带宽评估和控制。基于丢包的带宽估计算法主要依据网络中的丢包情况来动态调整带宽估计&#xff0c;以适应网络状况的变化。本文主要讲解最新 LossBasedBweV2 的实现。 1…
阅读更多...
推荐文章
最新文章

Copyright @ 2022~2023