【UE5】将2D切片图渲染为体积纹理，最终实现使用RT实时绘制体积纹理【第四篇-着色器投影-接收阴影部分】

上一章中实现了体积渲染的光照与自阴影，那我们这篇来实现投影

回顾

勘误

在开始本篇内容之前，我已经对上一章中的内容的错误进行了修改。为了确保不会错过这些更正，同时也避免大家重新阅读一遍，我将在这里为大家演示一下修改的具体内容。

错误连接：在之前的文章里，SkyLightEnvMapSample 错误地连接到了“光源方向”。
正确连接：实际上，需要沿垂直方向 (0,0,-1) 进行采样，这样才能与 SkyAtmosphere 的结果保持一致。

(图为SkyLightEnvMapSample 正确的输入)

扩展:
快速的制作一个左右分屏，对比一下两者:

在材质编辑器没有SkyAtmosphere，因此左侧没有环境光:

在场景中，可以看到左右两侧的天光是基本一致的:

准备工作：整理和完善

再开始本章工作前，先对我们的凌乱的Shader做一次整理和完善吧！

整理

整理Freams

首先我们正式将XYFrames拆成两个参数，因为怕有人忘记这是一个float2值

在这里插入图片描述
我们有一段时间不会再见到他们了，把他们 折叠到节点 ，收纳起来

起个名改个引脚，后续的相同操作就不多说明了

整理Base

本章中还需要修改这里，所以先不打包
但我们把Density移动到LightVecor上方
在这里插入图片描述

之前	之后

Tip:
在这里拖动

Tip：
小懒蛋们，在文章最后展示全部代码的分，完整的输入节点的"快速粘贴"

完善光照输入

在上一章中介绍了多种对环境光照的取值方式，我们现在为他们制作切换函数

1.整理输入

调整位置，将LightVector LightColor SkyColor 三个相关输入摆放在一起：
（图中演示的是不基于SkyAtmosphere，都做相同操作）

之前	之后

2.制作函数

在这里插入图片描述
将它们折叠到函数，起名VolumeLight
(如果你使用的是早期UE5版本，则需要手动创建材质函数)

为其增加Input ，输入类型为StaticBool，三个输入分别命名为
UseSkyAtmosphere CustomLightVector CustomColor

我们可以使用一个小技巧，在材质中创建一个“结构体”，然后通过Switch节点进行切换，从而减少Switch节点的数量。
现在，我们已经制作了一个函数，使其可以在几种方式之间进行切换。
需要特别说明的是，实际传递的内容与MaterialAttributes节点使用的名字无关。例如，在全局位置偏移中实际放置的是LightVector。
在这里插入图片描述

在这里插入图片描述

上面这几张整体截图中，Input的输入类型是 Bool ，但应该像第一张图一样是 StaticBool

归一化

为了出于对转换结果的安全考虑，这里增加一个归一化
在这里插入图片描述

世界空间LightVectorWS

我们保留一个未转换为本地空间的光照方向作为输出，稍后会用到
在这里插入图片描述

Tip：为了避免造成误解，需要再次说明，实际传递的内容与 MaterialAttributes 节点上使用的名字无关。例如，在 全局位置偏移 中，实际放置的是 LightVector 。只是将它作为"结构体"使用。

完成后是这个样子
在这里插入图片描述

3.整理SelfShadow

好现在我么可以整理剩下的东西了
在这里插入图片描述
如上图，直接折叠，改好名即可

Done
清爽啦
现在已经把环境整理妥当，那就开始本章内容吧！

制作Shader

简单的概述

接下来的阴影效果会将着色器的复杂度提升一大截。

需要注意的是，着色器讲究的是“看上去对的”就是“对的”。除非你确实有重大需求，否则没有必要无脑地加入更多功能，以免增加不必要的复杂度。目前，体积雾的着色器已经在计算光照的过程中实现了“自阴影”，这在很多情况已经足够了。

接下来，我们要为其增加另外两种阴影效果，分别是“体积雾对其他物体投射的阴影（投射阴影）”和“其他物体在体积雾上的阴影（接收阴影）”

接收阴影

在材质球中实现真正的“接收阴影”是一项非常复杂的任务，这对于Shader来说是非常昂贵和不切实际的。然而，我们可以利用“距离场阴影”技术来实现相似的效果。UE引擎已经广泛应用了这种技术，它计算成本低且能够生成柔和的软阴影，在性能和视觉效果之间取得了良好的平衡。

因此，我们的“接收阴影”本质上是实现一个“距离场阴影”。不过，在这篇文章中，我不会详细介绍“距离场阴影”的具体实现，因为相关信息已经很容易找到。未来，我计划写一些基于距离场的效果，届时会对“距离场阴影”进行更详细的介绍。

接下来的工作是采样全局距离场，以实现所需的阴影效果。

增加变量

在这里插入图片描述

为 RayMarching 新增4个输入

输入	说明
LightVectorWS	世界空间光方向
CameraPosWS	世界空间相机位置
LocalObjectBoundsMax	本地空间的Bound框大小
LightTangent	光切线,也就是对距离场步进时的距离，这将决定阴影边缘的模糊程度
DFSSteps	`DistanceFieldShdowSteps` 的缩写，距离场阴影的采样步数

快速粘贴

