文章目录
- 前言
- 一、阴影接受的步骤
- 1、在v2f中添加UNITY_SHADOW_COORDS(idx),unity会自动声明一个叫_ShadowCoord的float4变量，用作阴影的采样坐标.
- 2、在顶点着色器中添加TRANSFER_SHADOW(o)，用于将上面定义的_ShadowCoord纹理采样坐标变换到相应的屏幕空间纹理坐标，为采样阴影纹理使用.
- 3、在片断着色器中添加UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)，其中atten即存储了采样后的阴影.
- 4、加上所需要的宏
- 二、补充
- 1、在场景中，旋转摄像头 或 拉近摄像头 时影子会时不时的消失，这是因为我们没有正确开启 光照模式
- 2、场景中的阴影是纯黑的，黑的看不见原本的颜色的情况
- 3、要正确接受阴影，最好开启阴影投射中的ShadowCaster
前言
Unity中Shader阴影的接收(基于上一篇文章)
- Unity中Shader阴影的投射
一、阴影接受的步骤
这是没有写阴影接收前的效果（虽然勾选了接收阴影，但是没有阴影效果）
采样阴影
1.在v2f中添加UNITY_SHADOW_COORDS(idx),unity会自动声明一个叫_ShadowCoord的float4变量，用作阴影的采样坐标.
2.在顶点着色器中添加TRANSFER_SHADOW(o)，用于将上面定义的_ShadowCoord纹理采样坐标变换到相应的屏幕空间纹理坐标，为采样阴影纹理使用.
3.在片断着色器中添加UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)，其中atten即存储了采样后的阴影.
因为是接受阴影，所以效果写在实现效果的Pass中
1、在v2f中添加UNITY_SHADOW_COORDS(idx),unity会自动声明一个叫_ShadowCoord的float4变量，用作阴影的采样坐标.
这里需要引入 AutoLighting.cginc
#include “AutoLight.cginc”
查看源码可知，为什么是叫 _ShadowCoord 的 float4 变量
UNITY_SHADOW_COORDS(1)
2、在顶点着色器中添加TRANSFER_SHADOW(o)，用于将上面定义的_ShadowCoord纹理采样坐标变换到相应的屏幕空间纹理坐标，为采样阴影纹理使用.
TRANSFER_SHADOW(o)
3、在片断着色器中添加UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)，其中atten即存储了采样后的阴影.
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)
在使用之前，需要得到 i.worldPos
- 首先，在 v2f 中，定义一个 float4 存储worldPos
float4 worldPos :TEXCOORD2;
- 然后，在顶点着色器中，把 顶点信息 转化到世界空间下
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
- 最后，在片元着色器使用 UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)
现在我们输出看一下效果（会发现效果不对，只有白色）
return atten;
这时，我们对比一下，自带的 Shader 和 我们写的Shader之间有什么区别
自带的 Shader 中，比我们Shader多出了 SHADOWS_SCREEN 的宏
4、加上所需要的宏
- 法一，使用一个比较全面的宏来定义(比较浪费性能)
#pragma multi_compile_fwdbase novertexlight nodynlightmap nodirlightmap
定义在LightMode = ForwardBase的Pass中,在此Pass中仅只持一个平行灯(逐像素)以及其它逐顶点灯和SH当照.这个指令的作用是一次性生成Unity在ForwardBase中需要的各种内置宏.
DIRECTIONAL DIRLIGHTMAP_COMBINED DYNAMICLIGHTMAP_ON LIGHTMAP_ON LIGHTMAP_SHADOW_MIXING LIGHTPROBE_SH SHADOWS_SCREEN SHADOWS_SHADOWMASK VERTEXLIGHT_ON
- DIRECTIONAL :主平行灯下的效果开启,fowwardBase下必开宏
- DIRLIGHTMAP_COMBINED :烘焙界面中的DirecitonalMode设置为Directional
- DYNAMICLIGHTMAP_ON :RealtimeGI是否开启
- LIGHTMAP_ON：当对象标记为LightMap Static并且场景烘焙后开启
- LIGHTMAP_SHADOW_MIXING:当灯光设置为Mixed,光照烘焙模式设置为Subtractive或者shadowMask时开启,Baked Indirect情况下无效
- LIGHTPROBE_SH:开启光照探针,动态物体会受到LightProbe的影响,静态物体与此不相关
- SHADOWS_SCREEN:在硬件支持屏幕阴影的情况下，同时处理阴影的距离范围内时开启
- SHADOWS_SHADOWMASK:当灯光设置为Mixed,光照烘焙模式设置为shadowMask时开启
- VERTEXLIGHT_ON ：是否受到逐顶点的照明
使用之后,我们会发现,小狐狸能接受阴影了
然后,我们用atten值与采样后的纹理值,相乘输出即可
我们会发现影子比较黑,可以在 光线处调节 或者 之后使用 GI 来修改
虽然,我们实现了阴影的效果
但是,使用这个全面的 宏,特别消耗性能
可以看见,这个Shader的变体已经到了惊人的 86 个之多,但是,没有使用到。这是极其浪费的,所以我们要剔除无用的变体
#pragma multi_compile_fwdbase
//剔除无用的变体
#pragma skip_variants DIRLIGHTMAP_COMBINED DYNAMICLIGHTMAP_ON LIGHTMAP_ON LIGHTMAP_SHADOW_MIXING LIGHTPROBE_SH SHADOWS_SHADOWMASK VERTEXLIGHT_ON
剔除后,变体只剩下 5 个了
- 法二、自己定义需要的变体
#pragma multi_compile DIRECTIONAL SHADOWS_SCREEN
可以看见我们的变体数量还是 5 个,且效果一样
测试代码:
Shader "MyShader/P1_7_3"
{
Properties
{
[Enum(Off,0,On,1)]_ZWrite("ZWrite",int) = 0
[Enum(UnityEngine.Rendering.CompareFunction)]_ZTest("ZTest",int) = 0
//使用这个标签，可以使外部暴露属性，有标题
[Header(Base)]
[NoScaleOffset]_MainTex ("Texture", 2D) = "white" {}
_Clip("Clip",Range(0,1)) = 0
//使用这个标签可以 在两行暴露属性之间加 间隙
[Space(10)]
[Header(Dissolve)]
_DissolveTex("DissolveTex",2D) = "black"{}
[NoScaleOffset]_RampTex("RampTex(RGB)",2D) = "black" {}
}
SubShader
{
Tags{"Queue" = "Geometry"}
Blend Off
Cull Back
/*ZWrite [_ZWrite]
ZTest [_ZTest]*/
Offset -1,-1
UsePass "MyShader/P1_6_4/XRay"
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
//#pragma multi_compile_fwdbase
//剔除无用的变体
//#pragma skip_variants DIRLIGHTMAP_COMBINED DYNAMICLIGHTMAP_ON LIGHTMAP_ON LIGHTMAP_SHADOW_MIXING LIGHTPROBE_SH SHADOWS_SHADOWMASK VERTEXLIGHT_ON
//自己定义，阴影需要使用的变体
#pragma multi_compile DIRECTIONAL SHADOWS_SCREEN
#include "UnityCG.cginc"
#include "AutoLight.cginc"
sampler2D _MainTex;
float _Clip;
sampler2D _DissolveTex;
//这个四维向量，xyzw分别表示 Tilling 和 Offset 的 xy ,命名方式 在纹理名 后加 _ST
float4 _DissolveTex_ST;
//因为 在使用渐变纹理时，只使用了 渐变纹理的 u 坐标，所以把 sampler2D 换为 sampler
sampler _RampTex;
struct appdata
{
float4 vertex : POSITION;
float4 uv : TEXCOORD0;
};
//1.在v2f中添加UNITY_SHADOW_COORDS(idx),unity会自动声明一个叫_ShadowCoord的float4变量，用作阴影的采样坐标.
struct v2f
{
float4 uv : TEXCOORD0;
float4 pos : SV_POSITION;
UNITY_SHADOW_COORDS(1)
float4 worldPos :TEXCOORD2;
};
//2.在顶点着色器中添加TRANSFER_SHADOW(o)，用于将上面定义的_ShadowCoord纹理采样坐标变换到相应的屏幕空间纹理坐标，为采样阴影纹理使用.
v2f vert (appdata v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
//为了减少传入的值 ，所以就不创建新变量来存储，而是把 uv 改为 四维向量 来用
//使用 o.uv 的 xy 来存放 原人物贴图
//使用 o.uv 的 zw 来存放 噪波贴图缩放 和 偏移 后的值
o.uv.xy = v.uv.xy;
//o.uv.zw = v.uv * _DissolveTex_ST.xy + _DissolveTex_ST.zw;
o.uv.zw = TRANSFORM_TEX(v.uv,_DissolveTex);
TRANSFER_SHADOW(o)
//把顶点转化到世界空间下
o.worldPos = mul(unity_ObjectToWorld,v.vertex);
return o;
}
//3.在片断着色器中添加UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)，其中atten即存储了采样后的阴影.
fixed4 frag (v2f i) : SV_Target
{
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos)
fixed4 col = tex2D(_MainTex, i.uv.xy);
//把阴影 和 纹理相乘
col *= atten;
//外部获取的 纹理 ，使用前都需要采样
fixed4 dissolveTex = tex2D(_DissolveTex,i.uv.zw);
//片段的取舍
clip(dissolveTex.r - _Clip);
//进行归一化
fixed4 dissolveValue = saturate((dissolveTex.r - _Clip) / (_Clip + 0.1 - _Clip));
fixed4 rampTex = tex1D(_RampTex,dissolveValue.r);
//col += rampTex;
return col;
}
ENDCG
}
//阴影的投射
Pass
{
//1、设置 "LightMode" = "ShadowCaster"
Tags{"LightMode" = "ShadowCaster"}
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
//需要添加一个 Unity变体
#pragma multi_compile_shadowcaster
#include "UnityCG.cginc"
//声明消融使用的变量
float _Clip;
sampler2D _DissolveTex;
float4 _DissolveTex_ST;
//2、appdata中声明float4 vertex:POSITION;和half3 normal:NORMAL;这是生成阴影所需要的语义.
//注意：在appdata部分，我们几乎不要去修改名字 和 对应的类型。
//因为，在Unity中封装好的很多方法都是使用这些标准的名字
struct appdata
{
float4 vertex:POSITION;
half3 normal:NORMAL;
float4 uv:TEXCOORD;
};
//3、v2f中添加V2F_SHADOW_CASTER;用于声明需要传送到片断的数据.
struct v2f
{
float4 uv : TEXCOORD;
V2F_SHADOW_CASTER;
};
//4、在顶点着色器中添加TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)，主要是计算阴影的偏移以解决不正确的Shadow Acne和Peter Panning现象.
v2f vert(appdata v)
{
v2f o;
o.uv.zw = TRANSFORM_TEX(v.uv,_DissolveTex);
TRANSFER_SHADOW_CASTER_NORMALOFFSET(o);
return o;
}
//5、在片断着色器中添加SHADOW_CASTER_FRAGMENT(i)
fixed4 frag(v2f i) : SV_Target
{
//外部获取的 纹理 ，使用前都需要采样
fixed4 dissolveTex = tex2D(_DissolveTex,i.uv.zw);
//片段的取舍
clip(dissolveTex.r - _Clip);
SHADOW_CASTER_FRAGMENT(i);
}
ENDCG
}
}
}
二、补充
1、在场景中，旋转摄像头 或 拉近摄像头 时影子会时不时的消失，这是因为我们没有正确开启 光照模式
Tags{“LightMode”=“ForwardBase”}
2、场景中的阴影是纯黑的，黑的看不见原本的颜色的情况
可以在 光线处调节 或者 之后使用 GI 来修改
3、要正确接受阴影，最好开启阴影投射中的ShadowCaster
Tags{“LightMode” = “ShadowCaster”}
，
