Oracle基础-PL/SQL编程备份

1、PL/SQL简介

PL/SQL块结构

约定：为了方便，本文后面把PL/SQL简称PL。

PL程序都是以块（BLOCK）为基本单位，整个PL块分三部分：声明部分（使用DECLARE开头）、执行部分(以BEGIN开头)和异常处理部分（以EXCEPTION开头）。其中执行部分是必须的，其他两个部分可选。无论PL的代码量有多大，其基本结构都是由这三部分组成。标准的PL语法格式如下：

[DECLARE]

-- 声明部分，可选

BEGIN

-- 执行部分，必须

[EXCEPTION]

-- 异常处理，可选

接下来对PL块的三个部分进行详细说明：

（1）声明部分由关键字DECLARE开始，到BEGIN关键字结束。在这部分可以声明PL程序块中所用到的变量、常亮和游标等。需要注意的是：在某个PL块中声明的内容只能在当前块中使用，而在其他的PL中无法引用。

（2）执行部分以关键字BEGIN开始，它的结束方式通常有两种。如果PL块中的代码在运行时出现异常，则执行完异常处理部分的代码就结束；如果没有使用异常处理或PL未出现异常，则以END关键字结束。执行部分是整个PL程序块的主体，主要的逻辑控制和运算都在这部分完成，所以在执行部分可以包含多个PL语句和SQL语句。

（3）异常处理部分以关键字EXCEPTION开始，在该关键字所包含的代码执行完毕后，整个PL块也就执行结束了。在执行PL代码的过程中，可能会产生一些意想不到的错误，比如除数为零，空值参与运算等，这些错误都会导致程序中断运行。这样程序设计人员就可以在异常处理部分通过编写一定量的代码来纠正错误或者给用户提供一些错误信息提示，甚至将各种数据操作回退到异常产生之前的状态，以备重新运行代码块。另外，对于可能出现的多种异常情况，用户可以使用WHEN THEN语句来实现多分支判断，然后在每个分支下通过编写代码来处理相应的异常。

对于PL块中的语句，需要指出的是：每一条语句都必须以分号结束，每条SQL语句可以写成多行的形式，同样必须使用分号来结束。另外，一行中也可以有多条SQL语句，但是他们之间必须以分号分隔。

【例1.1】定义一个PL，计算两个整数的和与这两个整数的差的商。

set serveroutput on;
declare
    a int := 100;
    b int := 200;
    c number;
   begin
     c := (a+b)/(a-b);
     dbms_output.put_line(c);
   exception
     when zero_divide then
       dbms_output.put_line('除数不能为零');
    end;
    /

在上面的代码中，首先使用"set serveroutput on"命令来实现在服务端显示执行结果；然后使用declare关键字声明了3个变量，其中，前两个为int变量a和b的初始值分别为100，200；最后在PL块的执行部分计算，并调用"dbms_output.put_line(c)"输出。为了防止除数为0，还设置了异常处理部分。若发生除数为零的情况，则代码块通过调用dbms_output.put_line('除数不能为零')，向用户提示。如

2、数据类型、变量和常量

2.1 概述

数据类型本质上是一种用于描述数据存储的内存结构，用它来决定变量中所存储数据的类型，而变量本质上是一种用名称进行识别的标示符号，它可以存储不同类型的数据。根据不同的数据类型，定义不同名称的变量，这样就可以存储不同类型的数据。变量在程序运行的过程中，其值可以发生变化，与变量对应的就是常量，常量是指在程序运行的过程中，值不会发生变化。

2.2 基本数据类型

PL有多种数据类型，这些数据类型能够满足在编写PL程序过程中定义变量和常量。

2.2.1 数值类型

数值类型主要包括NUMBER、PLS_INTEGER和BINARY_INTEGER三种基本类型。其中，NUMBER变量可以存储整数或浮点数，而PLS_INTEGER和BINARY_INTEGER只能存储整数。

NUMBER 类型还可以通过number(P,S)的形式来格式化数字。其中，P表示精度，S表示刻度范围。精度是指数值中所有有效数字的个数，而刻度范围是指小数点右边小数位的个数，其中P和S都是可选的。

【例2.2.1.1】声明一个精度为9，刻度范围是2的表示金额的变量Num_Money,代码如下。

Num_Money NUMBER(9,2);

PL还提出“子类型”的概念，子类型就是与NUMBER类型等价的类型别名，甚至可以说是NUMBER类型的多种命名形式，这些等价的子类型主要包括DEC,DECIMAL,DOUBLE,INTEGER,INT,NUMERIC,SMALLINT,BINARY_INTEGER,PLS_INTEGER等。

2.2.2 字符类型

字符类型主要包括VARCHAR2,CHAR,LONG,NCHAR,NVARCHAR2等，这些类型的变量可以用来存储字符串或字符数据。

1、VARCHAR2

PL语言中的VARCHAR2与数据库类型中的VARCHAR2类似，可以用来存储可变长度的字符串，声明语法格式为：

VARCHAR2(maxlength)

maxlength表示可以存储字符串的最大长度，这个参数值在定义变量时必须给出（因为VARCHAR2类型没有默认的最大长度），maxlength最大值是32767.

