STM32之HAL开发——启动文件详解【精华版】

启动文件介绍

启动文件是使用机器认识的汇编语言，由汇编编写，是系统上电复位后第一个执行的程序，经过一些必要的配置，最终能够调用 main 函数，使得用户程序能够在 MCU上正常运行起来的必备文件。

无论是是何种MCU，从简单的51，MSP430，到ARM9，ARM11，A7 都必须有启动文件，因为对于嵌入式开发，绝大部分情况都是使用C语言，而C语言一般都是从main函数开始，但是对于MCU来说，他是如何找到并执行main函数的，就需要用到“启动文件”，就是各种 startup_xxxx.s 文件。

如下图就是STM32F103系列的启动文件
在这里插入图片描述
从代码中的描述部分可以看出，stm32f103系列单片机启动文件主要做了如下工作！

初始化堆栈指针 SP（__initial_sp）
初始化 PC 指针（Reset_Handler）
初始化中断向量表（__Vectors）
配置系统时钟（SystemInit）
调用 C 库函数 _main 初始化用户堆栈，从而最终调用 main 函数去到 C 的世界

ARM汇编指令查找

在stm32中的启动文件中有许多我们看不懂的汇编指令，这些汇编指令需要我们去查找它的用法。ARM 的汇编指令我们可以在MDK->Help->Uvision Help 中搜索到，以 EQU 为例，检索如下：
在这里插入图片描述检索出来的结果会有很多，我们只需要看 Assembler User Guide 这部分即可。下面列出了启动文件中使用到的 ARM 汇编指令，该列表的指令全部从 ARM Development Tools 这个帮助文档里面检索而来。其中编译器相关的指令 WEAK 和 ALIGN 为了方便也放在同一个表格了。

常见指令表格

在这里插入图片描述

启动方式介绍

在这里插入图片描述

【主闪存存储器】STM32内置的Flash，一般我们使用JTAG或者SWD模式下载程序时，就是下载到这个里面，重启后也直接从这启动程序，可以理解为电脑中的软件安装在这里。
【内置 SRAM】芯片内置的RAM区，没有程序存储的能力了，可以理解为这个是电脑的内存条。
【系统存储器】一块特定的区域，只读ROM存储器，STM32厂家在这个区域内部预置了一段BootLoader，也就是我们常说的ISP程序，出厂后无法修改。选用这种模式启动,可以从串口下载程序到Flash中，可以理解为电脑中的Window系统安装在这里。

启动文件代码详解

栈的介绍

Stack_Size      EQU     0x00000400
                AREA    STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem       SPACE   Stack_Size
__initial_sp

开辟栈的大小为 0X00000400（1KB），名字为 STACK， NOINIT 即不初始化，可读可写， 8（2^3）
字节对齐。
栈的作用是用于局部变量，函数调用，函数形参等的开销，栈的大小不能超过内部 SRAM 的大小。如果编写的程序比较大，定义的局部变量很多，那么就需要修改栈的大小。如果某一天，你写的程序出现了莫名奇怪的错误，并进入了硬 fault 的时候，这时你就要考虑下是不是栈不够大，溢出了。

堆的介绍

Heap_Size       EQU     0x00000200
                AREA    HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem        SPACE   Heap_Size
__heap_limit

开辟堆的大小为 0X00000200（512 字节），名字为 HEAP， NOINIT 即不初始化，可读可写， 8（2^3）字节对齐。 __heap_base 表示对的起始地址， __heap_limit 表示堆的结束地址。堆是由低向高生长的，跟栈的生长方向相反。
堆主要用来动态内存的分配，像 malloc() 函数申请的内存就在堆上面。这个在 STM32 里面用的比较少。

特殊指令介绍

PRESERVE8：指定当前文件的堆栈按照 8 字节对齐。
THUMB：表示后面指令兼容 THUMB 指令。 THUBM 是 ARM 以前的指令集， 16bit，现在 Cortex-M系列的都使用 THUMB-2 指令集， THUMB-2 是 32 位的，兼容 16 位和 32 位的指令，是 THUMB的超集

向量表介绍

当内核响应了一个发生的异常后，对应的异常服务例程 (ESR) 就会执行。为了决定 ESR 的入口地址，内核使用了“向量表查表机制”。这里使用一张向量表。向量表其实是一个 WORD（32 位整数）数组，每个下标对应一种异常，该下标元素的值则是该 ESR 的入口地址。向量表在地址空间中的位置是可以设置的，通过 NVIC 中的一个重定位寄存器来指出向量表的地址。在复位后，该寄存器的值为 0。因此，在地址 0 （即 FLASH 地址 0）处必须包含一张向量表，用于初始时的异常分配。要注意的是这里有个另类： 0 号类型并不是什么入口地址，而是给出了复位后 MSP （栈顶指针）的初值。
在这里插入图片描述

向量表相关代码介绍

