基于oracle数据库存储过程的创建及调用

news2024/9/22 2:24:53

基于oracle数据库存储过程的创建及调用

教学大纲：

  1. PLSQL编程：Hello World、程序结构、变量、流程控制、游标.
  2. 存储过程：概念、无参存储、有参存储（输入、输出）.
  3. JAVA调用存储存储过程.

1. PLSQL编程

1.1. 概念和目的

什么是PL/SQL?

  1. PL/SQL（Procedure Language/SQL）
  2. PLSQL是Oracle对sql语言的过程化扩展 (类似于Basic)
  3. 指在SQL命令语言中增加了过程处理语句（如分支、循环等），使SQL语言具有过程处理能力。

1.2. 程序结构

通过Plsql Developer工具的Test Window 创建 程序模版或者通过语句在SQL Window编写

提示：PLSQL语言的大小写是不区分的

PL/SQL可以分为三个部分：声明部分、可执行部分、异常处理部分。

-- Created on 2018/3/21 by ADMINISTRATOR 
DECLARE
  -- 声明变量、游标。
  I INTEGER;
BEGIN
  -- 执行语句

  --[异常处理]

END;

其中 DECLARE部分用来声明变量或游标（结果集类型变量），如果程序中无变量声明可以省略掉

1.3. Hello World

BEGIN

  --打印hello world

  DBMS_OUTPUT.PUT_LINE('hello world');

END;

其中DBMS_OUTPUT 为oracle内置程序包，相当于Java中的System.out,而PUT_LINE（）是调用的方法,相当于println（）方法

在sqlplus中也可以编写运行PLSQL程序：

SQL> BEGIN
  2
  3    --打印hello world
  4
  5    DBMS_OUTPUT.PUT_LINE('hello world');
  6
  7  END;
  8  /

PL/SQL 过程已成功完成。

执行结束后并未显示输出的结果，默认情况下，输出选项是关闭状态的 我们需要开启一下 set serveroutput on
请添加图片描述
SQLPLUS中执行PLSQL程序 需要在程序最后添加一个 / 标识程序的结束

1.4. 变量

PLSQL编程中常见的变量分两大类：

  1. 普通数据类型（char,varchar2, date, number, boolean, long）

  2. 特殊变量类型（引用型变量、记录型变量）

声明变量的方式为

变量名  变量类型（变量长度）  例如： v_name  varchar2(20);

1.4.1. 普通变量

变量赋值的方式有两种：

  1. 直接赋值语句 := 比如: v_name := ‘zhangsan’
  2. 语句赋值，使用select …into … 赋值：（语法 select 值 into 变量）

【示例】打印人员个人信息，包括： 姓名、薪水、地址

-- 打印人员个人信息，包括： 姓名、薪水、地址
DECLARE
  -- 姓名
  V_NAME VARCHAR2(20) := '张三'; -- 声明变量直接赋值
  --薪水
  V_SAL NUMBER;
  --地址
  V_ADDR VARCHAR2(200);

BEGIN

  --在程序中直接赋值
  V_SAL := 1580;

  --语句赋值
  SELECT '上海市传智播客' INTO V_ADDR FROM DUAL;

  --打印变量
  DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || ',薪水：' || V_SAL || ',地址：' ||V_ADDR);

END;

1.4.2. 引用型变量

变量的类型和长度取决于表中字段的类型和长度

通过表名.列名%TYPE指定变量的类型和长度，例如： v_name emp.ename%TYPE;

【示例】查询emp表中7839号员工的个人信息，打印姓名和薪水

-- 查询emp表中7839号员工的个人信息，打印姓名和薪水
DECLARE
  -- 姓名
  V_NAME EMP.ENAME%TYPE; -- 声明变量直接赋值
  --薪水
  V_SAL EMP.SAL%TYPE;

