【VB6|第27期】如何在VB6中使用Shell函数实现同步执行

news2024/12/28 19:03:31

日期：2024年9月1日
作者：Commas
签名：(ง •_•)ง 积跬步以致千里,积小流以成江海……
注释：如果您觉得有所帮助，帮忙点个赞，也可以关注我，我们一起成长；如果有不对的地方，还望各位大佬不吝赐教，谢谢^ - ^
1.01³⁶⁵ = 37.7834；0.99³⁶⁵ = 0.0255
1.02³⁶⁵ = 1377.4083；0.98³⁶⁵ = 0.0006

在这里插入图片描述

文章目录

一、前言
二、Shell函数的同步执行问题
三、实现同步执行的步骤
- 1、`OpenProcess` ：打开进程，以获得进程句柄。
- 2、`WaitForSingleObject`：等待一个进程句柄指示的进程结束。
- 3、`CloseHandle`: 关闭一个内核对象句柄。
四、完整示例
五、结论

一、前言

书接上回，Shell 函数是异步执行的，但还是有很多开发者在使用 Shell 函数打开外部程序时，会希望程序能够等待该外部程序执行完毕再继续执行，即同步执行。本文将为你介绍如何实现这一功能。

二、Shell函数的同步执行问题

然而，默认情况下，Shell 函数是异步执行的，这意味着它会启动一个新的进程，然后立即返回，不会等待该进程结束。这在某些场景下可能不是我们想要的结果。那么，如何实现同步执行呢？

三、实现同步执行的步骤

其实原理很简单，为了实现同步执行，就必须等待进程结束后才继续执行后面的代码。我们可以使用 Windows API 函数来达到我们的预期效果，步骤如下：

1、`OpenProcess` ：打开进程，以获得进程句柄。

Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long

其中，参数说明：

dwDesiredAccess:这是一个访问掩码，用于指定你想要对进程对象进行的操作类型。常见的访问权限包括：

参数	说明
`PROCESS_TERMINATE`	允许终止进程。
`PROCESS_CREATE_THREAD`	允许创建一个线程。
`PROCESS_VM_OPERATION`	允许在进程的地址空间进行操作。
`PROCESS_VM_READ`	允许读取进程的地址空间。
`PROCESS_VM_WRITE`	允许写入进程的地址空间。
`SYNCHRONIZE`	允许等待进程终止。

通常为了等待进程结束，我们会使用 SYNCHRONIZE（即 Private Const SYNCHRONIZE = &H100000）权限。

bInheritHandle:如果这个值为 TRUE，则创建的进程句柄可以被子进程继承；否则不能。
dwProcessId:要打开的进程的标识符，即 Shell 函数的返回值。

返回值说明：

如果函数成功，返回值是进程对象的句柄。
如果函数失败，返回值是 NULL。

2、`WaitForSingleObject`：等待一个进程句柄指示的进程结束。

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long

其中，参数说明：

参数	说明
`hHandle`	要等待的内核对象的句柄（即 `OpenProcess` 函数的成功返回值）。这可以是事件、作业、进程、线程、互斥量或信号量的句柄。
`dwMilliseconds`	等待的时间间隔，以毫秒为单位。如果这个值为 `INFINITE`（即 `Private Const INFINITE = -1&`），则该函数将无限期地等待，直到对象变为信号状态。

返回值说明：

返回值	说明
`WAIT_OBJECT_0`	对象处于信号状态。
`WAIT_TIMEOUT`	指定的时间已经过去，但对象还没有处于信号状态。
`WAIT_FAILED`	函数失败。

3、`CloseHandle`: 关闭一个内核对象句柄。

Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

其中 hObject 为要关闭的内核对象的句柄，即 OpenProcess 函数的成功返回值。

返回值说明：

如果函数成功，返回值是非零。
如果函数失败，返回值是零。

四、完整示例

以下是完整示例，展示如何使用 API 函数等待Shell 函数启动的进程结束：

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Const SYNCHRONIZE = &H100000
Private Const INFINITE = -1&
Private Sub OpenBrowserAndWait()
    Dim RetVal As Long
    Dim ProcessHandle As Long
    Dim Result As Long
    ' 使用Shell函数启动浏览器
    RetVal = Shell("explorer http://www.example.com", 1)
    ' 如果Shell函数成功启动了进程，它会返回进程ID
    If RetVal > 0 Then
        ' 打开进程，以获得进程句柄
        ProcessHandle = OpenProcess(SYNCHRONIZE, 0, RetVal)
        ' 等待进程结束
        Result = WaitForSingleObject(ProcessHandle, INFINITE)
        ' 关闭进程句柄
        Call CloseHandle(ProcessHandle)
    End If
End Sub