手写操作系统--进入保护模式的开篇

news2024/9/29 7:26:32

之前我们讲的主引导扇区以及内核加载器等内容。都是在实模式下运行的。在实模式下寻址范围仅有1M，是远远不够我们用的。我们想要更大的内存空间，就得进入保护模式，实模式是一个历史遗留问题，本身是没有这个名字的。是因为有了保护模式才对原先的8086模式起个名字叫实模式。为何叫保护模式呢，顾名思义，是有些东西想要保护起来。我们回顾实模式，内核和用户程序都跑在同一个内存空间中。地址都是实际的物理地址。分分钟可以修改别人的程序甚至是内核程序。这样做是非常危险的。因此保护模式想在根源上杜绝这些问题因此就有了更多的保护措施。下面我们一一道来。

（1）首先，寄存器的扩展

如上图所示，实模式下的16位寄存器都变成了32位（除了段寄存器）并且在原先的寄存器名字上多了个E，表示扩展。如果是64位的话扩展名就是R比如说RAX。我们只讨论32位的，64位只是顺带提一句。

下面我们介绍下段寄存器。在原先的实模式下，想访问超过64KB的内存就需要借助段寄存器才能把20跟地址线充分利用，也就是访问1M的内存，公式我们前面介绍过（段寄存器*16+偏移地址）

进入保护模式后，32位的CPU拥有着访问4GB内存的能力，远不是1M能比的，此时不再需要段寄存器来辅助寻址，那这么说段寄存器岂不是没用了？然而并不是，段寄存器在进入保护模式后，叫段选择子，386之后还扩展了两个段寄存器（fs,gs）段选择子如图所示：

这就是段选择子也就是我们实模式下的段寄存器。它的0-1比特位是表示特权级，就是访问权限。保护模式嘛必然加了很多安全的东西。我们知道在intel的架构提供了几种特权级别：

这样的圈我们也称为环。比如最里面的level 0也叫0环。是权限最高的一个给操作系统使用的。往外还有1环，2环，3环。但是在现代操作系统（windows,Linux）均没有使用1环2环权限。只使用了0环和3环也就是我们教科书上对应的内核态和用户态，这是权限级别。

讲完了特权级我们回到段选择子中，看到第三个比特位TI，这是表示访问的是GDT还是LDT，如果为1访问的是GDT，如果为0访问的是LDT。至于什么是GDT,LDT后面我们会介绍。，最后就是3-15位比特位。这是一个索引值。用于检索GDT表项。你可以把它理解为是数组的下标索引。GDT也称为全局描述符表，是一个类似于数组的这么一个表。这个表有多大呢，就是我们索引的最大值也就是13个1，也就是8192个（0也算，真实情况下第一个项是全0，能用的其实是8191个）：

GDT中的每一项也叫段描述符。段选择子的最大功能就是索引到对应的段描述符。什么是段描述符呢？

图示就是一个段描述符。这是一个64位的段描述符。里面记录了很多有用的信息。我们现在只需要关注一些重点就可以了。毕竟这么描述符挺复杂的。低32位的16-31比特位与高32位的0-7和24-31共同组成了一个32位的线性地址（这个地址不是真实的物理地址是需要转换的）。低32位的0-15位和高32位的16-19位组成一个20位的界限，记录了这个段的长度。这是最基本的信息，有了这些信息我们就能找到对应的段在什么位置以及它有多长。其次高32位的8-11这4个比特位标识一个类型。会把找到的段标识为数据段还是代码段还是系统段。先介绍这么多。以后有些位我们用到在细说。

可能会很好奇为什么这个段描述符长的这么怪，一个段地址分为三份。那是因为Intel能走到今天这么一个硬件大帝国。靠的就是它的兼容性。为了兼容之前的产品（中间出过一个80286，地址总线24根）那么它的描述符长的就很规范:

这是80386的段描述符：

段描述符就是这么进化而来的。我们写操作系统的时候用的是80386的段描述符，也就是最后一个图。

x86使用一个寄存器来指GDT表的首地址这个寄存器是GDTR:

我们能操作的指令是:

lgdt  [指针] ;加载GDT
sgdt  [指针] ;保存GDT

下面我们在讲讲A20线：

为了兼容8086，A20线默认是关闭的，想要访问超过实模式下1M的内存，我们必须把这个A20线打开，有兴趣的可以查查这A20的历史，我也不是很懂。

下面上代码：

memory_base equ 0   ;   内存基址=0
memory_limit equ ((1024*1024*1024*4)/(1024*4))-1  ;4G/4K -1

;第一步构建段描述符，相当于C语言定义一个结构体
gdt_base:              ;第1一个 也就是索引为0的是不可用的 全为0
    dd 0, 0
gdt_code:             ;构建代码段，数据段段描述符
    dw memory_limit & 0xffff ;段界限0-15位
    dw memory_base & 0xffff ;基地址的0-16位
    db (memory_base>>16)& 0xff ;基地址16-23位
    db 0b_1_00_1_1_0_1_0 ;存在 - dlp 0 - S _ 代码 - 非依从 - 可读 - 没有被访问过
    ; 4k - 32 位 - 不是 64 位 - 段界限 16 ~ 19
    db 0b1_1_0_0_0000 | (memory_limit >> 16) & 0xf;
    db (memory_base >> 24) & 0xff; 基地址 24 ~ 31 位
gdt_data:
     dw memory_limit & 0xffff; 段界限 0 ~ 15 位
    dw memory_base & 0xffff; 基地址 0 ~ 15 位
    db (memory_base >> 16) & 0xff; 基地址 16 ~ 23 位
    ; 存在 - dlp 0 - S _ 数据 - 向上 - 可写 - 没有被访问过
    db 0b_1_00_1_0_0_1_0;
    ; 4k - 32 位 - 不是 64 位 - 段界限 16 ~ 19
    db 0b1_1_0_0_0000 | (memory_limit >> 16) & 0xf;
    db (memory_base >> 24) & 0xff; 基地址 24 ~ 31 位
gdt_end:

;第二步 定义好gdtr寄存器 参考上图gdtr寄存器的比特位

gdt_ptr:
    dw (gdt_end - gdt_base)- 1
    dd gdt_base

;第三步 定义好段选择子 参考选择子的比特位

code_selector equ (1 << 3) ;这里很巧妙 将变成8 也就是1000 访问索引为1 ，访问的是GDT ，访问的权限是系统级
data_selector equ (2 << 3)   ;2左移3位是10000 10表示索引2 访问GDT ， 访问权限是系统级

;第四步 打开A20 启动保护模式
  xchg bx, bx  ; 断点

    cli; 关闭中断

    ; 打开 A20 线
    in al,  0x92
    or al, 0b10
    out 0x92, al

    lgdt [gdt_ptr]; 加载 gdt

    ; 启动保护模式
    mov eax, cr0
    or eax, 1
    mov cr0, eax

    ; 用跳转来刷新缓存，启用保护模式
    jmp dword code_selector:protect_mode

;第五步 进入保护模式 用保护模式输入超过1M的内存空间

[bits 32] ;告诉编译器进入32位
protect_mode:
    xchg bx, bx; 断点
    mov ax, data_selector
    mov ds, ax
    mov es, ax
    mov fs, ax
    mov gs, ax
    mov ss, ax; 初始化段寄存器

    mov esp, 0x10000; 修改栈顶

    mov byte [0xb8000], "P"
    mov byte [0x200000], "P"

这些代码全部在内核加载器中实现，我们看看实际效果：

实模式下即将进入保护模式