((InputName="Tex"),(InputName="XYFrames"),(InputName="NumFrames"),(InputName="MaxSteps"),(InputName="StepSize"),(InputName="LocalCamVec"),(InputName="CurPos"),(InputName="FinalStepSize"),(InputName="Density"),(InputName="LightVector"),(InputName="LightColor",Input=(OutputIndex=1)),(InputName="SkyColor",Input=(OutputIndex=2)),(InputName="ShadowSteps"),(InputName="ShadowStepSize"),(InputName="ShadowDensity"),(InputName="ShadowThreshold"),(InputName="AmbientDensity"),(InputName="LightVectorWS"),(InputName="CameraPosWS"),(InputName="LocalObjectBoundsMax",Input=(OutputIndex=3,Mask=1,MaskR=1,MaskG=1,MaskB=1)),(InputName="LightTangent"),(InputName="DFSSteps")

增加代码

RayMarching代码如下:

//创建变量，从0开始累加沿相机方向步进过程中的总密度
float accumdens = 0;

//Shadow部分
//创建变量，透射率和光线的能量
float transmittance =1;
float3 lightenergy = 0;
//基本和相机方向步进一样，但这些都是常量，不需要写进for里
Density *= StepSize;
LightVector *= ShadowStepSize;
ShadowDensity *= ShadowStepSize;
//一个对数来计算阈值，用来判断光线是否还值得计算
float shadowthresh = -log(ShadowThreshold)/ShadowDensity;

//使用 MaxSteps 作为最大步数进行循环，每次循环执行以下操作
for (int i = 0; i < MaxSteps; i++)
{
    float cursample = PseudoVolumeTexture(Tex, TexSampler, saturate(CurPos), XYFrames, NumFrames).r;// 在当前步进位置进行纹理采样

    //Shadow部分
    if(cursample > 0.001)//如果采样位置没有密度，则跳过
    {
        float3 Lpos = CurPos;//Lpos将作为光线步进的起始位置
        float shadowdist = 0;//和之前的accumdens一样，积累阴影
        
        //自阴影
        for(int s = 0; s < ShadowSteps; s++)
        {
            Lpos += LightVector;//移动步进位置
            float Lsample = PseudoVolumeTexture(Tex, TexSampler, saturate(Lpos), XYFrames, NumFrames).r;//采样
            
            //判断是否在框内，不是则直接break退出for
            float3 shadowboxtest = floor( 0.5+ (abs(0.5-Lpos)));
            //float exitshadowbox = shadowboxtest.x + shadowboxtest.y + shadowboxtest.z;
            float exitshadowbox = dot(shadowboxtest,1);//简短的通道相加
            if(shadowdist > shadowthresh || exitshadowbox >= 1) break;

            shadowdist += Lsample;//累计
        }

        //接收阴影
        float3 dfpos = 2 * (CurPos -0.5) * LocalObjectBoundsMax;//-0.5 * 2，得到一个居中的Bound
        dfpos = LWCToFloat(TransformLocalPositionToWorld(Parameters,dfpos)) - CameraPosWS;//将dfpos转换为世界空间，需要LWC精度所以在代码里转换，减去相机位置
        float dftracedist = 1; //创建四个变量
        float dfshadow = 1;//这是我们最终要的
        float curdist = 0;
        float DistanceAlongTrace = 0;

        for (int d = 0; d < DFSSteps; d++)//又一次的光线步进
        {
            DistanceAlongTrace += curdist;//增加距离
            curdist = GetDistanceToNearestSurfaceGlobal(dfpos);//采样全局距离场，他和蓝图里`DistanceToNearestSurface`是相同函数

            float SphereSize = DistanceAlongTrace * LightTangent;//采样距离场软阴影的球形距离

            dfshadow = min( saturate(curdist/SphereSize),dfshadow);//用小于它的结果来更新变量

            dfpos.xyz += LightVectorWS * dftracedist * curdist;//继续移动位置
            dftracedist *= 1.0001;//增加一个很小的因子
        }


        //更新样本和光能，算法是BeersLaw函数
        cursample = 1 -exp(-cursample * Density);
        lightenergy += exp(-shadowdist * ShadowDensity) * cursample * transmittance * LightColor * dfshadow;//在结果上乘dfshadow
        transmittance *= 1-cursample;
        
        //环境光照部分
        shadowdist = 0;//重置一下阴影距离，继续利用它计算光照

        Lpos = CurPos + float3(0,0,0.025);//新位置
        float Lsample = PseudoVolumeTexture(Tex, TexSampler, saturate(Lpos), XYFrames, NumFrames).r;//采样
        shadowdist += Lsample;

        Lpos = CurPos + float3(0,0,0.05);
        Lsample = PseudoVolumeTexture(Tex, TexSampler, saturate(Lpos), XYFrames, NumFrames).r;//采样
        shadowdist += Lsample;

        Lpos = CurPos + float3(0,0,0.15);
        Lsample = PseudoVolumeTexture(Tex, TexSampler, saturate(Lpos), XYFrames, NumFrames).r;//采样
        shadowdist += Lsample;

        lightenergy += exp(-shadowdist * AmbientDensity) *cursample * SkyColor * transmittance;//累计到光

   
    }

    CurPos += -LocalCamVec;
}

CurPos += LocalCamVec * (1 - FinalStepSize);
float cursample = PseudoVolumeTexture(Tex, TexSampler, saturate(CurPos), XYFrames, NumFrames).r;

return float4(lightenergy, transmittance);

这是增加的部分:
在这里插入图片描述

正像之前说的，这里不介绍距离场阴影的原理，总之我们在上一章自阴影的下方又写了接收阴影，并在后面lightenergy的累计里带上了dfshadow

Tip:
使用custom写hlsl的一大缺点就是没啥向后兼容性，EPIC改不改函数名字完全取决于心情。这里使用了一个函数 GetDistanceToNearestSurfaceGlobal() 他就是蓝图中的 DistanceToNearestSurface , 如果将来哪个版本里函数报错了，希望你知道你需要找什么。