BEGIN
  --查询表中的姓名和薪水并赋值给变量
  --注意查询的字段和赋值的变量的顺序、个数、类型要一致
  SELECT ENAME, SAL INTO V_NAME, V_SAL FROM EMP WHERE EMPNO = 7839;

  --打印变量
  DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || ',薪水：' || V_SAL);

END;

引用型变量的好处：

使用普通变量定义方式，需要知道表中列的类型，而使用引用类型，不需要考虑列的类型，使用%TYPE是非常好的编程风格，因为它使得PL/SQL更加灵活，更加适应于对数据库定义的更新。

1.4.3. 记录型变量

接受表中的一整行记录，相当于Java中的一个对象

语法： 变量名称 表名%ROWTYPE， 例如： v_emp emp%rowtype;

【示例】

查询并打印7839号员工的姓名和薪水

-- 查询emp表中7839号员工的个人信息，打印姓名和薪水
DECLARE
  -- 记录型变量接受一行
  V_EMP EMP%ROWTYPE;

BEGIN
  --记录型变量默认接受表中的一行数据，不能指定字段。
  SELECT * INTO V_EMP FROM EMP WHERE EMPNO = 7839;

  --打印变量，通过变量名.属性的方式获取变量中的值
  DBMS_OUTPUT.PUT_LINE('姓名：' || V_EMP.ENAME || ',薪水：' || V_EMP.SAL);

END;

如果有一个表，有100个字段，那么你程序如果要使用这100字段话，如果你使用引用型变量一个个声明，会特别麻烦，记录型变量可以方便的解决这个问题

错误的使用：

1． 记录型变量只能存储一个完整的行数据

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-bOZs1kKY-1693138890299)(img/Image 5.png)]

2．返回的行太多了，记录型变量也接收不了

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-wP56Ka55-1693138890299)(img/Image 6.png)]

1.5. 流程控制

1.5.1. 条件分支

语法：

BEGIN

  IF 条件1 THEN 执行1
    
   ELSIF 条件2 THEN 执行 2
  
   ELSE 执行3
    
  END IF; 
  
END;

注意关键字：ELSIF

【示例】判断emp表中记录是否超过20条，10-20之间，或者10条以下

DECLARE
  --声明变量接受emp表中的记录数
  V_COUNT NUMBER;

BEGIN

  --查询emp表中的记录数赋值给变量

  SELECT COUNT(1) INTO V_COUNT FROM EMP;

  --判断打印

  IF V_COUNT > 20 THEN
    DBMS_OUTPUT.PUT_LINE('EMP表中的记录数超过了20条为：' || V_COUNT || '条。');

  ELSIF V_COUNT >= 10 THEN
    DBMS_OUTPUT.PUT_LINE('EMP表中的记录数在10~20条之间为：' || V_COUNT || '条。');

  ELSE
    DBMS_OUTPUT.PUT_LINE('EMP表中的记录数在10条以下为：' || V_COUNT || '条。');

  END IF;

END;

1.5.2. 循环

在ORACLE中有三种循环方式，这里我们不展开,只介绍其中一种：loop循环

语法：

BEGIN
  LOOP
  	EXIT WHEN 退出循环条件  
  END LOOP;
END;

【示例】打印数字1-10

DECLARE
 --声明循环变量并赋初值
 V_NUM NUMBER := 1;

BEGIN

 LOOP
 
   EXIT WHEN V_NUM > 10;
   
   DBMS_OUTPUT.PUT_LINE(V_NUM);
 
   --循环变量自增
   V_NUM := V_NUM + 1;
 
 END LOOP;

END;

2. 游标

2.1. 什么是游标

用于临时存储一个查询返回的多行数据（结果集,类似于Java的Jdbc连接返回的ResultSet集合），通过遍历游标，可以逐行访问处理该结果集的数据。

游标的使用方式：声明—>打开—>读取—>关闭

2.2. 语法

游标声明：

CURSOR 游标名[(参数列表)] IS 查询语句;

游标的打开：

OPEN 游标名;

游标的取值：

FETCH 游标名 INTO 变量列表;

