【ESP-NOW with ESP32：向多个开发板发送数据（一对多）】

news2025/2/24 10:03:18

【ESP-NOW with ESP32：向多个开发板发送数据（一对多）】

  • 1. 项目概况
  • 2. 先决条件
    • 2.1 环境配置
    • 2.2 所需零件
  • 3. 获取主板 MAC 地址
  • 4. ESP32 发射器 （ESP-NOW）
    • 4.1 接收方的MAC地址
    • 4.2 OnDataSent（） 回调函数
    • 4.3 setup（）
    • 4.4 添加对等节点
    • 4.5 loop（）
    • 4.6 将相同的数据发送到多个板
    • 4.7 向每个板发送不同的数据
  • 5. ESP32 接收器代码 （ESP-NOW）
  • 6. ESP8266 接收器代码 （ESP-NOW）
  • 7. 示范
  • 8. 总结

在本教程中，您将学习如何使用 ESP-NOW 通信协议将数据从一个 ESP32 发送到多个 ESP32 或 ESP8266 开发板（一对多配置）。这些板将使用Arduino IDE进行编程。
在这里插入图片描述

ESP-NOW with ESP32：通过 NodeMCU 向多个板卡发送数据 一对多 ESP8266
要在 ESP32 或 ESP8266 上开始使用 ESP-NOW，请先阅读以下 ESP-NOW 指南：

ESP-NOW 入门（ESP32 with Arduino IDE）
ESP-NOW 入门（ESP8266 NodeMCU 和 Arduino IDE）
ESP-NOW with ESP32：从多个开发板接收数据（多对一）

1. 项目概况

本教程介绍如何使用 ESP-NOW（一对多配置）将数据从一个 ESP32 发送到多个 ESP32 或 ESP8266 开发板。

ESP-NOW with ESP32：向多个开发板发送数据（一对多） 项目概况

  • 一个 ESP32 充当发送器;
  • 多个 ESP32 或 ESP8266 板充当接收器。我们同时使用两块 ESP32 开发板和一块
    ESP8266 开发板测试了此设置。您应该能够将更多板添加到您的设置中;
    如果消息成功投递，ESP32发送方将收到确认消息。您知道哪些看板收到了消息，哪些看板没有收到消息; 您需要上传略有不同的接收器代码，具体取决于您使用的是 ESP32还是 ESP8266;
    例如，我们将在板之间交换随机值。您应该修改此示例以发送命令或传感器读数（使用 ESP-NOW 交换传感器读数）。

本教程涵盖以下两种方案：

  • 向所有板发送相同的消息;
  • 向每个看板发送不同的消息。

您可能还喜欢阅读： ESP-NOW ESP32 开发板之间的双向通信。

2. 先决条件

我们将使用 Arduino IDE 对 ESP32/ESP8266 开发板进行编程，因此在继续本教程之前，请确保已在 Arduino IDE 中安装这些开发板。

2.1 环境配置

在 Arduino IDE 中安装 ESP32 开发板（Windows、Mac OS X 和 Linux）
在Arduino IDE中安装ESP8266板（Windows，Mac OS X，Linux）

2.2 所需零件

要学习本教程，您需要多个 ESP32 开发板和/或 ESP8266 开发板。

  • ESP32（阅读最佳 ESP32 开发板 )
  • ESP8266（阅读最佳 ESP8266 开发板 )

3. 获取主板 MAC 地址

要通过 ESP-NOW 发送消息，您需要知道接收器板的 MAC 地址。每个开发板都有一个唯一的 MAC 地址（了解如何获取和更改 ESP32 MAC 地址）。

将以下代码上传到每个接收器板以获取其 MAC 地址。

// Complete Instructions to Get and Change ESP MAC Address: https://RandomNerdTutorials.com/get-change-esp32-esp8266-mac-address-arduino/

#ifdef ESP32
  #include <WiFi.h>
#else
  #include <ESP8266WiFi.h>
#endif

void setup(){
  Serial.begin(115200);
  Serial.println();
  Serial.print("ESP Board MAC Address:  ");
  Serial.println(WiFi.macAddress());
}
 
void loop(){

}

上传代码后，按 RST/EN 按钮，MAC 地址应显示在串行监视器上。

ESP32 开发板 MAC 地址，带 Arduino IDE 串行监视器

您可以在标签上写下主板的 MAC 地址，以清楚地识别每个主板。

识别 ESP32 开发板 MAC 地址

