VBA批量合并带有图片、表格与文本框的Word

news2024/11/16 15:26:06

本文介绍基于VBA语言，对大量含有图片、文本框与表格的Word文档加以批量自动合并，并在每一次合并时添加分页符的方法。

在我们之前的文章基于Python中docx与docxcompose批量合并多个Word文档文件并逐一添加分页符（https://blog.csdn.net/zhebushibiaoshifu/article/details/117718274）中，介绍过基于Python语言的python-docx（docx）模块与docxcompose模块，对大量Word文档加以合并的方法；但是，基于这种方法，我们无法对具有非明确大小的文本框的Word加以合并，因为python-docx无法处理含有这种元素的Word文件。最近，一位老哥提出了合并含有文本框的Word的需求，所以就尝试用VBA来实现这一操作，这里就介绍一下具体的方法。

其中，VBA是Visual Basic for Applications的缩写，其是基于Visual Basic语言的一种扩展，主要应用于微软Office套件中各种应用程序，例如Word、Excel与PowerPoint等；其允许用户创建自定义的宏和应用程序来自动执行各种任务，从而提高工作效率。目前，VBA主要就是应用于需要批量操作Office文件的各类场景中。

本文的需求如下。现在有一个文件夹，其中包含大量文档文件，如下图所示；其中，每一个文档中，都包含图片、表格、文本框等较为复杂的元素。

我们现在希望，可以批量将文件夹中大量文档文件加以合并；并且在合并时，每次都需要在新的1页中合并下一个文件（也就是，不同文件的内容不要出现在1页中）。

明确了需求，即可开始代码撰写。本文所需代码如下。

Sub merge_word()
    Dim time_start As Single: time_start = Timer
    Dim word_result As Document
    Dim word_temp As Document
    Dim file_dialog As FileDialog
    Dim str As String
    Dim file
    Dim num As Long
    
    Set word_result = ActiveDocument
    Set file_dialog = Application.FileDialog(msoFileDialogFilePicker)
    
    With file_dialog
        .AllowMultiSelect = True
        .Title = "请选择【一个或多个】需要与当前文档合并的文件"
        With .Filters
            .Clear
            .Add "Word文件", "*.doc*;*.dot*;*.wps"
            .Add "所有文件", "*.*"
        End With
        If .Show Then
            Application.ScreenUpdating = False
            num = .SelectedItems.count
            For Each file In .SelectedItems
                Set word_temp = Documents.Open(file)
                word_temp.Range.Copy
                
                word_result.Range(word_result.Range.End - 1, word_result.Range.End).Select
                
                DoEvents
                Selection.Paste
                Selection.InsertBreak
                
                word_temp.Close wdDoNotSaveChanges
            Next
            
            Application.ScreenUpdating = True
        End If
    End With
    
    Set word_result = Nothing
    Set word_temp = Nothing
    Set file_dialog = Nothing
    
    str = Format(Timer - time_start, "均已成功合并；共用时0秒！")
    str = Format(num, "您选择合并0个文件，") & str
    MsgBox str, vbInformation, "文件合并结果"
End Sub

上述代码中，我们首先进行变量声明。time_start是一个Single类型的变量，用以记录代码开始执行的时间；Timer函数返回一个单精度浮点数，表示从计算机启动到现在经过的秒数。word_result是一个Document类型的变量，用以存储当前打开的Word文档。word_temp是另一个Document类型的变量，用以临时存储要合并的其他Word文档。file_dialog是一个FileDialog类型的变量，用以存储文件选择对话框对象。str是一个字符串类型的变量，用以存储最终要显示在消息框中的合并结果信息。file用以在循环中存储用户选择的每个文件路径。num是一个长整型变量，用以存储用户选择的文件数量。

随后，我们获取当前文档。将当前正在编辑的Word文档赋值给word_result变量，这个文档就是要合并其他文档内容的结果文档。

接下来，我们打开文件选择对话框。创建一个文件选择对话框对象，并逐一设置对话框的属性；其中，允许用户选择多个文件，自定义对话框标题，并设置文件类型过滤器，其中第一个表示只显示Word文档文件，第二个则表示显示所有类型的文件。

紧接着，通过If .Show Then语句，判断用户在对话框中是否选择了文件。如果是的话，执行合并操作。其中，首先获取用户选择的文件数量；随后，循环遍历每个选择的文件——打开每个选择的文件作为临时文档，将临时文档的全部内容复制到剪贴板；将光标定位到目标文档（也就是结果文件）的最后一个字符处，并将剪贴板中的内容粘贴到目标文档的末尾，同时在粘贴的内容后插入一个分页符；最后，关闭临时文档而不保存更改。接下来，进行下一次遍历。其中需要注意，这里如果我们不添加DoEvents这句代码，会导致其下方的Selection.Paste这句代码报错（虽然会报错，但其实选择调试后继续按下F5，程序也还是可以运行）。

最后，即可清理变量引用，并计算合并操作的耗时，将结果信息显示在消息框中。

代码的执行方法如下。首先，在任意路径创建一个空白的Word文档，作为我们的结果文件。随后，在这个文档中，同时按下Alt键与F11键，进入VBA宏界面，如下图所示。