游标的关闭：

CLOSE 游标名;

2.3. 游标的属性

游标的属性返回值类型说明
%ROWCOUNT整型获得FETCH语句返回的数据行数
%FOUND布尔型最近的FETCH语句返回一行数据则为真，否则为假
%NOTFOUND布尔型与%FOUND属性返回值相反
%ISOPEN布尔型游标已经打开时值为真，否则为假

其中 %NOTFOUND是在游标中找不到元素的时候返回TRUE,通常用来判断退出循环

2.4. 创建和使用

【示例】使用游标查询emp表中所有员工的姓名和工资，并将其依次打印出来。

--使用游标查询emp表中所有员工的姓名和工资，并将其依次打印出来。
DECLARE
 --声明游标
 CURSOR C_EMP IS
   SELECT ENAME, SAL FROM EMP;

 --声明变量用来接受游标中的元素
 V_ENAME EMP.ENAME%TYPE;

 V_SAL EMP.SAL%TYPE;

BEGIN

 --打开游标
 OPEN C_EMP;

 --遍历游标中的值
 LOOP
 
   --通过FETCH语句获取游标中的值并赋值给变量
   FETCH C_EMP
     INTO V_ENAME, V_SAL;
 
   --通过%NOTFOUND判断是否有值,有值打印,没有则退出循环
   EXIT WHEN C_EMP%NOTFOUND;
 
   DBMS_OUTPUT.PUT_LINE('姓名:' || V_ENAME || ',薪水:' || V_SAL);
 
 END LOOP;

 --关闭游标
 CLOSE C_EMP;

END;

执行结果:

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-1FuXzDRT-1693138890300)(img/Image 7.png)]

2.5. 带参数的游标

【示例】使用游标查询并打印某部门的员工的姓名和薪资，部门编号为运行时手动输入。

 --使用游标查询并打印某部门的员工的姓名和薪资，部门编号为运行时手动输入。
DECLARE
  --声明游标传递参数
  CURSOR C_EMP(V_EMPNO EMP.EMPNO%TYPE) IS
    SELECT ENAME, SAL FROM EMP WHERE EMPNO = V_EMPNO;

  --声明变量用来接受游标中的元素
  V_ENAME EMP.ENAME%TYPE;

  V_SAL EMP.SAL%TYPE;

BEGIN

  --打开游标并传递参数
  OPEN C_EMP(10);

  --遍历游标中的值
  LOOP

 


       --通过%NOTFOUND判断是否有值,有值打印,没有则退出循环
       EXIT WHEN C_EMP%NOTFOUND;
       
       --通过FETCH语句获取游标中的值并赋值给变量
    FETCH C_EMP
      INTO V_ENAME, V_SAL;

    DBMS_OUTPUT.PUT_LINE('姓名:' || V_ENAME || ',薪水:' || V_SAL);


  END LOOP;

  --关闭游标
  CLOSE C_EMP;

END;

注意:%NOTFOUND属性默认值为FLASE,所以在循环中要注意判断条件的位置.如果先判断在FETCH会导致最后一条记录的值被打印两次(多循环一次默认);

3. 存储过程

3.1. 概念作用

之前我们编写的PLSQL程序可以进行表的操作,判断,循环逻辑处理的工作,但无法重复调用.

可以理解之前的代码全都编写在了main方法中,是匿名程序. JAVA可以通过封装对象和方法来解决复用问题

PLSQL是将一个个PLSQL的业务处理过程存储起来进行复用,这些被存储起来的PLSQL程序称之为存储过程

存储过程作用：

1， 在开发程序中，为了一个特定的业务功能，会向数据库进行多次连接关闭(连接和关闭是很耗费资源), 需要对数据库进行多次I/O读写，性能比较低。如果把这些业务放到PLSQL中，在应用程序中只需要调用PLSQL就可以做到连接关闭一次数据库就可以实现我们的业务,可以大大提高效率.