4. ESP32 发射器 （ESP-NOW）

以下代码通过 ESP-NOW 将数据发送到多个（三个）ESP 板。您应该使用接收器板的 MAC 地址修改代码。您还应该根据接收器板的数量添加或删除代码行。

/*********
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp-now-one-to-many-esp32-esp8266/
  
  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.
  
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

#include <esp_now.h>
#include <WiFi.h>

// REPLACE WITH YOUR ESP RECEIVER'S MAC ADDRESS
uint8_t broadcastAddress1[] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};
uint8_t broadcastAddress2[] = {0xFF, , , , , };
uint8_t broadcastAddress3[] = {0xFF, , , , , };

typedef struct test_struct {
  int x;
  int y;
} test_struct;

test_struct test;

esp_now_peer_info_t peerInfo;

// callback when data is sent
void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  char macStr[18];
  Serial.print("Packet to: ");
  // Copies the sender mac address to a string
  snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
           mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
  Serial.print(macStr);
  Serial.print(" send status:\t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}
 
void setup() {
  Serial.begin(115200);
 
  WiFi.mode(WIFI_STA);
 
  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }
  
  esp_now_register_send_cb(OnDataSent);
   
  // register peer
  peerInfo.channel = 0;  
  peerInfo.encrypt = false;
  // register first peer  
  memcpy(peerInfo.peer_addr, broadcastAddress1, 6);
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
  // register second peer  
  memcpy(peerInfo.peer_addr, broadcastAddress2, 6);
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
  /// register third peer
  memcpy(peerInfo.peer_addr, broadcastAddress3, 6);
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
}
 
void loop() {
  test.x = random(0,20);
  test.y = random(0,20);
 
  esp_err_t result = esp_now_send(0, (uint8_t *) &test, sizeof(test_struct));
   
  if (result == ESP_OK) {
    Serial.println("Sent with success");
  }
  else {
    Serial.println("Error sending the data");
  }
  delay(2000);
}

代码的工作原理，首先，包括esp_now.h和WiFi.h的图书馆。

#include <esp_now.h>
#include <WiFi.h>

4.1 接收方的MAC地址

插入接收方的 MAC 地址。在我们的示例中，我们将数据发送到三个板。

uint8_t broadcastAddress1[] = {0x3C, 0x71, 0xBF, 0xC3, 0xBF, 0xB0};
uint8_t broadcastAddress2[] = {0x24, 0x0A, 0xC4, 0xAE, 0xAE, 0x44};
uint8_t broadcastAddress3[] = {0x80, 0x7D, 0x3A, 0x58, 0xB4, 0xB0};

然后，创建一个包含我们要发送的数据的结构。我们称这种结构为test_struct它包含两个整数变量。您可以更改此设置以发送所需的任何变量类型。

typedef struct test_struct {
  int x;
  int y;
} test_struct;

创建一个类型的新变量test_struct这被称为测试这将存储变量的值。

test_struct test;

创建类型的变量esp_now_peer_info_t存储有关对等方的信息。

esp_now_peer_info_t peerInfo;

4.2 OnDataSent（） 回调函数

接下来，定义OnDataSent（）功能。这是一个回调函数，将在发送消息时执行。在这种情况下，此函数将打印消息是否成功传递以及针对哪个 MAC 地址。因此，您知道哪些板收到了消息，哪些板没有收到消息。

void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  char macStr[18];
  Serial.print("Packet from: ");
  // Copies the sender mac address to a string
  snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
           mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
  Serial.print(macStr);
  Serial.print(" send status:\t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}

4.3 setup（）

在setup（），初始化串行监视器以进行调试：

Serial.begin(115200);

将设备设置为 Wi-Fi 站：

WiFi.mode(WIFI_STA);

初始化 ESP-NOW：

if (esp_now_init() != ESP_OK) {
  Serial.println("Error initializing ESP-NOW");
  return;
}

成功初始化 ESP-NOW 后，注册发送消息时将调用的回调函数。在这种情况下，请注册OnDataSent（）之前创建的函数。

esp_now_register_send_cb(OnDataSent);

4.4 添加对等节点

之后，我们需要与其他 ESP-NOW 设备配对以发送数据。这就是我们在下一行中所做的 - 注册对等节点：

// register peer
peerInfo.channel = 0;
peerInfo.encrypt = false;
// register first peer
memcpy(peerInfo.peer_addr, broadcastAddress1, 6);
if (esp_now_add_peer(&peerInfo) != ESP_OK){
  Serial.println("Failed to add peer");
  return;
}
// register second peer
memcpy(peerInfo.peer_addr, broadcastAddress2, 6);
if (esp_now_add_peer(&peerInfo) != ESP_OK){
  Serial.println("Failed to add peer");
  return;
}
/// register third peer
memcpy(peerInfo.peer_addr, broadcastAddress3, 6);
if (esp_now_add_peer(&peerInfo) != ESP_OK){
  Serial.println("Failed to add peer");
  return;
}

如果要添加更多对等体，只需复制这些行并传递对等体 MAC 地址：

memcpy(peerInfo.peer_addr, broadcastAddress, 6);
if (esp_now_add_peer(&peerInfo) != ESP_OK){
  Serial.println("Failed to add peer");
  return;
}

4.5 loop（）

在loop（），我们将每 2 秒通过 ESP-NOW 发送一条消息（您可以更改此延迟时间）。

为每个变量赋值：

test.x = random(0,20);
test.y = random(0,20);

请记住，测试是一种结构。在这里，分配要在结构内发送的值。在本例中，我们只是发送随机值。例如，在实际应用中，这些应替换为命令或传感器读数。

4.6 将相同的数据发送到多个板

最后，按如下方式发送消息：

esp_err_t result = esp_now_send(0, (uint8_t *) &test, sizeof(test_struct));

的第一个参数esp_now_send（）function 是接收方的 MAC 地址。如果你通过0作为参数，它将向所有注册的对等节点发送相同的消息。如果要向每个对等方发送不同的消息，请按照下一节操作。

检查消息是否已成功发送：

if (result == ESP_OK) {
  Serial.println("Sent with success");
}
else {
  Serial.println("Error sending the data");
}

这loop（）每 2000 毫秒（2 秒）执行一次。

delay(2000);

4.7 向每个板发送不同的数据

向每个板发送不同消息的代码与前一个非常相似。因此，我们只看一下其中的区别。

如果要向每个看板发送不同的消息，则需要为每个看板创建一个数据结构，例如：

test_struct test;
test_struct test2;
test_struct test3;

在本例中，我们将发送相同的结构类型 （test_struct).只要接收方代码准备好接收该类型的结构，就可以发送不同的结构类型。

然后，为每个结构的变量分配不同的值。在此示例中，我们只是将它们设置为随机数。

test.x = random(0,20);
test.y = random(0,20);
test2.x = random(0,20);
test2.y = random(0,20);
test3.x = random(0,20);
test3.y = random(0,20);

最后，您需要调用esp_now_send（）每个接收器的功能。

例如，发送测试MAC 地址为广播地址1.

esp_err_t result1 = esp_now_send(
  broadcastAddress1, 
  (uint8_t *) &test,
  sizeof(test_struct));
   
if (result1 == ESP_OK) {
  Serial.println("Sent with success");
}
else {
  Serial.println("Error sending the data");
}

对其他板执行相同的操作。对于第二个板，请发送测试2结构：

esp_err_t result2 = esp_now_send(
  broadcastAddress2, 
  (uint8_t *) &test2,
  sizeof(test_struct));

if (result2 == ESP_OK) {
  Serial.println("Sent with success");
}
else {
  Serial.println("Error sending the data");
}

最后，对于第三块板，发送测试3结构：

esp_err_t result3 = esp_now_send(
  broadcastAddress3, 
  (uint8_t *) &test3,
  sizeof(test_struct));

if (result3 == ESP_OK) {
  Serial.println("Sent with success");
}
else {
  Serial.println("Error sending the data");
}

下面是向每个板发送不同消息的完整代码。

/*********
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp-now-one-to-many-esp32-esp8266/
  
  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.
  
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

#include <esp_now.h>
#include <WiFi.h>

// REPLACE WITH YOUR ESP RECEIVER'S MAC ADDRESS
uint8_t broadcastAddress1[] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};
uint8_t broadcastAddress2[] = {0xFF, , , , , };
uint8_t broadcastAddress3[] = {0xFF, , , , , };

typedef struct test_struct {
  int x;
  int y;
} test_struct;

void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  char macStr[18];
  Serial.print("Packet to: ");
  // Copies the sender mac address to a string
  snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
           mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
  Serial.print(macStr);
  Serial.print(" send status:\t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}
 
void setup() {
 
  Serial.begin(115200);
 
  WiFi.mode(WIFI_STA);
 
  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }

  esp_now_register_send_cb(OnDataSent);

  // register peer
  esp_now_peer_info_t peerInfo;
  peerInfo.channel = 0;  
  peerInfo.encrypt = false;
    
  memcpy(peerInfo.peer_addr, broadcastAddress1, 6);
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
  
  memcpy(peerInfo.peer_addr, broadcastAddress2, 6);
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
  memcpy(peerInfo.peer_addr, broadcastAddress3, 6);
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
}
 
void loop() {
  test_struct test;
  test_struct test2;
  test_struct test3;
  test.x = random(0,20);
  test.y = random(0,20);
  test2.x = random(0,20);
  test2.y = random(0,20);
  test3.x = random(0,20);
  test3.y = random(0,20);
 
  esp_err_t result1 = esp_now_send(
    broadcastAddress1, 
    (uint8_t *) &test,
    sizeof(test_struct));
   
  if (result1 == ESP_OK) {
    Serial.println("Sent with success");
  }
  else {
    Serial.println("Error sending the data");
  }
  delay(500);
  esp_err_t result2 = esp_now_send(
    broadcastAddress2, 
    (uint8_t *) &test2,
    sizeof(test_struct));

  if (result2 == ESP_OK) {
    Serial.println("Sent with success");
  }
  else {
    Serial.println("Error sending the data");
  }
  
  delay(500);  
  esp_err_t result3 = esp_now_send(
    broadcastAddress3, 
    (uint8_t *) &test3,
    sizeof(test_struct));
   
  if (result3 == ESP_OK) {
    Serial.println("Sent with success");
  }
  else {
    Serial.println("Error sending the data");
  }
  delay(2000);
}

查看原始代码

5. ESP32 接收器代码 （ESP-NOW）

将下一个代码上传到接收器板（在我们的示例中，我们使用了三个接收器板）。

/*********
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp-now-one-to-many-esp32-esp8266/
  
  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.
  
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

#include <esp_now.h>
#include <WiFi.h>

//Structure example to receive data
//Must match the sender structure
typedef struct test_struct {
  int x;
  int y;
} test_struct;

//Create a struct_message called myData
test_struct myData;

//callback function that will be executed when data is received
void OnDataRecv(const uint8_t * mac, const uint8_t *incomingData, int len) {
  memcpy(&myData, incomingData, sizeof(myData));
  Serial.print("Bytes received: ");
  Serial.println(len);
  Serial.print("x: ");
  Serial.println(myData.x);
  Serial.print("y: ");
  Serial.println(myData.y);
  Serial.println();
}
 
void setup() {
  //Initialize Serial Monitor
  Serial.begin(115200);
  
  //Set device as a Wi-Fi Station
  WiFi.mode(WIFI_STA);

  //Init ESP-NOW
  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }
  
  // Once ESPNow is successfully Init, we will register for recv CB to
  // get recv packer info
  esp_now_register_recv_cb(OnDataRecv);
}
 
void loop() {

}

代码的工作原理与发送方类似，首先包括库：

#include <esp_now.h>
#include <WiFi.h>

创建一个结构来接收数据。此结构应与发送方草图中定义的结构相同。

typedef struct test_struct {
  int x;
  int y;
} test_struct;

创建一个test_struct称为myData（我的数据）.

test_struct myData;

创建一个回调函数，当 ESP32 通过 ESP-NOW 接收到数据时调用该函数。该函数被调用onDataRecv（）并应接受以下几个参数：

void OnDataRecv(const uint8_t * mac, const uint8_t *incomingData, int len)

复制传入数据data 变量添加到myData（我的数据）变量。

memcpy(&myData, incomingData, sizeof(myData));

现在，myData（我的数据）结构包含几个变量，其中包含发送方 ESP32 发送的值。访问变量x，例如调用myData.x.

在此示例中，我们打印接收到的数据，但在实际应用中，您可以在OLED显示器上打印数据。

Serial.print("Bytes received: ");
Serial.println(len);
Serial.print("x: ");
Serial.println(myData.x);
Serial.print("y: ");
Serial.println(myData.y);
Serial.println();

在setup（），初始化串行监视器。

Serial.begin(115200);

将设备设置为 Wi-Fi Station。

WiFi.mode(WIFI_STA);

初始化 ESP-NOW：

if (esp_now_init() != ESP_OK) {
  Serial.println("Error initializing ESP-NOW");
  return;
}

注册一个回调函数，该函数将在收到数据时调用。在这种情况下，我们注册OnDataRecv（）之前创建的函数。

esp_now_register_recv_cb(OnDataRecv);

6. ESP8266 接收器代码 （ESP-NOW）

如果您使用 ESP8266板作为接收器，请改为上传以下代码。

/*********
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp-now-one-to-many-esp32-esp8266/
  
  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.
  
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

#include <ESP8266WiFi.h>
#include <espnow.h>

//Structure example to receive data
//Must match the sender structure
typedef struct test_struct {
  int x;
  int y;
} test_struct;

//Create a struct_message called myData
test_struct myData;

//callback function that will be executed when data is received
void OnDataRecv(uint8_t * mac, uint8_t *incomingData, uint8_t len) {
  memcpy(&myData, incomingData, sizeof(myData));
  Serial.print("Bytes received: ");
  Serial.println(len);
  Serial.print("x: ");
  Serial.println(myData.x);
  Serial.print("y: ");
  Serial.println(myData.y);
  Serial.println();
}
 
void setup() {
  //Initialize Serial Monitor
  Serial.begin(115200);
  
  //Set device as a Wi-Fi Station
  WiFi.mode(WIFI_STA);

  //Init ESP-NOW
  if (esp_now_init() != 0) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }
  
  // Once ESPNow is successfully Init, we will register for recv CB to
  // get recv packer info
  esp_now_set_self_role(ESP_NOW_ROLE_SLAVE);
  esp_now_register_recv_cb(OnDataRecv);
}
 
void loop() {

}

除了一些小细节外，此代码与 ESP32 接收器代码非常相似。因此，我们不会解释它是如何工作的。要了解更多信息，您可以阅读我们的 ESP-NOW ESP8266 NodeMCU 入门指南。

7. 示范

打开所有开发板的电源后，打开发送器所连接的COM端口的Arduino IDE串行监视器。

您应该开始在串行监视器中接收带有相应接收器 MAC 地址的“传送成功”消息。

ESP32 ESP-NOW 发送数据到多个板卡 交货状态 串口监视器

如果断开其中一个主板的电源，您将收到该特定主板的“交付失败”消息。因此，您可以快速确定哪个板没有收到消息。

ESP32 ESP-NOW 发送数据到多个开发板 交付状态失败 串口监视器

如果要检查板是否确实接收到消息，可以打开它们所连接的 COM 端口的串行监视器，也可以使用 PuTTY 与板建立串行通信。

如果您使用的是 PuTTY，请选择串行通信，写下 COM 端口号和波特率 （115200），如下所示，然后单击打开。

串行通信 ESP 板 PuTTY

然后，您应该看到正在接收的消息。

ESP32 ESP8266 NodeMCU ESP-NOW 向多板发送数据交付成功演示

为每个开发板打开串行通信，并检查它们是否正在接收消息。

8. 总结

🥳🥳🥳现在，我们在本教程中，您学习了如何使用 ESP-NOW（一对多通信）从单个 ESP32 向多个 ESP8266 或 ESP32 板发送数据。🛹🛹🛹从而实现对外部世界进行感知，充分认识这个有机与无机的环境，后期会持续分享esp32跑freertos实用案列🥳🥳🥳科学地合理地进行创作和发挥效益，然后为人类社会发展贡献一点微薄之力。🤣🤣🤣

参考文献：

  • 【ESP-NOW ESP32 开发板之间的双向通信】
  • 【ESP-NOW 入门（ESP32 with Arduino IDE）】
  • ESP-NOW with ESP32: Send Data to Multiple Boards (one-to-many)

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：http://www.coloradmin.cn/o/1347894.html

如若内容造成侵权/违法违规/事实不符，请联系多彩编程网进行投诉反馈，一经查实，立即删除！

相关文章

2023-12-16 LeetCode每日一题（统计区间中的整数数目）

2023-12-16 LeetCode每日一题（统计区间中的整数数目）

2023-12-16每日一题 一、题目编号 2276. 统计区间中的整数数目二、题目链接 点击跳转到题目位置 三、题目描述 给你区间的 空 集&#xff0c;请你设计并实现满足要求的数据结构&#xff1a; **新增&#xff1a;**添加一个区间到这个区间集合中。 **统计&#xff1a;**计算…
阅读更多...
Plantuml之甘特图语法介绍(二十八)

Plantuml之甘特图语法介绍(二十八)

简介&#xff1a; CSDN博客专家&#xff0c;专注Android/Linux系统&#xff0c;分享多mic语音方案、音视频、编解码等技术&#xff0c;与大家一起成长&#xff01; 优质专栏&#xff1a;Audio工程师进阶系列【原创干货持续更新中……】&#x1f680; 优质专栏&#xff1a;多媒…
阅读更多...
Transformer基本结构

Transformer基本结构

Transformer基本结构 输入部分、编码部分、解码部分、输出部分 1、输入部分 原文本嵌入层及其位置编码器目标文本嵌入层及其位置编码器 位置编码器(PositionalEncoding)&#xff1a;将词汇位置不同可能会产生不同语义的信息加入到词张量中&#xff0c;以弥补位置信息的缺失 …
阅读更多...
node版本管理器nvm的下载和使用

node版本管理器nvm的下载和使用

介绍 nvm 全名 node.js version management&#xff0c;顾名思义是一个nodejs的版本管理工具。通过它可以安装和切换不同版本的nodejs。 下载和安装 在下载和安装nvm前&#xff0c;需要确保当前电脑没有安装node&#xff0c;否则则需要先把原来的node卸载了。 下载地址&#…
阅读更多...
HTML+CSS+JS制作三款雪花酷炫特效

HTML+CSS+JS制作三款雪花酷炫特效

🎀效果展示 🎀代码展示 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"> <html
阅读更多...
Fortran 编译后Dll依赖问题（libifcoremd.dll）

Fortran 编译后Dll依赖问题（libifcoremd.dll）

在VS里&#xff0c;点击运行按钮&#xff0c;程序正常运行。 在exe文件目录中&#xff0c;双击exe运行&#xff0c;提示缺少libifcoremd.dll文件&#xff0c;经查阅资料和以往的经验&#xff0c;解决方法如下&#xff1a; 红色是默认的&#xff0c;绿色是能够正常运行的。
阅读更多...
AcWing算法提高课-2.3.1矩阵距离

AcWing算法提高课-2.3.1矩阵距离

算法提高课整理 CSDN个人主页&#xff1a;更好的阅读体验 本文同步发表于 CSDN | 洛谷 | AcWing | 个人博客 原题链接 题目描述 给定一个 01 矩阵&#xff0c;求矩阵中每个元素离 1 的最短曼哈顿距离。 输入格式 第一行两个整数 n , m n,m n,m。 接下来一个 n n n 行 …
阅读更多...
跳圈圈^^

跳圈圈^^

欢迎来到程序小院 跳圈圈 玩法&#xff1a;女骑士点击左下按钮越过低处火圈&#xff0c;点击右下按钮越过高处火圈&#xff0c;越过火圈获得分数&#xff0c;快去挑战吧^^。开始游戏https://www.ormcc.com/play/gameStart/235 html <div id"loadicon"><im…
阅读更多...
机器学习分类模型

机器学习分类模型

机器学习常见分类模型及特点 机器学习常见分类模型优缺点 决策树模型 决策树&#xff08;Decision Tree&#xff09;是一类常见的机器学习方法&#xff0c;可应用于分类与回归任务&#xff0c;这里主要讨论分类决策树。决策树是基于树结构来进行决策的。下图是使用决策树来决定…
阅读更多...
python统计分析——协方差和pearson相关系数

python统计分析——协方差和pearson相关系数

参考资料&#xff1a;用python动手学统计学 使用数据见代码&#xff1a; dic{"x":[18.5,18.7,19.1,19.7,21.5,21.7,21.8,22.0,23.4,23.8],"y":[34,39,41,38,45,41,52,44,44,49] } cov_datapd.DataFrame(dic) 变量x、y的协方差Cov(x,y)的计算公式如下&am…
阅读更多...
【LLM 】7个基本的NLP模型，为ML应用程序赋能

【LLM 】7个基本的NLP模型，为ML应用程序赋能

在上一篇文章中&#xff0c;我们已经解释了什么是NLP及其在现实世界中的应用。在这篇文章中&#xff0c;我们将继续介绍NLP应用程序中使用的一些主要深度学习模型。 BERT 来自变压器的双向编码器表示&#xff08;BERT&#xff09;由Jacob Devlin在2018年的论文《BERT:用于语言…
阅读更多...
开关电源反馈环路重要参数设计，PC817和TL431实例计算和取值详解

开关电源反馈环路重要参数设计，PC817和TL431实例计算和取值详解

author&#xff1a;小高霸气 data:2021.04.16 下面介绍开关电源重要的反馈电路PC817和TL431设计和应用。 在开关电源当中&#xff0c;对稳压反馈电路的设计通常会使用TL431和PC817来配合使用。在TOP 及3842等单端反激电路中的反馈电路很多都采用TL431和PC817作为参考、隔离、取…
阅读更多...
css原子化的框架Tailwindcss的使用教程(原始html和vue项目的安装与配置)

css原子化的框架Tailwindcss的使用教程(原始html和vue项目的安装与配置)

安装教程 中文官网教程 原始的HTML里面使用 新建文件夹npm init -y 初始化项目 安装相关依赖 npm install -D tailwindcss postcss-cli autoprefixer初始化两个文件 npx tailwindcss init -p根目录下新建src/style.css tailwind base; tailwind components; tailwind ut…
阅读更多...
Bmp2Png是什么工具？好用吗？

Bmp2Png是什么工具？好用吗？

Bmp2Png是什么工具&#xff1f;好用吗&#xff1f; 批量BMP图片转为PNG透明图片&#xff0c;去掉BMP黑色背景&#xff0c;压缩导出png图片V1.1前段时间上传了一款bmp转png并去黑底的demo软件&#xff0c;非常受欢迎&#xff0c; 上一版本地址&#xff1a;批量BMP图片转为PNG…
阅读更多...
Visual Transformer (ViT)模型详解

Visual Transformer (ViT)模型详解

1 Vit简介 1.1 Vit的由来 ViT是2020年Google团队提出的将Transformer应用在图像分类的模型&#xff0c;虽然不是第一篇将transformer应用在视觉任务的论文&#xff0c;但是因为其模型“简单”且效果好&#xff0c;可扩展性强&#xff08;scalable&#xff0c;模型越大效果越好…
阅读更多...
【LLM】人工智能应用构建的十大预训练NLP语言模型

【LLM】人工智能应用构建的十大预训练NLP语言模型

在人工智能领域&#xff0c;自然语言处理&#xff08;NLP&#xff09;被广泛认为是阅读、破译、理解和理解人类语言的最重要工具。有了NLP&#xff0c;机器可以令人印象深刻地模仿人类的智力和能力&#xff0c;从文本预测到情感分析再到语音识别。 什么是自然语言处理&#xf…
阅读更多...
C语言实验5：结构体

C语言实验5：结构体

目录 一、实验要求 二、实验原理 1. 普通结构体 1.1 显示声明结构体变量 1.2 直接声明结构体变量 ​编辑 1.3 typedef在结构体中的作用 2. 结构体的嵌套 3. 结构体数组 4. 指向结构体的指针 4.1 静态分配 4.2 动态分配 三、实验内容 1. 学生数据库 代码 截图 …
阅读更多...
《数据库开发实践》之触发器【知识点罗列+例题演练】

《数据库开发实践》之触发器【知识点罗列+例题演练】

一、什么是触发器&#xff1f; 1.概念&#xff1a; 简单来说触发器就是一种特殊的存储过程&#xff0c;在数据库服务器触发事件的时候会自动执行其SQL语句集。 2.构成四要素&#xff1a; &#xff08;1&#xff09;名称&#xff1a;要符合标识符命名规则 &#xff08;2&am…
阅读更多...
跳跃表原理及实现

跳跃表原理及实现

一、跳表数据结构 跳表是有序表的一种&#xff0c;其底层是通过链表实现的。链表的特点是插入删除效率高&#xff0c;但是查找节点效率很低&#xff0c;最坏的时间复杂度是O(N)&#xff0c;那么跳表就是解决这一痛点而生的。 为了提高查询效率&#xff0c;我们可以给链表加上索…
阅读更多...
ORACLE Primavera Unifier v23.12 最新虚拟机(VM)分享下载

ORACLE Primavera Unifier v23.12 最新虚拟机(VM)分享下载

引言 根据上周的计划&#xff0c;我近日简单制作了一个基于ORACLE Primavera Unifier 最新版23.12的虚拟机演示环境&#xff0c;里面包括了unifier的全套系统服务 此虚拟系统环境仅用于演示、培训和测试目的。如要在生产环境中使用此虚拟机&#xff0c;请您与Oracle 销售代表联…
阅读更多...
推荐文章
最新文章

Copyright @ 2022~2023