AREA    RESET, DATA, READONLY
EXPORT  __Vectors
EXPORT  __Vectors_End
EXPORT  __Vectors_Size

定义一个数据段，名字为 RESET，可读。并声明 __Vectors、 __Vectors_End 和 __Vectors_Size 这三个标号具有全局属性，可供外部的文件调用。

__Vectors       DCD     __initial_sp               ; Top of Stack
                DCD     Reset_Handler              ; Reset Handler
                DCD     NMI_Handler                ; NMI Handler
                DCD     HardFault_Handler          ; Hard Fault Handler
                DCD     MemManage_Handler          ; MPU Fault Handler
                DCD     BusFault_Handler           ; Bus Fault Handler
                DCD     UsageFault_Handler         ; Usage Fault Handler
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     SVC_Handler                ; SVCall Handler
                DCD     DebugMon_Handler           ; Debug Monitor Handler
                DCD     0                          ; Reserved
                DCD     PendSV_Handler             ; PendSV Handler
                DCD     SysTick_Handler            ; SysTick Handler

                ; External Interrupts
                DCD     WWDG_IRQHandler            ; Window Watchdog
                DCD     PVD_IRQHandler             ; PVD through EXTI Line detect
                DCD     TAMPER_IRQHandler          ; Tamper
                DCD     RTC_IRQHandler             ; RTC
                DCD     FLASH_IRQHandler           ; Flash
                DCD     RCC_IRQHandler             ; RCC
                DCD     EXTI0_IRQHandler           ; EXTI Line 0
                DCD     EXTI1_IRQHandler           ; EXTI Line 1
                ......
__Vectors_End

__Vectors 为向量表起始地址， __Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。向量表从FLASH的0地址开始放置，以4个字节为一个单位，地址0存放的是栈顶地址，0X04存放的是复位程序的地址，以此类推。从代码上看，向量表中存放的都是中断服务函数的函数名，可我们知道 C 语言中的函数名就是一个地址
DCD：分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内存。在向量表中DCD 分配了一堆内存，并且以 ESR 的入口地址初始化它们

复位程序介绍

Reset_Handler   PROC
                EXPORT  Reset_Handler             [WEAK]
                IMPORT  __main
                IMPORT  SystemInit
                LDR     R0, =SystemInit
                BLX     R0               
                LDR     R0, =__main
                BX      R0
                ENDP

复位子程序是系统上电后第一个执行的程序，调用 SystemInit 函数初始化系统时钟，然后调用 C库函数 _mian，最终调用 main 函数去到 C 的世界。

WEAK：表示弱定义，如果外部文件优先定义了该标号则首先引用该标号，如果外部文件没有声明也不会出错。这里表示复位子程序可以由用户在其他文件重新实现，这里并不是唯一的。
IMPORT：表示该标号来自外部文件，跟 C 语言中的 EXTERN 关键字类似。这里表示 SystemInit 和__main这两个函数均来自外部的文件。

中断服务程序介绍

在启动文件里面已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的，真正的中断复服务程序需要我们在外部的 C 文件里面重新实现，这里只是提前占了一个位置而已。
如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时，程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无线循环，即程序就死在这里。

NMI_Handler     PROC
                EXPORT  NMI_Handler                [WEAK]
                B       .
                ENDP
HardFault_Handler\
                PROC
                EXPORT  HardFault_Handler          [WEAK]
                B       .
                ENDP
....
Default_Handler PROC
                EXPORT  WWDG_IRQHandler            [WEAK]
                EXPORT  PVD_IRQHandler             [WEAK]
                EXPORT  TAMPER_IRQHandler          [WEAK]
....

B：跳转到一个标号。这里跳转到一个‘ .’，即表示无线循环。

用户堆栈初始化

             IF      :DEF:__MICROLIB
            
             EXPORT  __initial_sp
             EXPORT  __heap_base
             EXPORT  __heap_limit
            
             ELSE
            
             IMPORT  __use_two_region_memory
             EXPORT  __user_initial_stackheap

__user_initial_stackheap

             LDR     R0, =  Heap_Mem
             LDR     R1, =(Stack_Mem + Stack_Size)
             LDR     R2, = (Heap_Mem +  Heap_Size)
             LDR     R3, = Stack_Mem
             BX      LR

             ALIGN

             ENDIF

             END

首先判断是否定义了 __MICROLIB，如果定义了这个宏则赋予标号 __initial_sp（栈顶地址）、__heap_base（堆起始地址）、 __heap_limit（堆结束地址）全局属性，可供外部文件调用。有关这个宏我们在 KEIL 里面配置，具体见图下。然后堆栈的初始化就由 C 库函数 _main 来完成。
在这里插入图片描述
如果没有定义 __MICROLIB，则插入标号 __use_two_region_memory，这个函数需要用户自己实
现，具体要实现成什么样，可在 KEIL 的帮助文档里面查询到。