2， ORACLE官方给的建议：能够让数据库操作的不要放在程序中。在数据库中实现基本上不会出现错误，在程序中操作可能会存在错误.(如果在数据库中操作数据,可以有一定的日志恢复等功能.)

3.2. 语法

CREATE OR REPLACE PROCEDURE 过程名称[(参数列表)] IS
BEGIN

END [过程名称];

根据参数的类型，我们将其分为3类讲解：

l 不带参数的

l 带输入参数的

l 带输入输出参数(返回值)的。

3.3. 无参存储

3.3.1. 创建存储

通过Plsql Developer或者语句创建存储过程:

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-0VwfCLqh-1693138890300)(img/Image 8.png)]

【示例】 通过调用存储过程打印hello world

创建存储过程:

--通过调用存储过程打印hello world
CREATE OR REPLACE PROCEDURE P_HELLO IS
BEGIN

  DBMS_OUTPUT.PUT_LINE('hello world');

END P_HELLO;

通过工具查看创建好的存储过程:

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-ovaGoALp-1693138890300)(img/Image 9.png)]

3.3.2. 调用存储过程

  1. 通过PLSQL程序调用：
BEGIN
 --直接输入调用存储过程的名称
  P_HELLO;

END P_HELLO;
  1. 在SQLPLUS中通过EXEC命令调用:

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-ew4Ti2FY-1693138890301)(img/1521617110557.png)]

提示:SQLPLUS中显示结果的前提是需要 set serveroutput on

注意：

第一个问题：is和as是可以互用的，用哪个都没关系的
第二个问题：过程中没有declare关键字，declare用在语句块中

3.4. 带输入参数的存储过程

【示例】查询并打印某个员工（如7839号员工）的姓名和薪水–存储过程：要求，调用的时候传入员工编号，自动控制台打印。

--查询并打印某个员工（如7839号员工）的姓名和薪水
--要求，调用的时候传入员工编号，自动控制台打印。
CREATE OR REPLACE PROCEDURE P_QUERYNAMEANDSAL(I_EMPNO IN EMP.EMPNO%TYPE) IS
  --声明变量接受查询结果
  V_ENAME EMP.ENAME%TYPE;
  V_SAL   EMP.SAL%TYPE;

BEGIN

  --根据用户传递的员工号查询姓名和薪水
  SELECT ENAME, SAL INTO V_ENAME, V_SAL FROM EMP WHERE EMPNO = I_EMPNO;

  --打印结果
  DBMS_OUTPUT.PUT_LINE('姓名:' || V_ENAME || ',薪水:' || V_SAL);

END P_QUERYNAMEANDSAL;

命令调用：

SQL> exec p_querynameandsal(7839);
姓名:KING,薪水:5000

PL/SQL 过程已成功完成。

PLSQL程序调用：

BEGIN

 P_QUERYNAMEANDSAL(7839);

END;

执行结果:

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-Ejwoh4oR-1693138890301)(img/1521617584136.png)]

3.5. 带输出参数的存储过程

【示例】输入员工号查询某个员工（7839号员工）信息，要求，将薪水作为返回值输出，给调用的程序使用。

 --输入员工号查询某个员工（7839号员工）信息，要求，将薪水作为返回值输出，给调用的程序使用。
CREATE OR REPLACE PROCEDURE P_QUERYSAL_OUT(I_EMPNO IN EMP.EMPNO%TYPE,O_SAL OUT EMP.SAL%TYPE) IS

BEGIN

  SELECT SAL INTO O_SAL FROM EMP WHERE EMPNO = I_EMPNO;

END P_QUERYSAL_OUT;

PLSQL程序调用：

DECLARE
  --声明一个变量接受存储过程的输出参数
  V_SAL EMP.SAL%TYPE;

BEGIN

  P_QUERYSAL_OUT(7839, V_SAL); --注意参数的顺序

  DBMS_OUTPUT.PUT_LINE(V_SAL);

END;

注意:调用的时候,参数要与定义的参数的顺序和类型一致.

