BI技巧丨Window应用之移动平均

news2024/11/23 18:37:34

Window函数白茶之前介绍过，可以用来处理同环比问题，因为其函数内部特性，我们还可以用其来处理移动平均问题。

先来看看本期的案例数据：

案例数据非常的简单，随机模拟一下销售挂蛋的情况即可。

将其导入到PowerBI中，添加日期表：

日期表 =
GENERATE (
    CALENDAR ( MIN ( '示例'[时间] ), MAX ( '示例'[时间] ) ),
    VAR DA = [Date]
    VAR YEAR =
        YEAR ( DA )
    VAR QUARTER =
        "季度" & FORMAT ( DA, "Q" )
    VAR MONTE =
        FORMAT ( DA, "MM" ) & "月"
    VAR DAY =
        DAY ( DA )
    VAR WEEKID =
        WEEKDAY ( DA, 2 )
    RETURN
        ROW (
            "年度", YEAR,
            "季度", QUARTER,
            "月份", MONTE,
            "日", DAY,
            "年度季度", YEAR & QUARTER,
            "年度月份", YEAR & MONTE,
            "星期", WEEKID
        )
)

模型关系如下：

添加如下度量值：

销售金额：

001.Sales =
SUM ( '示例'[销售金额] )

Topn移动平均：

002.Topn移动 =
VAR CurrentDate =
    MAX ( '日期表'[Date] )
VAR CurrentTable =
    TOPN (
        3,
        FILTER (
            FILTER ( ALL ( '日期表'[Date] ), [001.Sales] <> BLANK () ),
            '日期表'[Date] <= CurrentDate
        ),
        CALCULATE ( MAX ( '日期表'[Date] ) ), DESC
    )
VAR Result =
    AVERAGEX ( CurrentTable, [001.Sales] )
RETURN
    IF ( [001.Sales] <> BLANK (), Result, BLANK () )

Values移动平均：

003.Values移动 =
VAR CurrentDate =
    MAX ( '示例'[时间] )
VAR CurrentTable =
    TOPN (
        3,
        FILTER ( ALL ( '示例'[时间] ), '示例'[时间] <= CurrentDate ),
        CALCULATE ( VALUES ( '示例'[时间] ) ), DESC
    )
VAR Result =
    AVERAGEX ( CurrentTable, [001.Sales] )
RETURN
    Result

结果如下：

这是白茶之前处理移动平均的办法，可能时间太过久远了，小伙伴都不记得了。

1.结果中Topn和Values的核心区别在于Topn内部的第3参数，分别是Max和Values的区别；

2.为了展示不同的上下文，Topn是借助日期表构建的逻辑，Values利用的是Fact表中的日期列；

3.两个上下文的区别是Dim日期表是需要过滤掉无值日期，而Fact则不需要；

4.两段逻辑的内部核心都是利用Topn返回筛选后的动态表，再利用均值函数求出移动平均。

有了Window函数之后，我们还可以换种写法：

004.Window移动 =
CALCULATE (
    ( [001.Sales] / COUNT ( '日期表'[Date] ) ),
    WINDOW (
        -2,
        REL,
        0,
        REL,
        FILTER ( ALLSELECTED ( '日期表' ), [001.Sales] <> BLANK () )
    )
)

结果如下：