寄存器说明
以cortex-M3，首先先要了解比较特别的几个寄存器：
r15 PC程序计数器（Program Counter）,存储下一条要执行的指令的地址。
r14 LR连接寄存器（Link Register ），保存函数返回地址，当通过BL或BLX指令调用函数时，硬件自动将函数返回地址保存在R14寄存器中。当函数完成时，将LR值传到PC，即可返回到被调用位置。
r13 SP 堆栈指针(Process Stack Pointer)，保护现场和恢复现场要用，当发生异常的时候，硬件会把当前状态（使用到寄存器数值）保存在堆栈中，SP保存这个堆栈指针，异常处理完成，通过SP出栈，恢复到异常前的状态，可以时MSP、PSP。
CPSR程序状态寄存器(current program status register)，CPSR和其他寄存器不一样,其他寄存器是用来存放数据的,都是整个寄存器具有一个含义.而CPSR寄存器是按位起作用的,也就是说,它的每一位都有专门的含义。
函数形参被放在R0-R3中，超过4个参数值传递则放栈里。
双堆栈指针
双堆栈指针对于任务现场保护、恢复现场至关重要。
【双堆栈指针（MSP&PSP）】
- Cortex-M3内核中有两个堆栈指针（MSP & PSP），但任何时刻只能使用到其中一个。
- 复位后处于线程模式特权级，默认使用MSP。
- 通过SP访问到的是正在使用的那个指针，可以通过MSR/MRS指令访问指定的堆栈指针。
- 通过设置CONTROL寄存器的bit[1]选择使用哪个堆栈指针。CONTROL[1]=0选择主堆栈指针；CONTROL[1]=1选择进程堆栈指针。
- Handler模式下，只允许使用主堆栈指针MSP；PSP一般用在线程模式，任务执行就是用到这个PSP；线程模式下可以使用MSP，也可以使用PSP。
对于裸机程序，一直使用MSP。对于有OS的程序，OS内核和中断使用MSP，而应用程序task则使用PSP。
那双堆栈指针的作用是什么？答案是为了隔离OS和应用程序，程序的运行少不了堆栈，因为我们CPU只有少量的通用寄存器，当我们使用的临时变量比较多得时候，就需要将这些临时变量存储到堆栈里，而堆栈的push和pop都是通过SP来实现的，所以通过MSP和PSP就能实现OS内核与应用程序的隔离，应用程序task用PSP，而OS用MSP，这样会非常安全。因为应用程序再怎么折腾也只是在自己的堆栈内折腾，不会影响内核OS。
MCU上电执行过程
向量表中的MSP初始值和复位向量:
CM3离开复位状态时，首先要做的是读取下面两个值（根据boot执行，硬件自动执行）：
从地址0x0000 0000,取出MSP(主堆栈指针)的值 从地址0x0000 0004,取出复位向量(程序开始执行的地 址， LSB必须是1）
汇编启动文件，主要做了堆栈空间分配，更新MSP指针，跳到Reset_Handler执行，执行SystemInit并返回，再执行到__main，虽然会执行到main函数，但是这个__main和main函数是不一样，再跳到main函数时，还会做一些操作。
FreeRTOS调度过程
简单分析：
重点在于任务初始化、SVC、pendsv、systick
任务栈初始化
这个栈空间，就是我们任务初始化的内存空间，是一个全局数组。
栈顶指针
栈顶指针-1 状态寄存器XPSR
栈顶指针-2 任务线程函数指针 PC
栈顶指针-3 LR 函数返回地址
栈顶指针-8 R12、R3、R2、R1、R0
栈顶指针-16 R11、R10、R9、R8、R7、R6、R5、R4
异常返回时，异常完成时，进行出栈，恢复先前压入栈的寄存器值xPSP， PC， LR,R12以及R3~R0寄存器的值，恢复堆栈指针值，根据栈指针。(这是由硬件去完成) 后面会用到。
进入SVC系统调用：
执行第一个任务，MSP地址更新（多余），进入SVC系统调用
__asm void prvStartFirstTask( void )
{
PRESERVE8
/* 在Cortex-M中，0xE000ED08是SCB_VTOR这个寄存器的地址，
里面存放的是向量表的起始地址，即MSP的地址 MCU上电就做了，该步骤多余*/
ldr r0, =0xE000ED08
ldr r0, [r0]
ldr r0, [r0]
/* 设置主堆栈指针msp的值 */
msr msp, r0
/* 使能全局中断 */
cpsie i
cpsie f
dsb
isb
/* 调用SVC去启动第一个任务 */
svc 0
nop
nop
}
执行SVC，跳到执行用户的第一个任务
__asm void vPortSVCHandler( void )
{
/*在进入异常前 会将 把xPSP， PC， LR,R12以及R3~R0寄存器的值压入栈 ，由硬件完成
因为这个函数是不返回，这个可以不关心。
*/
extern pxCurrentTCB;
PRESERVE8
ldr r3, =pxCurrentTCB /* 加载pxCurrentTCB的地址到r3 */
ldr r1, [r3] /* 加载pxCurrentTCB到r1 */
ldr r0, [r1] /* 加载pxCurrentTCB指向的值到r0，目前r0的值等于第一个任务堆栈的栈顶
ldmia r0!, {r4-r11} /* 以r0为基地址，将栈里面的内容加载到r4~r11寄存器，同时r0会递增 */
msr psp, r0 /* 将r0的值，即任务的栈指针更新到psp 后面异常退出时，根据SPS进行出栈， 就是前面任务栈初始化值出栈给到寄存器*/
isb
mov r0, #0 /* 设置r0的值为0 */
msr basepri, r0 /* 设置basepri寄存器的值为0，即所有的中断都没有被屏蔽 */
orr r14, #0xd /* 当从SVC中断服务退出前,通过向r14寄存器最后4位按位或上0x0D，
使得硬件在退出时使用进程堆栈指针PSP完成出栈操作并返回后进入线程模式、返回Thumb状态 */
bx r14 /* 异常返回，这个时候栈中的剩下内容将会自动加载到CPU寄存器：
xPSR，PC（任务入口地址），R14，R12，R3，R2，R1，R0（任务的形参）
同时PSP的值也将更新，即指向任务栈的栈顶 */
}
此时调度器就执行第一个任务。
任务切换
pendSV中断服务函数实现任务切换。
执行portYIELD,手动触发pendSV中断
#define portYIELD() \
{ \
/* 触发PendSV，产生上下文切换 */ \
portNVIC_INT_CTRL_REG = portNVIC_PENDSVSET_BIT; \
__dsb( portSY_FULL_READ_WRITE ); \
__isb( portSY_FULL_READ_WRITE ); \
}
pendSV
__asm void xPortPendSVHandler( void )
{
extern pxCurrentTCB;
extern vTaskSwitchContext;
PRESERVE8
/* 当进入PendSVC Handler时，上一个任务运行的环境即：
xPSR，PC（任务入口地址），R14，R12，R3，R2，R1，R0（任务的形参）
这些CPU寄存器的值会自动保存到任务的栈中，剩下的r4~r11需要手动保存 */
/* 获取任务栈指针到r0 */
mrs r0, psp
isb
ldr r3, =pxCurrentTCB /* 加载pxCurrentTCB的地址到r3 */
ldr r2, [r3] /* 加载pxCurrentTCB到r2 */
stmdb r0!, {r4-r11} /* 将CPU寄存器r4~r11的值存储到r0指向的地址 */
str r0, [r2] /* 将任务栈的新的栈顶指针存储到当前任务TCB的第一个成员，即栈顶指针 */
//以上 上下文保存
stmdb sp!, {r3, r14} /* 将R3和R14临时压入堆栈，因为即将调用函数vTaskSwitchContext,
调用函数时,返回地址自动保存到R14中,所以一旦调用发生,R14的值会被覆盖,因此需要入栈保护;
R3保存的当前激活的任务TCB指针(pxCurrentTCB)地址,函数调用后会用到,因此也要入栈保护 */
mov r0, #configMAX_SYSCALL_INTERRUPT_PRIORITY /* 进入临界段 */
msr basepri, r0
dsb
isb
bl vTaskSwitchContext /* 调用函数vTaskSwitchContext，寻找新的任务运行,通过使变量pxCurrentTCB指向新的任务来实现任务切换 */
mov r0, #0 /* 退出临界段 */
msr basepri, r0
ldmia sp!, {r3, r14} /* 恢复r3和r14 */
ldr r1, [r3]
ldr r0, [r1] /* 当前激活的任务TCB第一项保存了任务堆栈的栈顶,现在栈顶值存入R0*/
ldmia r0!, {r4-r11} /* 出栈 */
msr psp, r0
isb
bx r14 /* 异常发生时,R14中保存异常返回标志,包括返回后进入线程模式还是处理器模式、
使用PSP堆栈指针还是MSP堆栈指针，当调用 bx r14指令后，硬件会知道要从异常返回，
然后出栈，这个时候堆栈指针PSP已经指向了新任务堆栈的正确位置，
当新任务的运行地址被出栈到PC寄存器后，新的任务也会被执行。*/
nop
}
参考资料：
[野火®]《FreeRTOS 内核实现与应用开发实战—基于STM32》
猪哥-嵌入式