3.7. JAVA程序调用存储过程

需求:如果一条语句无法实现结果集, 比如需要多表查询,或者需要复杂逻辑查询,我们可以选择调用存储查询出你的结果.

3.7.1. 分析jdk API

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-sZmncKhT-1693138890301)(img/1521621189862.png)]

通过Connection对象的prepareCall方法可以调用存储过程

[外链图片转存失败,源站可能有防盗链机制,建议将图片保存下来直接上传(img-893FnryQ-1693138890301)(img/1521621415263.png)]

得出结论: 通过Connection对象调用prepareCall方法传递一个转义sql语句调用存储过程, 输入参数直接调用set方法传递.输出参数需要注册后,执行存储过程,通过get方法获取.参数列表的下标是从1开始的

3.7.2. 实现代码

准备环境：

l 导入Oracle的jar包

【示例】通过员工号查询员工的姓名和薪资

package cn.itcast.oracle.jdbc;

import oracle.jdbc.OracleTypes;
import java.sql.CallableStatement;
import java.sql.Connection;
import java.sql.DriverManager;

public class ProcedureTest {
    public static void main(String[] args) throws Exception {
        //1.加载驱动
        Class.forName("oracle.jdbc.driver.OracleDriver");

        //2.获得连接对象

        //2.1 设置连接字符串
        String url ="jdbc:oracle:thin:@localhost:1521:xe" ;

        String name = "scott";

        String password = "tiger";

        Connection conn = DriverManager.getConnection(url, name, password);


        //3.获取语句对象
        String sql = "{call p_querysal_out(?,?)}";//转义语法,{call  存储过程(参数列表)}
        CallableStatement call = conn.prepareCall(sql);

        //4.设置输入参数
        call.setInt(1,7839);

        //5.注册输出参数
        call.registerOutParameter(2, OracleTypes.DOUBLE);

        //6.执行存储过程
        call.execute();

        //7.获取输出参数
        double sal = call.getDouble(2);
        System.out.println("薪水:"+sal);

        //8.释放资源
        call.close();
        conn.close();

    }
}

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：http://www.coloradmin.cn/o/936498.html

如若内容造成侵权/违法违规/事实不符，请联系多彩编程网进行投诉反馈，一经查实，立即删除！

相关文章

力扣真题：无重复字符的最长子串（三种方法）

力扣真题：无重复字符的最长子串（三种方法）