注意：数据库类型的VARCHAR2的最大长度是4000字节，所以一个长度大于4000字节的PL类型VARCHAR2变量不可以赋值给数据库中的VARCHAR2变量，只能赋值给LONG类型的数据库变量。

2、CHAR

char 类型表示指定长度的字符串，其语法格式如下：

CHAR(maxlength)

maxlength指可存储字符串的最大长度，以字节为单位，最大32767字节，CHAR类型的默认最大长度是1。与VARCHAR2不同，maxlength可以不指定，默认为1。如果赋值CHAR类型的指不足maxlength，则会在后面用空格补全，这也是不同VARCHAR2的地方。

注意：数据库类型的CHAR最大只有2000字节，所以如果PL中CHAR类型变量的长度大于2000字节，则不能赋给数据库中的CHAR。

3、LONG

LONG类型表示一个可变的字符串，最大长度是32767，而数据库类型的LONG最大长度为2GB，所以几乎任何字符串都可以赋值给它。

4、NCHAR和NVARCHAR2

NCHAR和NVARCHAR2类型是PL 8.0以后才加入的类型，它们的长度要根据各国字符集来确定，只能具体情况具体分析。

2.2.3 日期类型

日期类型只有一种DATE类型，用来存储日期和时间，DATE类型的存储空间是7个字节，分别使用一个字节存储世纪、年、月、日、小时、分、秒。

2.2.4 布尔类型

布尔类型也只有一种BOOLEAN，主要用户程序的流程控制和业务逻辑判断，其值可以使TRUE,FALSE,NULL。

2.3 特殊数据类型

2.3.1 %TYPE类型

使用%TYPE关键字可以声明一个与指定列相同的数据类型，它通常紧跟在指定列名的后面。

【例2.3.1.1】声明一个与emp表中job列的数据类型完成相同的变量var_job

declare
    var_job emp.job%TYPE;

使用%TYPE定义变量有两个好处：第一，用户不必查询表中各个列的数据类型，就可以确保所定义的变量能够存储检索的数据；第二，如果对表中已有列的数据类型进行修改，则不必考虑对已定义的变量所使用的的数据类型进行更改，因为%TYPE类型的变量会根据列的实际类型自动调整自身的数据类型。

【例2.3.1.2】使用%TYPE类型的变量输出emp表中编号为7369的员工名称和职务信息

SQL> set serveroutput on
SQL> declare 
  2      var_ename emp.ename%TYPE;
  3      var_job   emp.job%TYPE;
  4      begin
  5           select ename,job 
  6           into var_ename,var_job
  7           from emp
  8           where empno = 7369;
  9           dbms_output.put_line(var_ename || '的职务是' || var_job);
 10     end;
 11  /

在上面的代码中使用into子句，它位于select子句的后面，用于设置将从数据库检索的数据存储到哪个变量中。

注意：由于into子句中的变量只能存储一个单独的值，所以要求select子句只能返回一行数据，这个由where子句进行了限定，如果select子句返回多行数据，则代码运行后会返回错误信息

2.3.2 RECORD类型

RECORD称为记录类型，使用该类型的变量可以存储由多个列值组成的一行数据，在声明记录类型变量之前，首先需要定义记录类型，然后才可以声明记录类型的变量。记录类型是一种结构化的数据类型，它使用type语句进行定义，在记录类型的定义结构中包含成员变量及其数据类型，语法：

type record_type is record

(

var_member1 data_type [not null] [:=default_value],

...

var membern data_type [not null] [:=default_value]

)

record_type:表示要定义的记录类型名称

var_member1:表示该记录类型的成员变量名称。

data_type:表示成员变量的数据类型

【例2.3.2.1】声明一个记录类型emp_type,然后使用该类型的变量存储emp表中的一条记录信息，并输出。

set serveroutput on;
SQL> declare
  2      type emp_type is record
  3      (
  4           var_name varchar2(20),
  5           var_job varchar2(20),
  6           var_sal number
  7      );
  8      empinfo emp_type;
  9      begin
 10          select ename,job,sal into empinfo
 11          from emp
 12          where empno = 7369;
 13          dbms_output.put_line('员工' || empinfo.var_name || '的职务是' || empinfo.var_job ||'，工资是' || empinfo.var_sal);
 14          end;
 15  /

2.3.3 %ROWTYPE类型

%rowtype 类型变量结合了“%type”和“record”变量的优点，它可以根据数据表中行的结构定义一种特殊的数据类型，用来存储从数据表中检索到的一行数据。语法：

rowVar_name table_name%rowtype;

rowVar_name:表示可以存储一行数据的变量名

table_name:指定的表名

【例2.3.3.1】声明一个%ROWTYPE类型的变量rowVar_emp,然后使用该变量存储emp表中的一行数据。

set serveroutput on;
SQL> declare
  2      rowVar_emp emp%rowtype;
  3      begin
  4        select * into rowVar_emp from emp where empno = 7369;
  5        dbms_output.put_line('员工'||rowVar_emp.ename || '的编号是' || rowVar_emp.empno ||'，职务是' || rowVar_emp.job);
  6        end;
  7  /