使用方法

1. 新建txt文本文件，将下方代码粘贴进去
2. 编辑对应的jdk路径 如：set JAVA_HOME=D:\Java\jdk-17.0.11
3. 修改文件后缀为bat，双击运行选择对应版本

@echo off
rem 切换Java jdk版本
echo 请以管理员来进行切换
java -version
 
:menu
echo =============================================
echo 请选择要切换的jdk版本
echo 1：Java jdk 1.8
echo 2：Java jdk 17
echo 3: 取消
echo =============================================
set /p ch=请选择：
if "%ch%"=="1" goto java1.8
if "%ch%"=="2" goto java17
if "%ch%"=="3" goto exit
goto menu
 
 
:java17
set JAVA_HOME=D:\Java\jdk-17.0.11
set JRE_HOME=D:\Java\jdk-17.0.11
set JAVA_VERSION=17
goto exec
 
 
:java1.8
set JAVA_HOME=D:\Java\jdk1.8.0_371
set JRE_HOME=D:\Java\jdk1.8.0_371
set JAVA_VERSION=1.8
goto exec
 
:exec
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit" /v CurrentVersion /t REG_SZ /f /d "%JAVA_VERSION%"
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment" /v CurrentVersion /t REG_SZ /f /d "%JAVA_VERSION%"
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v JAVA_HOME /t REG_SZ /f /d "%JAVA_HOME%"
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v JRE_HOME /t REG_SZ /f /d "%JRE_HOME%"

echo 已切换到JDK %JAVA_VERSION%
echo ！！在环境变量窗口点击确定刷新版本！！
rundll32 sysdm.cpl,EditEnvironmentVariables
pause
goto exit
:exit