这道题我一开始使用了Set加类似滑动窗口的方法，最后解得出来，但效率不尽人意，最后经过几次修改，最终用到是滑动窗口指针数组的方式讲效果达到最优，超过近99%的代码。 1、第一版 class Solution {public int lengthOf…
阅读更多...
python 双向链表

python 双向链表

双向链表基本介绍 双向链表增删改查操作思路分析 双向链表增删改查操作代码实现 """ 双向链表的增删改查 """# 英雄类 class HeroNode:next None # 指向下一个节点，默认为空pre None # 指向前一个节点，默认为空def …
阅读更多...
STM32 CubeMX (H750)RGB屏幕 LTDC

STM32 CubeMX (H750)RGB屏幕 LTDC

STM32 CubeMX STM32 RGB888 LTDC STM32 CubeMX一、STM32 CubeMX 设置时钟树LTDC使能设置屏幕参数修改RGB888的GPIO 二、代码部分效果 RGB屏幕线束定义： 一、STM32 CubeMX 设置 时钟树 这里设置的时钟，关于刷新速度 举例子：LCD_CLK24MHz 时…
阅读更多...
福利之舞：员工的心跳与企业的平衡术

福利之舞：员工的心跳与企业的平衡术

引言：员工福利与满意度的关系 在现代企业中，员工福利已经不仅仅是一种待遇，而是与员工满意度、忠诚度和生产力紧密相连的关键因素。一个合理且吸引人的福利制度可以大大提高员工的工作积极性，同时也能够吸引和留住顶尖的人才。但…
阅读更多...
ElasticSearch（一）数据类型

ElasticSearch（一）数据类型

ElasticSearch&#xff08;一&#xff09;数据类型 1.简述 Es数据类型分为基础数据类型和复杂类型数据&#xff0c;掌握ES数据类型才能进一步使用ES检索数据内容。 <dependency><groupId>org.springframework.boot</groupId><artifactId>spring-boot…
阅读更多...
【MySQL系列】Select语句单表查询详解入门（SELECT，AS，模糊查询，运算符，逻辑运算符）

【MySQL系列】Select语句单表查询详解入门（SELECT，AS，模糊查询，运算符，逻辑运算符）

&#x1f490; &#x1f338; &#x1f337; &#x1f340; &#x1f339; &#x1f33b; &#x1f33a; &#x1f341; &#x1f343; &#x1f342; &#x1f33f; &#x1f344;&#x1f35d; &#x1f35b; &#x1f364; &#x1f4c3;个人主页 &#xff1a;阿然成长日记 …
阅读更多...
【80天学习完《深入理解计算机系统》】第十一天 3.5 过程（函数调用）

【80天学习完《深入理解计算机系统》】第十一天 3.5 过程（函数调用）

专注 效率 记忆 预习 笔记 复习 做题 欢迎观看我的博客&#xff0c;如有问题交流&#xff0c;欢迎评论区留言&#xff0c;一定尽快回复&#xff01;&#xff08;大家可以去看我的专栏&#xff0c;是所有文章的目录&#xff09; 　 文章字体风格&#xff1a; 红色文字表示&#…
阅读更多...
【JAVA】String 类

【JAVA】String 类

⭐ 作者&#xff1a;小胡_不糊涂 &#x1f331; 作者主页&#xff1a;小胡_不糊涂的个人主页 &#x1f4c0; 收录专栏&#xff1a;浅谈Java &#x1f496; 持续更文&#xff0c;关注博主少走弯路&#xff0c;谢谢大家支持 &#x1f496; String 1. 字符串构造2. String对象的比…
阅读更多...
快速封禁大法--东方日报JS解密过程

快速封禁大法--东方日报JS解密过程

破解难点&#xff1a; 1.所有接口参数都有时间限制&#xff0c;且与当前加载页面绑定&#xff0c;参数无法在短期内复用 2. token参数破解&#xff1a;点击翻页时第一个加载的接口&#xff0c;会返回一个token&#xff08;详见&#xff1a;get_token() 函数内容&#xff09; 3.…
阅读更多...
lab8 lock

lab8 lock

PreRead 第六章3.5节&#xff1a;物理内存分配器8.1-8.3 文章目录 PreReadMemory allocatortaskshints思路 Buffer cachetaskhints思路实现 这次的lab&#xff0c;本质上都是通过将锁的粒度减小来获得性能的提升 第一个task&#xff0c;可以简单地按cpu划分&#xff0c;因为本…
阅读更多...
Python Opencv实践 - Sobel边缘检测

Python Opencv实践 - Sobel边缘检测

import cv2 as cv import numpy as np import matplotlib.pyplot as pltimg cv.imread("../SampleImages/pomeranian.png", cv.IMREAD_GRAYSCALE) print(img.shape)#Sobel边缘检测 #cv.sobel( src, ddepth, dx, dy[,ksize[, scale[, delta[, borderType]]]] ) #src:…
阅读更多...
当面临在职备考不确定性的结果时，你可能需要闭着眼冲一下

当面临在职备考不确定性的结果时，你可能需要闭着眼冲一下

提前批面试在某种程度上像是联考分流幕后的那只无形之手&#xff0c;既助长了拿到优秀资格考生的备考热情&#xff0c;又打击了提面落榜考生的笔试自信心。就在这样的局面下&#xff0c;使得项目最终完成了联考前的分流操作。但如果你还是遵从自己的本心的话&#xff0c;就应该…
阅读更多...
算法-图BFS/DFS-单词接龙

算法-图BFS/DFS-单词接龙

算法-图BFS/DFS-单词接龙 1 题目概述 1.1 题目出处 https://leetcode-cn.com/problems/number-of-islands 1.2 题目描述 给定两个单词&#xff08;beginWord 和 endWord&#xff09;和一个字典&#xff0c;找到从 beginWord 到 endWord 的最短转换序列的长度。转换需遵循如…
阅读更多...
2023年6月GESP C++ 三级试卷解析

2023年6月GESP C++ 三级试卷解析

2023年6月GESP C 三级试卷解析 一、单选题&#xff08;每题2分&#xff0c;共30分&#xff09; 1.高级语言编写的程序需要经过以下&#xff08; &#xff09;操作&#xff0c;可以生成在计算机上运行的可执行代码。 A.编辑 B.保存 C.调试 D.编译 【答案】D 【考纲知识点…
阅读更多...
LeetCode-406-根据身高重建队列

LeetCode-406-根据身高重建队列

题目描述&#xff1a; 假设有打乱顺序的一群人站成一个队列&#xff0c;数组 people 表示队列中一些人的属性&#xff08;不一定按顺序&#xff09;。每个 people[i] [hi, ki] 表示第 i 个人的身高为 hi &#xff0c;前面 正好 有 ki 个身高大于或等于 hi 的人。 请你重新构造…
阅读更多...
IDEA项目启动的时候找不到类

IDEA项目启动的时候找不到类

IDEA项目启动的时候找不到类 我在运行微服务的项目的时候启动多个项目由于存在依赖关系&#xff0c;但是我确实是引入了对应的依赖的地址但是就是找不到对应的类。 解决的方法&#xff1a;
阅读更多...
代码随想录算法训练营第四十八天|LeetCode 583，72，编辑距离总结篇

代码随想录算法训练营第四十八天|LeetCode 583，72，编辑距离总结篇

目录 LeetCode 583.两个字符串的删除操作 动态规划五步曲&#xff1a; 1.确定dp[i][j]的含义 2.找出递推公式 3.初始化dp数组 4.确定遍历方向 5.打印dp数组 LeetCode 72.编辑距离 动态规划五步曲&#xff1a; 1.确定dp[i][j]的含义 2.找出递推公式 3.初始化dp数组 4.确定遍历方…
阅读更多...
模2运算规则

模2运算规则

模2加法 模2加法没有进位&#xff0c;等同于异或运算。一位数的模2加法规则如下&#xff1a; 0 0 0 0 1 1 1 0 1 1 1 0 多位数的模2加法中&#xff0c;每一位都按照上面的规则进行&#xff0c;例如: 当多个数相加&#xff0c;对应位置上如果有偶数个1&#xff0c;…
阅读更多...
【OpenCV实战】3.OpenCV颜色空间实战

【OpenCV实战】3.OpenCV颜色空间实战

OpenCV颜色空间实战 〇、Coding实战内容一、imread1.1 函数介绍1.2 Flags1.3 Code 二. 色彩空间2.1 获取单色空间2.2. HSV、YUV、RGB2.3. 不同颜色空间应用场景 〇、Coding实战内容 OpenCV imread()方法不同的flags差异性获取单色通道【R通道、G通道、B通道】HSV、YUV、RGB 一…
阅读更多...
基于学生心理学算法优化的BP神经网络（预测应用） - 附代码

基于学生心理学算法优化的BP神经网络（预测应用） - 附代码

基于学生心理学算法优化的BP神经网络&#xff08;预测应用&#xff09; - 附代码 文章目录 基于学生心理学算法优化的BP神经网络&#xff08;预测应用&#xff09; - 附代码1.数据介绍2.学生心理学优化BP神经网络2.1 BP神经网络参数设置2.2 学生心理学算法应用 4.测试结果&…
阅读更多...
推荐文章
最新文章

Copyright @ 2022~2023